Masalah pemetaan bayangan pertama kali

Saya telah menerapkan pemetaan bayangan dasar untuk pertama kalinya di OpenGL menggunakan shader dan saya menghadapi beberapa masalah. Di bawah ini Anda dapat melihat contoh pemandangan yang saya buat:

Proses pemetaan bayangan yang saya ikuti adalah bahwa saya membuat adegan ke framebuffer menggunakan Matriks Tampilan dari sudut pandang cahaya dan matriks proyeksi dan model yang digunakan untuk rendering normal.

Pada pass kedua, saya mengirim matriks MVP di atas dari sudut pandang cahaya ke vertex shader yang mengubah posisi menjadi ruang terang. Shader fragmen melakukan pembagian perspektif dan mengubah posisi ke koordinat tekstur.

Ini vertex shader saya,

#version 150 core

uniform mat4 ModelViewMatrix;
uniform mat3 NormalMatrix;
uniform mat4 MVPMatrix;
uniform mat4 lightMVP;

uniform float scale;

in vec3 in_Position;
in vec3 in_Normal;
in vec2 in_TexCoord;

smooth out vec3 pass_Normal;
smooth out vec3 pass_Position;
smooth out vec2 TexCoord;
smooth out vec4 lightspace_Position;

void main(void){
    pass_Normal = NormalMatrix * in_Normal; 
    pass_Position = (ModelViewMatrix * vec4(scale * in_Position, 1.0)).xyz;
    lightspace_Position = lightMVP * vec4(scale * in_Position, 1.0);
    TexCoord = in_TexCoord;

    gl_Position = MVPMatrix * vec4(scale * in_Position, 1.0);
}

Dan shader fragmen saya,

#version 150 core

struct Light{
    vec3 direction;
};

uniform Light light;
uniform sampler2D inSampler;
uniform sampler2D inShadowMap;

smooth in vec3 pass_Normal;
smooth in vec3 pass_Position;
smooth in vec2 TexCoord;
smooth in vec4 lightspace_Position;

out vec4 out_Color;


float CalcShadowFactor(vec4 lightspace_Position){

    vec3 ProjectionCoords = lightspace_Position.xyz / lightspace_Position.w;

    vec2 UVCoords;
    UVCoords.x = 0.5 * ProjectionCoords.x + 0.5;
    UVCoords.y = 0.5 * ProjectionCoords.y + 0.5;

    float Depth = texture(inShadowMap, UVCoords).x;
    if(Depth < (ProjectionCoords.z + 0.001)) return 0.5;
    else return 1.0;
}

void main(void){

    vec3 Normal = normalize(pass_Normal);
    vec3 light_Direction = -normalize(light.direction);
    vec3 camera_Direction = normalize(-pass_Position);
    vec3 half_vector = normalize(camera_Direction + light_Direction);

    float diffuse = max(0.2, dot(Normal, light_Direction));
    vec3 temp_Color = diffuse * vec3(1.0);

    float specular = max( 0.0, dot( Normal, half_vector) );

    float shadowFactor = CalcShadowFactor(lightspace_Position);

    if(diffuse != 0 && shadowFactor > 0.5){
        float fspecular = pow(specular, 128.0);
        temp_Color += fspecular;
    }

    out_Color = vec4(shadowFactor * texture(inSampler, TexCoord).xyz * temp_Color, 1.0);
}

Salah satu masalah adalah bayangan diri seperti yang Anda lihat dalam gambar, peti memiliki bayangan sendiri. Apa yang saya coba adalah mengaktifkan offset poligon (yaitu glEnable (POLYGON_OFFSET_FILL), glPolygonOffset (GLfloat, GLfloat)) tetapi tidak banyak berubah. Seperti yang Anda lihat di fragmen shader, saya telah meletakkan nilai offset statis 0,001 tetapi saya harus mengubah nilai tergantung pada jarak cahaya untuk mendapatkan efek yang lebih diinginkan, yang tidak terlalu berguna. Saya juga mencoba menggunakan pemusnahan wajah depan ketika saya membuat framebuffer, itu tidak banyak berubah juga.

Masalah lainnya adalah bahwa piksel di luar frustum tampilan Cahaya mendapatkan naungan. Satu-satunya objek yang seharusnya bisa membuat bayangan adalah peti. Saya kira saya harus memilih proyeksi yang lebih tepat dan melihat matriks, tetapi saya tidak yakin bagaimana melakukannya. Apa sajakah praktik umum, yang harus saya pilih proyeksi ortografis?

Dari googling sekitar sedikit, saya mengerti bahwa masalah ini tidak sepele. Adakah yang punya mudah menerapkan solusi untuk masalah ini. Bisakah Anda memberi saya beberapa tips tambahan?

Tolong tanyakan kepada saya jika Anda memerlukan informasi lebih lanjut tentang kode saya.

Berikut ini adalah perbandingan dengan dan tanpa pemetaan bayangan dari close-up peti. Bayangan diri lebih terlihat.

Anda seharusnya tidak membayangi poligon yang menghadap ke belakang dari cahaya.

Saya mengubah shader fragmen Anda menjadi kode di bawah ini.

float CalcShadowFactor(vec4 lightspace_Position)
{

    vec3 ProjectionCoords = lightspace_Position.xyz / lightspace_Position.w;

    vec2 UVCoords;
    UVCoords.x = 0.5 * ProjectionCoords.x + 0.5;
    UVCoords.y = 0.5 * ProjectionCoords.y + 0.5;

    float Depth = texture(inShadowMap, UVCoords).x;
    if(Depth < (ProjectionCoords.z + 0.001)) return 0.5;
    else return 1.0;
}

void main(void)
{

    vec3 Normal = normalize(pass_Normal);
    vec3 light_Direction = -normalize(light.direction);
    vec3 camera_Direction = normalize(-pass_Position);
    vec3 half_vector = normalize(camera_Direction + light_Direction);

    float fndotl = dot(Normal, light_Direction);
    float shadowFactor = CalcShadowFactor(lightspace_Position);
    float diffuse = max(0.0, fndotl) * shadowFactor + 0.2;
    vec3 temp_Color = vec3(diffuse);

    float specular = max( 0.0, dot( Normal, half_vector) );

    if(shadowFactor > 0.9){
        float fspecular = pow(specular, 128.0);
        temp_Color += fspecular;
    }

    out_Color = vec4(shadowFactor * texture(inSampler, TexCoord).xyz * temp_Color, 1.0);
}

Mengenai bayangan diri, saya tidak yakin apa yang Anda maksudkan - saya tidak melihat "bayangan jerawat" pada peti di tangkapan layar Anda. Jika Anda maksudkan bahwa wajah-wajah yang menghadap jauh dari terang itu gelap, yah, tentu saja itu - mereka seharusnya! :) Wajah samping memang terlihat sedikit aneh, membelah diagonal menjadi setengah menyala dan setengah teduh. Jika Anda menggunakan N dot L untuk penerangan, dan Anda memiliki normals yang baik (yaitu normals keras pada kubus ini, bukan normals yang dihaluskan) yang seharusnya tidak terjadi.

Menggunakan offset poligon dan / atau menggambar wajah belakang ke peta bayangan adalah solusi standar (well ... workarounds really) untuk jerawat bayangan.

Sedangkan untuk matriks proyeksi, Anda harus menganggap cahaya sebagai kamera. Jika itu adalah titik cahaya, itu akan menjadi kamera perspektif dan jika itu adalah cahaya terarah itu akan seperti kamera ortografis. Buat matriks proyeksi dengan cara yang sama seperti yang Anda lakukan untuk kamera, menggunakan bidang pandang cahaya, rasio aspek, dll.

Untuk membatasi shader piksel untuk hanya menggambar piksel dalam frustum tampilan cahaya, setelah Anda menghitung bayangan peta UV hanya memeriksa apakah mereka antara 0 dan 1 dan discardjika tidak (atau mengatur warna cahaya ke nol). Cara lain adalah dengan mengatur tekstur peta bayangan ke mode "clamp to border" dan mengatur batas warna nol, yang akan memastikan segala sesuatu di luar peta bayangan mendapat bayangan penuh.

Pixel di luar tampilan lampu gelap karena diambil sampelnya dari luar tekstur kedalaman cahaya.

Ketika Anda mengubah titik oleh matriks proyeksi Anda mendapatkan koordinat klip [lightspace_Position] dari fragmen. Anda kemudian mengubahnya menjadi koordinat tekstur [UVCoords]. Namun, koordinat ruang klip dari fragmen masih dapat berada di luar rentang -1.0 hingga 1.0 (dari layar dan karenanya terpotong) dan karenanya koordinat tekstur yang dikonversi dapat berada di luar kisaran 0,0 hingga 1,0 dari tekstur Anda.

Coba ini:

if(UVCoords.x >= 0.0 && UVCoords.x <= 1.0 && UVCoords.y >= 0.0 && UVCoords.y <= 1.0 && (Depth < (ProjectionCoords.z + 0.001)))
    return 0.5;

Anda juga dapat melipatgandakan matriks bias ke dalam [lightMVP] Anda dan menghindari melakukan konversi koordinat dalam shader fragmen Anda.