Pad string dengan nol terkemuka sehingga panjangnya 3 karakter di SQL Server 2008

Saya memiliki string yang panjangnya hingga 3 karakter saat pertama kali dibuat di SQL Server 2008 R2.

Saya ingin menambahkannya dengan angka nol di depan, jadi jika nilai aslinya adalah '1' maka nilai baru adalah '001'. Atau jika nilai aslinya adalah '23' nilai baru adalah '023'. Atau jika nilai aslinya adalah '124' maka nilai baru sama dengan nilai asli.

Saya menggunakan SQL Server 2008 R2. Bagaimana saya melakukan ini menggunakan T-SQL?

Jika bidang sudah menjadi string, ini akan berfungsi

 SELECT RIGHT('000'+ISNULL(field,''),3)

Jika Anda ingin nulls ditampilkan sebagai '000'

Mungkin bilangan bulat - maka Anda ingin

 SELECT RIGHT('000'+CAST(field AS VARCHAR(3)),3)

Seperti yang dipersyaratkan oleh pertanyaan, jawaban ini hanya berfungsi jika panjang <= 3, jika Anda menginginkan sesuatu yang lebih besar Anda perlu mengubah konstanta string dan dua konstanta bilangan bulat dengan lebar yang dibutuhkan. misalnya'0000' and VARCHAR(4)),4

Meskipun pertanyaannya adalah untuk SQL Server 2008 R2, jika seseorang membaca ini dengan versi 2012 dan di atasnya, sejak itu menjadi lebih mudah dengan menggunakan FORMAT .

Anda dapat meneruskan string format numerik standar atau string format numerik khusus sebagai argumen format (terima kasih kepada Vadim Ovchinnikov untuk petunjuk ini).

Untuk pertanyaan ini misalnya kode suka

DECLARE @myInt INT = 1;
-- One way using a standard numeric format string
PRINT FORMAT(@myInt,'D3');
-- Other way using a custom numeric format string
PRINT FORMAT(@myInt,'00#');

output

001
001

Metode aman:

SELECT REPLACE(STR(n,3),' ','0')

Ini memiliki keuntungan mengembalikan string '***'untuk n <0 atau n> 999, yang merupakan indikator input out-of-bounds yang bagus dan jelas. Metode lain yang tercantum di sini akan gagal secara diam-diam dengan memotong input ke substring 3 karakter.

Berikut adalah teknik yang lebih umum untuk bantalan kiri dengan lebar yang diinginkan:

declare @x     int     = 123 -- value to be padded
declare @width int     = 25  -- desired width
declare @pad   char(1) = '0' -- pad character

select right_justified = replicate(
                           @pad ,
                           @width-len(convert(varchar(100),@x))
                           )
                       + convert(varchar(100),@x)

Namun, jika Anda berurusan dengan nilai-nilai negatif, dan menggunakan angka nol di depan, teknik ini atau teknik yang disarankan lainnya tidak akan berfungsi. Anda akan mendapatkan sesuatu yang terlihat seperti ini:

00-123

[Mungkin bukan yang Anda inginkan]

Jadi ... Anda harus melompati beberapa simpai tambahan Berikut ini satu pendekatan yang akan memformat angka negatif dengan benar:

declare @x     float   = -1.234
declare @width int     = 20
declare @pad   char(1) = '0'

select right_justified = stuff(
         convert(varchar(99),@x) ,                            -- source string (converted from numeric value)
         case when @x < 0 then 2 else 1 end ,                 -- insert position
         0 ,                                                  -- count of characters to remove from source string
         replicate(@pad,@width-len(convert(varchar(99),@x)) ) -- text to be inserted
         )

Orang harus mencatat bahwa convert()panggilan harus menentukan [n]varcharpanjang yang cukup untuk menahan hasil yang dikonversi dengan pemotongan.

Berikut adalah varian jawaban Hogan yang saya gunakan di SQL Server Express 2012:

SELECT RIGHT(CONCAT('000', field), 3)

Alih-alih khawatir jika bidangnya berupa string atau tidak, saya hanya CONCATmelakukannya, karena bagaimanapun juga akan menghasilkan string. Selain itu jika bidangnya bisa a NULL, menggunakan ISNULLmungkin diperlukan untuk menghindari fungsi mendapatkan NULLhasil.

SELECT RIGHT(CONCAT('000', ISNULL(field,'')), 3)

Saya selalu menemukan metode berikut ini sangat membantu.

REPLICATE('0', 5 - LEN(Job.Number)) + CAST(Job.Number AS varchar) as 'NumberFull'

Gunakan fungsi ini yang sesuai dengan setiap situasi.

CREATE FUNCTION dbo.fnNumPadLeft (@input INT, @pad tinyint)
RETURNS VARCHAR(250)
AS BEGIN
    DECLARE @NumStr VARCHAR(250)

    SET @NumStr = LTRIM(@input)

    IF(@pad > LEN(@NumStr))
        SET @NumStr = REPLICATE('0', @Pad - LEN(@NumStr)) + @NumStr;

    RETURN @NumStr;
END

Output sampel

SELECT [dbo].[fnNumPadLeft] (2016,10) -- returns 0000002016
SELECT [dbo].[fnNumPadLeft] (2016,5) -- returns 02016
SELECT [dbo].[fnNumPadLeft] (2016,2) -- returns 2016
SELECT [dbo].[fnNumPadLeft] (2016,0) -- returns 2016 

Bagi mereka yang ingin memperbarui data yang ada di sini adalah pertanyaan:

update SomeEventTable set eventTime=RIGHT('00000'+ISNULL(eventTime, ''),5)

Untuk bilangan bulat, Anda dapat menggunakan konversi implisit dari int ke varchar:

SELECT RIGHT(1000 + field, 3)

Saya tahu tiket lamanya yang saya pikir akan saya bagikan.

Saya menemukan kode ini mencari solusi. Tidak yakin apakah itu berfungsi pada semua versi MSSQL Saya memiliki MSSQL 2016.

declare @value as nvarchar(50) = 23
select REPLACE(STR(CAST(@value AS INT) + 1,4), SPACE(1), '0') as Leadingzero

mengembalikan "0023" The 4 dalam fungsi STR adalah panjang total termasuk nilai. Contoh 4, 23 dan 123 semuanya akan memiliki 4 dalam STR dan jumlah nol yang benar akan ditambahkan. Anda dapat menambah atau mengurangi itu. Tidak perlu mendapatkan panjang pada tanggal 23.

Sunting: Saya melihat sama dengan posting @Anon.

Coba ini dengan panjang tetap.

select right('000000'+'123',5)

select REPLICATE('0', 5 - LEN(123)) + '123'

Saya memiliki masalah yang sama dengan kolom integer sebagai input ketika saya membutuhkan varchar (atau string) berukuran tetap. Misalnya, 1 hingga '01', 12 hingga '12'. Kode ini berfungsi:

SELECT RIGHT(CONCAT('00',field::text),2)

Jika input juga merupakan kolom varchar, Anda dapat menghindari bagian casting.

Untuk pendekatan yang lebih dinamis coba ini.

declare @val varchar(5)
declare @maxSpaces int
set @maxSpaces = 3
set @val = '3'
select concat(REPLICATE('0',@maxSpaces-len(@val)),@val)

Menulis ini karena saya memiliki persyaratan hingga panjang tertentu (9). Pads kiri dengan @pattern SAJA ketika input perlu padding. Harus selalu mengembalikan panjang yang ditentukan dalam @pattern.

declare @charInput as char(50) = 'input'

--always handle NULL :)
set @charInput = isnull(@charInput,'')

declare @actualLength as int = len(@charInput)

declare @pattern as char(50) = '123456789'
declare @prefLength as int = len(@pattern)

if @prefLength > @actualLength
    select Left(Left(@pattern, @prefLength-@actualLength) + @charInput, @prefLength)
else
    select @charInput

Mengembalikan 1234input

Sederhana itu

Suka:

DECLARE @DUENO BIGINT
SET @DUENO=5

SELECT 'ND'+STUFF('000000',6-LEN(RTRIM(@DueNo))+1,LEN(RTRIM(@DueNo)),RTRIM(@DueNo)) DUENO

Saya datang ke sini secara khusus untuk mencari tahu bagaimana saya bisa mengubah zona waktu saya menjadi string zona waktu untuk mengubah tanggal menjadi DATETIMEOFFSET di SQL Server 2008. Gross, tetapi perlu.

Jadi saya memerlukan 1 metode yang akan mengatasi angka negatif dan positif, memformatnya menjadi dua karakter dengan nol di depan jika diperlukan. Jawaban Anons membuat saya dekat, tetapi nilai-nilai zona waktu negatif akan keluar 0-5daripada yang diperlukan-05

Jadi dengan sedikit perubahan pada jawabannya, ini berfungsi untuk semua konversi jam waktu

DECLARE @n INT = 13 -- Works with -13, -5, 0, 5, etc
SELECT CASE 
    WHEN @n < 0 THEN '-' + REPLACE(STR(@n * -1 ,2),' ','0') 
    ELSE '+' + REPLACE(STR(@n,2),' ','0') END + ':00'

Saya membuat fungsi ini yang melayani bigint dan satu nol terkemuka atau karakter tunggal lainnya (maks 20 karakter dikembalikan) dan memungkinkan untuk panjang hasil kurang dari panjang nomor input:

create FUNCTION fnPadNum (
  @Num BIGINT --Number to be padded, @sLen BIGINT --Total length of results , @PadChar varchar(1))
  RETURNS VARCHAR(20)
  AS
  --Pads bigint with leading 0's
            --Sample:  "select dbo.fnPadNum(201,5,'0')" returns "00201"
            --Sample:  "select dbo.fnPadNum(201,5,'*')" returns "**201"
            --Sample:  "select dbo.fnPadNum(201,5,' ')" returns "  201"
   BEGIN
     DECLARE @Results VARCHAR(20)
     SELECT @Results = CASE 
     WHEN @sLen >= len(ISNULL(@Num, 0))
     THEN replicate(@PadChar, @sLen - len(@Num)) + CAST(ISNULL(@Num, 0) AS VARCHAR)
     ELSE CAST(ISNULL(@Num, 0) AS VARCHAR)
     END

     RETURN @Results
     END
     GO

     --Usage:
      SELECT dbo.fnPadNum(201, 5,'0')
      SELECT dbo.fnPadNum(201, 5,'*')
      SELECT dbo.fnPadNum(201, 5,' ')