Daftar tipe file yang dikenal

Bagaimana saya bisa mendapatkan daftar nama tipe file yang saat ini diketahui vim?

Saya ingin dapat melakukan ini sehingga ketika vim tidak secara otomatis mendeteksi tipe file saya dapat mencoba beberapa tipe file yang diketahui vim tentang hal itu mungkin sama dan melihat apakah mereka memberikan highlight sintaksis yang masuk akal.

Saya tahu bahwa file vimscript yang berhubungan dengan tipe file dimasukkan ke dalam ftplugindirektori oleh konvensi tetapi mereka tidak perlu (saya tidak yakin, tapi saya tidak berpikir file vimscript dalam ftplugindirektori itu spesial) jadi saya ingin hanya tanyakan kepada vim jenis file apa yang diketahuinya, terlepas dari bagaimana mereka mengetahui tentang mereka.

Solusi Sederhana

Ketik :setfiletype (dengan spasi sesudahnya) , lalu tekan Ctrl-d.

Lihat :help cmdline-completionlebih lanjut tentang pelengkapan otomatis di baris perintah vim.

Solusi Rumit

Solusi ini menggunakan 'runtimepath'opsi untuk mendapatkan semua direktori sintaks yang tersedia, dan kemudian mengambil daftar file vimscript di direktori tersebut dengan ekstensi mereka dihapus. Ini mungkin bukan cara paling aman untuk melakukannya, jadi perbaikan dipersilahkan:

function! GetFiletypes()
    " Get a list of all the runtime directories by taking the value of that
    " option and splitting it using a comma as the separator.
    let rtps = split(&runtimepath, ",")
    " This will be the list of filetypes that the function returns
    let filetypes = []

    " Loop through each individual item in the list of runtime paths
    for rtp in rtps
        let syntax_dir = rtp . "/syntax"
        " Check to see if there is a syntax directory in this runtimepath.
        if (isdirectory(syntax_dir))
            " Loop through each vimscript file in the syntax directory
            for syntax_file in split(glob(syntax_dir . "/*.vim"), "\n")
                " Add this file to the filetypes list with its everything
                " except its name removed.
                call add(filetypes, fnamemodify(syntax_file, ":t:r"))
            endfor
        endif
    endfor

    " This removes any duplicates and returns the resulting list.
    " NOTE: This might not be the best way to do this, suggestions are welcome.
    return uniq(sort(filetypes))
endfunction

Anda kemudian dapat menggunakan fungsi ini dengan cara apa pun yang Anda inginkan, seperti mencetak semua nilai dalam daftar. Anda bisa mencapai itu seperti ini:

for f in GetFiletypes() | echo f | endfor

Perhatikan bahwa ini mungkin bisa dipadatkan sedikit, hanya saja ini agar mudah dibaca. Saya tidak akan menjelaskan setiap fungsi dan perintah yang digunakan di sini, tetapi di sini ada semua halaman bantuan untuk mereka:

• :help 'runtimepath'
• :help :let
• :help :let-&
• :help split()
• :help :for
• :help expr-.
• :help :if
• :help isdirectory()
• :help glob()
• :help fnamemodify()
• :help add()
• :help uniq()
• :help sort()

Jika versi vim Anda cukup baru (v7.4.2011 +), Anda dapat meminta tipe file yang dikenal dengan fungsi yang sekarang dapat kita gunakan untuk membantu mendefinisikan pelengkapan otomatis manual: getcompletion()

:echo getcompletion('', 'filetype')

Jika Anda ingin membatasi daftar untuk tipe file dimulai dengan 'c', Anda akan menelepon

:echo getcompletion('c', 'filetype')

dan seterusnya.

Catatan: tidak seperti solusi yang menguraikan nama file dan nama direktori $VIMRUNTIME/{syntax,filetype}/, solusi ini menganalisis 'runtimepath'juga. Sejauh yang saya mengerti, itu tidak melihat tipe file baru didefinisikan / terdaftar dengan cepat set ft=foobar, atau setelah perintah otomatis.

Anda juga dapat mencetak semua jenis file di terminal dengan menjalankan 2 perintah berikut:

1.

cd $(vim -e -T dumb --cmd 'exe "set t_cm=\<C-M>"|echo $VIMRUNTIME|quit' | tr -d '\015')

2.

cat <(ls -1 ftplugin/*.vim) <(ls -1 syntax/*.vim) | tr '\n' '\0' | xargs -0 -n 1 basename | sort | uniq | cut -f 1 -d '.'

Perintah pertama hanya menavigasi ke jalur runtime vim Anda (bagi saya itu adalah / usr / share / vim / vim80 ).

Perintah kedua mencantumkan semua nama tipe file dalam dua folder tempat vim menyimpan definisi tipe file.

Memperbarui

Perbaikan yang disarankan untuk dua perintah oleh muru yang menawarkan:

1.

cd $(vim -Nesc '!echo $VIMRUNTIME' -c qa)

2.

find syntax ftplugin -iname '*.vim' -exec basename -s .vim {} + | sort -u

Coba lihat dalam $ VIMRUNTIME / sintaks. Gunakan: echo $ VIMRUNTIME untuk mengetahui nilainya. Di komputer saya, $ VIMRUNTIME / sintaks adalah / usr / share / vim / vim81 / syntax. Ia memiliki semua file sintaks.

Jika Anda memiliki vim dengan gui, Anda juga dapat menggunakan menu Sintaks untuk mendapatkan semua tipe file yang didukung.