sed mengkonversi 4 spasi menjadi 2

Bagaimana seseorang mengkonversi 4 spasi menjadi 2 spasi dengan sed? Apa itu mungkin?

Saya menemukan ini tetapi itu mengonversi tab ke spasi:

sed -r ':f; s|^(\t*)\s{4}|\1\t|g; t f' file

Skrip yang Anda posting mengonversi 4 * n spasi menjadi n tab, hanya jika spasi tersebut didahului hanya dengan tab.

Jika Anda ingin mengganti 4 spasi dengan 2 spasi, tetapi hanya dalam lekukan, sementara itu mungkin dilakukan dengan sed, saya sarankan Perl sebagai gantinya.

perl -pe 's{^((?: {4})*)}{" " x (2*length($1)/4)}e' file

Sed:

sed -e 's/^/~/' -e ': r' -e 's/^\( *\)~    /\1  ~/' -e 't r' -e 's/~//' file

Anda mungkin ingin menggunakannya indent.

Tidak dengan cara langsung:

sed -r 's/ {4}/  /g'

Jika tidak, posisikan beberapa input jika gagal.

Jika hanya spasi yang akan dikonversi:

sed 'h;s/[^ ].*//;s/    /  /g;G;s/\n *//'

Dengan komentar:

sed '
  h; # save a copy of the pattern space (filled with the current line)
     # onto the hold space
  s/[^ ].*//; # remove everything starting with the first non-space
              # from the pattern space. That leaves the leading space
              # characters
  s/    /  /g; # substitute every sequence of 4 spaces with 2.
  G; # append a newline and the hold space (the saved original line) to
     # the pattern space.
  s/\n *//; # remove that newline and the indentation of the original
            # line that follows it'

Juga lihat 'ts'pengaturan dan :retabperintah vim

sed 's/^\( \+\)\1\1\1/\1\1/' file

Ini bekerja dengan membagi spasi memimpin menjadi empat instance dari grup yang sama (jadi mereka semua sama) dan kemudian menggantinya dengan hanya dua instance dari grup.

sed 's/    \{2,4\}\( \{0,1\}[^ ].*\)*/  \1/g' <input

Itu seharusnya hanya menekan urutan ruang terkemuka.