Hitung jumlah hari Minggu di bulan itu

8

Di Microsoft Excel saya mencari untuk menentukan jumlah hari Minggu di bulan tertentu. Saya menyusun spreadsheet anggaran dan beberapa sub rekening mendapatkan dana tambahan saat lima hari Minggu di bulan itu, bukan empat.

Satu-satunya sel yang harus saya referensi adalah judul lembar yang ada di Sel A1 dan sama dengan bulan saat ini. Sebagai contoh6/1/14

microsoft-excel microsoft-excel-2010 worksheet-function date-time wbeard52
sumber

Jawaban:

12

Coba ini di mana A1hari pertama setiap bulan:

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(A1&":"&EOMONTH(A1,0))),"ddd")="Sun"))

Anda juga dapat menggunakan ini untuk setiap hari dalam seminggu hanya mengubah "Sun"dan rentang tanggal apa pun dengan mengganti A1dengan tanggal mulai dan EOMONTH(A1,0)tanggal akhir.

Jay-ar
sumber
1
Wow. Ini sangat kreatif. Biarkan saya mengerti. Kami membuat nilai tanggal untuk sebulan penuh dengan fungsi tidak langsung dan baris? Kami kemudian mengonversinya menjadi teks dalam bentuk Matahari, Sen, dll. Kami mengevaluasi kondisi Matahari dan mengubah hasilnya menjadi satu atau nol dan kemudian menjumlahkan hasilnya. Apakah itu benar?
wbeard52
ya persis .. :)
Jay-ar
9

Jika tanggal yang Anda sebutkan selalu yang pertama di bulan itu, maka tanggal ini juga akan berfungsi:

=INT((WEEKDAY(A1-1)+EOMONTH(A1,0)-A1)/7)
teylyn
sumber
Sederhana. Sangat elegan dibandingkan dengan formula saya di atas. Terima kasih.
wbeard52
3

Sangat mirip dengan jawaban sebelumnya, tetapi hanya sedikit lebih bersih ...

=SUMPRODUCT(N(WEEKDAY(ROW(INDIRECT(A1&":"&EOMONTH(A1,0))))=1))
pengguna743733
sumber
3 
=DAY(EOMONTH(A1,0))-NETWORKDAYS.INTL(A1,EOMONTH(A1,0),11)

EDIT: Ini berfungsi di Excel 2016, tidak yakin kapan NETWORKDAYS.INTL diperkenalkan.

SRCP
sumber
Apa itu Networkdays.Intl tidak bekerja dengan semua excel
yass
Ah kamu benar Saya tidak melihat dia merujuk ke Excel 2010. Saya punya 2016. Tidak seperti networkdays, Networkdays.intl memungkinkan Anda memilih akhir pekan. Dalam hal ini, saya memberi tahu Excel bahwa akhir pekan adalah hari Minggu saja, itulah arti 11 singkatan tersebut. Jadi itu memberi Anda jumlah hari dalam periode tidak termasuk hari Minggu.
SRCP
NETWORKDAYS.INTLtersedia sejak Excel 2010 . Anda dapat melihat nomor 2010 di samping namanya. lihat tangkapan
layarnya
1

Saya percaya saya telah menemukan cara lain untuk menguliti kucing ini (bisa dikatakan).

Jika, Anda ingin menghindari memasukkan tanggal, dan memiliki lembar besar untuk proyeksi (misalnya, 18 bulan keluar) maka Anda bisa memberi tahu rumus apa bulan dan tahun Anda, dan memformatnya sesuai dengan itu. Ini bergabung dengan referensi absolut ke sel header yang berisi hari dalam seminggu yang bersangkutan dan Anda memiliki tabel yang jauh lebih ringkas dan lebih bersih (menurut saya).

A3 = Jan, B3 = 2017, C2: I2 = 3 Singkatan Hari Char (yaitu SUN)

Masukkan formula ke dalam sel C3

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(DATEVALUE(TEXT(CONCAT($A3,"/",$B3),"mm/dd/yyyy"))&":"&EOMONTH(DATEVALUE(TEXT(CONCAT($A3,"/",$B3),"mm/dd/yyyy")),0))),"ddd")=C$2))

Selamat berburu

Jeremy Cast
sumber
1

Sedikit variasi dari jawaban yang diterima , di mana Anda tidak memerlukan hari pertama bulan itu A1.

Ini dicapai dengan mengganti A1dengan:

date(year(today()),month(today()),1)

Ini dengan asumsi bahwa Anda menginginkannya untuk bulan berjalan.

=SUMPRODUCT(N(TEXT(ROW(INDIRECT(date(year(today()),month(today()),1)&":"&EOMONTH(date(year(today()),month(today()),1),0))),"ddd")="Sun"))
Calvt
sumber