Dapatkah drive jaringan yang dipetakan dihubungkan kembali dari baris perintah?

Setiap hari saya menemukan diri saya di command prompt Windows perlu mengakses drive jaringan yang dipetakan tetapi terputus. Saya belum menemukan perintah yang akan menyambungkan kembali drive ini tanpa membuka dan memetakan ulang (yang mengarah ke permainan menebak kata sandi, karena saya tidak memiliki komputer ini). Saya juga ingin skrip ini sehingga setiap malam drive terhubung kembali jika entah bagaimana telah terputus.

Solusi tercepat yang saya miliki saat ini adalah:

1. Ketik " start. "untuk membuka explorer,
2. Alt - D untuk memfokuskan bilah alamat,
3. ketik huruf drive yang saya inginkan dan tekan enter, dan tunggu untuk menampilkan konten drive
4. lalu akhirnya, tutup explorer dan kembali ke command prompt.

Saya tahu ini sedikit ketidaknyamanan, tapi saya sering melakukan ini melalui koneksi VNC atau PCAnywhere yang lambat di mana melakukan sesuatu melalui GUI sangat buruk, jadi saya hanya ingin tahu apakah ada solusi yang lebih baik.

Mungkin mencoba pushd \\server\share?

Saya harus memulai Windows 7 sebelum saya dapat menjalankan program VPN yang menghubungkan saya ke drive jaringan perusahaan. Oleh karena itu drive jaringan saya tidak terhubung kembali secara otomatis, hanya membukanya di Windows Explorer menghubungkannya kembali.

Saya telah membuat file batch kecil untuk memulai VPN, menyambungkan kembali drive jaringan, dan memulai beberapa aplikasi yang selalu saya gunakan.

Dalam file Batch saya, saya memiliki yang berikut ini:

REM Connect VPN here...

REM Opens an Explorer window looking at T: forcing a reconnect
Start /min explorer t:\

timeout 3 /nobreak

REM Kill all Explorer windows beginning with "T_drive" in the title
Taskkill /fi "windowtitle eq T_drive*"

REM Finish starting up here...

exit

Itu Taskkill /fi "windowtitle eq" perintah peka huruf besar kecil!

buat file batch (refreshletters.cmd) dengan perintah ini di dalamnya

( ini hanya akan bekerja di dalam file batch )

Diuji pada Win7 dan XP untuk menyegarkan huruf driver 'terputus' dan 'Tidak tersedia' di jendela konsol (baris perintah).

@echo off
net use |FIND ":" > %temp%\used.txt
FOR /F " tokens=1,2,3 delims= " %%i in (%temp%\used.txt) do (

  if %%i EQU Unavailable  (
    net use %%j %%k
    echo Activated %%j
   ) ELSE (
     if %%i EQU Disconnected (
       pushd .
       cd /d %%j
       dir . %>nul
       if NOT exist %%j\. (
          net use %%j /del /y
          net use %%j %%k
          echo Remapped %%j
          ) else (
             echo Fixed-up %%j
            )
       popd
       ) ELSE (
          echo Checked %%j
          )
     )
 )

Ini mungkin pertanyaan yang bodoh, tetapi dengan asumsi drive Anda "terputus" adalah H :, apakah Anda mencoba mengubah langsung ke drive?

Ini berfungsi untuk saya di bawah XP SP3:

C:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
Disconnected H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.


C:\>h:

H:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
OK           H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.

Saya tahu Anda mengatakan "penggunaan bersih" tidak berfungsi untuk Anda - tetapi inilah yang dapat Anda coba.

Jalankan file batch dengan net use / DELETE option untuk menghapus koneksi yang ada / persisten Dan kemudian Anda bisa menggunakan net use dengan opsi / SAVECRED untuk menggunakan kembali kredensial passowd yang digunakan int eh logon terakhir yang berhasil. Saya tidak yakin apakah ini akan mengatasi masalah Anda tetapi layak untuk dilihat.

Saya memiliki masalah yang sama dengan beberapa koneksi, dan intermiten. Saat saya me-reboot komputer, terkadang koneksi "baik" dan kadang tidak. Saya tidak memiliki masalah kata sandi karena saya menggunakan LAN perusahaan, tetapi saya masih memiliki aspek lain dari masalahnya.

Saya telah membuat file batch bernama ex.bat, dan menyimpannya (bersama banyak hal lainnya) di direktori \ util yang saya masukkan ke path saya. Saya dapat mengetik "ex h:" dan itu akan menjalankan Windows Explorer dan mengaturnya untuk langsung ke drive h :. Ini adalah file batch:

start explorer /e,/select,%1

Ini bekerja, dengan penekanan tombol yang jauh lebih sedikit. Atau jika tidak bekerja pada awalnya, tekan tombol Enter untuk membuka folder h: root dan tampilkan isinya. Atau, ketik "ex h: \ sub" di mana subfolder "sub" ada.

Masalah ini tampaknya menjadi jauh lebih buruk baru-baru ini, mungkin karena salah satu tambalan keamanan Windows XP.

Hal lain untuk dicoba adalah di sisi server. Pada server Windows, memodifikasi kunci Registry seharusnya menjaga server dari memutuskan koneksi pada batas waktu. Saya melakukan ini pada hampir semua server kami. File tersebut adalah:

Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters]
"autodisconnect"=dword:ffffffff

Saya memiliki masalah yang sama dan menemukan saya dapat memaksa koneksi ulang dengan "dir x:" sederhana dari baris perintah (di mana X: adalah drive yang dipetakan tetapi terputus.) Ini dari sistem Server 2003 untuk memetakan drive pada XP dan Win7 komputer.

Saya membuat file batch, wake_network_drives.bat, dengan dua baris ini:

    dir x:
    dir z:

dan mengatur tugas yang dijadwalkan untuk menjalankannya setiap malam sebelum program cadangan yang gagal karena drive kadang-kadang ditampilkan sebagai terputus.

Ketik saja:

NET USE H: \\server\share

(di mana H: tentu saja surat pengantar Anda)

Ketik 'NET /? GUNAKAN 'untuk melihat semua opsi yang diberikan perintah ini kepada Anda.

Jika Anda tidak menentang untuk menyimpan kata sandi ini dalam teks biasa dalam satu batch, Anda dapat membuat skrip penghapusan dan pembuatan ulang termasuk kredensial.

net use H: /delete
net use H: \\server\share /user:domain\user password /persistent:yes

Saya tahu itu tidak memenuhi persyaratan Anda untuk tidak menghapus bagian, tetapi itu menyelesaikan akar masalah harus mengingat kata sandi.

TL; ringkasan DR: menggunakan net use dan if exist

Saya mengalami masalah terkait saat membuat skrip cadangan malam hari. Itu harus memeriksa apakah komputer dihidupkan (menggunakan ping), mengirim paket ajaib untuk menyalakannya jika diperlukan (menggunakan MC-WOL ), tunggu Windows untuk boot, kemudian buat koneksi ke share SMB dan tunggu sampai ada.

Sementara jawaban lain di sini luar biasa, saya tidak ingin huruf drive yang dipetakan muncul / tidak ada, atau untuk memutuskan apa pun yang sedang dikerjakan pengguna, juga tidak memiliki jendela Explorer yang berkeliaran. yaitu tujuan tidak ada gangguan pengguna .

Berikut sejumlah kode yang mungkin bermanfaat bagi Anda:

set TARGET_IP=192.168.1.3
set TARGET_PATH=\\%TARGET_IP%\d$\backups
set ATTEMPTS=0

:LOOP

REM Give up eventually
if %ATTEMPTS% GEQ 200 goto NOJOY

REM Wait for IP connectivity to host, and/or burn up a couple seconds before retry
ping -n 1 -w 2000 %TARGET_IP% | find "TTL" > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

REM See if we're already connected, and try to give it a kick
if exist %TARGET_PATH% goto CONNECTED

REM Try to reconnect
net use %TARGET_PATH% > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

:CONNECTED
echo Connected
exit /b

:NOJOY
echo Couldn't connect

Jika Anda suka, Anda dapat mengganti alamat IP di atas dengan nama host (mis. server1 ).

net use diperlukan jika tidak ada koneksi yang ada. Saya mengalami beberapa kasus sudut di mana itu saja tampaknya tidak cukup untuk "membangunkan" saham (mis. Jika ada koneksi sebelumnya ada dalam keadaan terputus). Saya menemukan if exists arahan memiliki efek yang sama dengan alternatif yang disebutkan dalam jawaban lain (seperti pushd, dir, Explorer, dll), tetapi tampaknya pendekatan yang lebih ringan.

Jawaban dari StanZ bekerja untuk saya, tetapi saya harus dapat secara sistematis menentukan drive yang dipetakan tanpa status OK, karena pengguna di domain kami mendapatkan pemetaan drive yang berbeda. Saya kode di sini untuk menjalankan sebagai versi yang berdiri sendiri, yang dijalankan net use sebelum dan sesudah kode aktual, sehingga Anda dapat melihat hasilnya, tetapi Anda hanya perlu menyalinnya FOR pernyataan (tiga baris) ke dalam kode Anda untuk mendapatkan hasil yang diinginkan.

@ECHO OFF
::  
:: revision of answer from StanZ on superuser.com at the following url  
:: https://superuser.com/questions/52595/can-a-mapped-network-drive-be-reconnected-from-the-command-line/367910#367910  
:: https://superuser.com/a/367910  
:: which resulted in my  
::  
:: DriveStatusOK.bat  
:: iCharlieC  
::  
SETLOCAL ENABLEEXTENSIONS  
::  
:: you need only copy the one FOR statement (three lines)  
::   to use in your own code  
::   to force status of mapped network drives to OK  
::  
:: "tokens=1-2 delims=: " is used in the for statement  
:: to output only the drive letter from the output of...  
:: net use  
:: is piped to the first findstr which outputs only lines with drive letters  
::   then piped to another findstr to eliminate drives with a status of OK  
::   then piped to another findstr to get lines that start with a status  
::     -in other words, those lines that the first character is a letter-  
::     -this due to the fact that in our domain we have a drive  
::      that is mapped to a letter, but never has a status.  
::      I do not know the reason for this,  
::      but adding that last findstr prevents me from getting an error  
::      from trying to execute a dir on a non-existant drive letter.-  
::   then dir is executed on each drive letter (after appending ":\" to the letter)  
::      and the output redirected to NUL  
::  
:: run net use before as a visual here  
net use  
::  
FOR /F "tokens=1-2 delims=: " %%i in (  
    'net use ^| findstr ":" ^| findstr /i /v "^OK" ^| findstr /i "^[A-Z]"'  
    ) do dir "%%j:" > NUL  
::  
:: run net use after "waking" drive(s)  
net use  
::  
ENDLOCAL  

Mungkin pertanyaan lama tetapi masih relevan pada 2017 dan Windows 10 karena jaringan berbagi sering tidak terhubung kembali atau dilampirkan dengan benar oleh windows karena berbagai alasan. Berdasarkan masalah ini dan tidak adanya solusi kerja nyata dan penuh kerja nyata saya membuat proyek Github yang berisi Tugas Penjadwal dan VBS yang memecahkan masalah dengan hanya mencoba menyambungkan kembali drive setelah melanjutkan atau masuk jika tidak terhubung atau online.

Script sepenuhnya dapat dikonfigurasi dan dapat diatur tergantung pada kebutuhan pengguna yang sebenarnya.

Jalan ke proyek Github