Bagaimana saya bisa membuat google chrome beralih tab menggunakan roda mouse?

Di rumah saya menjalankan Fedora 17, dan saya sudah terbiasa dengan cepat memindai melalui tab terbuka dengan menggunakan roda mouse sambil melayang di atas bilah tab. Bagi saya, ini adalah sikap yang sangat alami.

Setidaknya seminggu sekali di tempat kerja (biasanya hari Senin), saya mencoba menggunakan teknik yang sama pada chrome yang berjalan di MacBook Pro, tetapi tab tidak mau bergerak. Ini mulai membuatku gila.

Adakah yang punya solusi yang memungkinkan saya menggunakan roda gulir untuk mengubah tab di google chrome untuk OSX?

(Saya menemukan utas kode google berikut, tetapi perbaikan yang disarankan tidak mengatasi masalah sejauh yang saya tahu - http://code.google.com/p/chrome-convenience-extension/issues/detail?id= 31 )

Ekstensi Toolbox Chrome mungkin menarik bagi Anda:

Saya belum mengujinya di OSX tapi itu berfungsi untuk Windows 7 dan seharusnya tidak ada masalah kompatibilitas di sana.

Menemukan solusi di utas Grup Google. Gunakan AutoHotKey dengan skrip berikut:

;; Wheel Scroll Tabs for Google Chrome 

#IfWinActive ahk_class Chrome_WidgetWin_1 
 ~$WheelDown:: 
 ~$WheelUp:: 
    MouseGetPos,, yaxis 
    IfGreater,yaxis,23, Return 
    IfEqual,A_ThisHotkey,~$WheelDown, Send ^{PgDn} 
                                 Else Send ^{PgUp} 
Return 
#IfWinActive

Catatan: Saya telah mengubahnya Chrome_WidgetWin_1karena itulah yang bekerja untuk saya. Jika itu tidak berhasil untuk Anda, coba ubah keChrome_WidgetWin_0

Sumber

Jika Anda menggunakan Chrome 32+ periksa solusi ini dengan AutoHotKey (skrip yang dikompilasi). Chrome Toolbox tidak bekerja di Chrome di atas 31.

https://plus.google.com/115670442023408995787/posts/WYPqqk2j9UB

Atau gunakan langsung:

; Mouse Wheel Tab Scroll 4 Chrome
; -------------------------------
; Scroll though Chrome tabs with your mouse wheel when hovering over the tab bar.
; If the Chrome window is inactive when starting to scroll, it will be activated.

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#Warn   ; Enable warnings to assist with detecting common errors.
#SingleInstance force   ; Determines whether a script is allowed to run again when it is already running.
#UseHook Off    ; Using the keyboard hook is usually preferred for hotkeys - but here we only need the mouse hook.
#InstallMouseHook
#MaxHotkeysPerInterval 1000 ; Avoids warning messages for high speed wheel users.

SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
Menu, Tray, Tip, Mousewheel tab scroll for Chrome (1.0.3)

WheelUp::
WheelDown::
    MouseGetPos,, ypos, id
    WinGetClass, class, ahk_id %id%
    If (ypos < 45 and InStr(class,"Chrome_WidgetWin"))
    {
        IfWinNotActive ahk_id %id%
            WinActivate ahk_id %id%
        If A_ThisHotkey = WheelUp
            Send ^{PgUp}
        Else
            Send ^{PgDn}
    }
    Else
    {
        If A_ThisHotkey = WheelUp
            Send {WheelUp}
        Else
            Send {WheelDown}
    }
    Return

Saya tidak memiliki masalah dengan Chrome / Chromium di Ubuntu, fungsionalitas yang Anda uraikan hanya berfungsi untuk saya. Namun saat ini saya harus menggunakan Chrome di Windows di mana saya melewatkan fungsi ini.

Seperti yang telah disebutkan beberapa orang, ada beberapa implementasi dalam bahasa scripting ² seperti AutoHotKey, yang hanya untuk Windows dan saya tidak pernah merasa perlu menjalankan AutoHotKey, AutoIt atau perangkat lunak serupa lainnya di Linux / OSX; tapi seperti yang saya pahami, AutoKey dan Automator harusnya setara dengan software. Jadi harus dimungkinkan untuk mengimplementasikan kembali pengiriman penekanan tombol dasar dalam bahasa tersebut untuk platform tertentu.

Inilah solusi yang saat ini berfungsi untuk saya: Komunitas AutoHotKey - tab_switcher - alihkan tab dengan roda mouse di jendela tab apa saja

Halo,

di sini ada skrip lain untuk berpindah tab dengan roda mouse - contoh skrip ini adalah untuk Chrome, Firefox dan Internet Explorer, tetapi juga dapat digunakan untuk program lain.

TabJumper(psWindowClass, piStripeYStart, piStripeYEnd)
{
    WinGet, idSearchWindow, ID, ahk_class %psWindowClass%
    MouseGetPos, iMouseX, iMouseY, idHoverWindow
    if (idSearchWindow=idHoverWindow
        && iMouseY>=piStripeYStart
        && iMouseY<=piStripeYEnd ) {

        ControlFocus,, ahk_id %idHoverWindow%
        if RegExMatch(A_ThisHotkey, "i).*wheelup.*")
        {
            ControlSend, ahk_parent, {Control Down}{Shift Down}{Tab Down}, ahk_id %idHoverWindow%
            Sleep, 60
            ControlSend, ahk_parent, {Tab Up}{Shift Up}{Control Up}, ahk_id %idHoverWindow%
        }
        else if RegExMatch(A_ThisHotkey, "i).*wheeldown.*")
        {
            ControlSend, ahk_parent, {Control Down}{Tab Down}, ahk_id %idHoverWindow%
            Sleep, 60
            ControlSend, ahk_parent, {Tab Up}{Control Up}, ahk_id %idHoverWindow%
        }
    }
}

Contoh penggunaan untuk chrome:

#SingleInstance, force

~WheelUp::
    TabJumper("Chrome_WidgetWin_1", 8, 88)
return

~WheelDown::
    TabJumper("Chrome_WidgetWin_1", 8, 88)
return

Parameter menjelaskan:

• TabJumper([Window class], [horizontal reaction stripe y axis start], [[horizontal reaction y axis end]])

  Bagaimana dengan "garis reaksi horizontal" ini?

  Ini berarti hanya dalam strip ini tab jendela diaktifkan, bagian lain dari jendela bereaksi secara normal dengan roda mouse seperti misalnya menggulir ke atas dan ke bawah halaman web.

Penggunaan: Ya, cukup instal Autohotkey, membuat .ahkfile baru , menempelkan kedua blok kode dan menjalankan skrip membawa Anda fungsionalitas. (Markup tambahan ditambahkan oleh saya.)

Untuk membantu memahami: {Control Down}{Shift Down}{Tab Down}dan {Tab Up}{Shift Up}{Control Up}merupakan penekanan tombol, satu adalah urutan untuk menekan dan menahan Crtl+ Shift+ Tab, yang lain untuk melepaskannya. Berikut daftar dengan pintasan keyboard dari Chrome.

1. Saya pribadi lebih suka Firefox daripada Chromium / Chrome di semua perangkat saya, tetapi di tempat kerja produsen perangkat lunak tertentu tidak dapat mempublikasikan ekstensi browser vital sebagai ekstensi Firefox yang ditandatangani (dan MS Edge) untuk produk tertentu. Mengenai perangkat lunak desktop Google, pada saat penulisan sebagian besar lebih rendah di luar teknologi dua puluh sesuatu yang melakukan hal-hal terminal di browser web dengan penggunaan Chromebook dari sudut pandang saya.
2. Menjalankan skrip terpisah untuk fungsionalitas (dasar) ini salah dan berlebihan. Saya sepenuhnya setuju dengan semua orang tentang pendapat itu.

Ada ekstensi chrome sederhana yang memungkinkan Anda untuk menggulir tab dengan alt + roda mouse atas / bawah:

https://chrome.google.com/webstore/detail/tab-wheel-scroll/aknfcgiicpmnfhncpljcadokcghjblal?hl=fr

1. Unduh dan instal Kontrol Tombol X-Mouse .
2. Buka "Pengaturan" dari menu baki.
3. Tambahkan profil baru untuk Chrome. Lihat gambar di bawah ini. String untuk menyalin: chrome.exe, Intermediate D3D Window, Chrome_WidgetWin_1, Google Chrome Tab Scroll.
4. Pilih Simulated Keysuntuk Wheel Up:
5. Masukkan {CTRL}{PGUP}, Periksa opsi "Hanya kirim jika proses profil aktif", dan tekan OK.
6. Ulangi 4 untuk Wheel Down.
7. Ulangi 5 dengan {CTRL}{PGDN}.
8. Klik Terapkan.

Aaa dan kamu sudah selesai 🎉