Cara membuat semua batas tabel tidak terlihat di MS Word setelah menyalin dari HTML

Saya berada dalam situasi di mana saya perlu membuat laporan HTML menjadi laporan kata dengan tidak lebih dari Ctrl+ Catau membukanya dengan Word. Saya berakhir dengan banyak tabel bersarang.

Masalahnya terletak pada kenyataan bahwa CSS memformat tabel dalam HTML sementara dalam dokumen Word mereka dibiarkan dengan batas-batas yang tampak mengerikan, yang perlu tidak terlihat.

Butuh banyak waktu untuk membuat setiap tabel berbatasan tidak terlihat.

Apakah ada cara untuk membuat semua batas setiap tabel dalam dokumen tidak terlihat?

Buat makro di Word menggunakan kode berikut:

Sub SelectAllTables()
    Dim tbl As Table
    Application.ScreenUpdating = False
    For Each tbl In ActiveDocument.Tables
        tbl.Range.Editors.Add wdEditorEveryone
    Next
    ActiveDocument.SelectAllEditableRanges (wdEditorEveryone)
    ActiveDocument.DeleteAllEditableRanges (wdEditorEveryone)
    Application.ScreenUpdating = True
End Sub

Jalankan makro untuk memilih semua tabel, maka Anda dapat mengubah batasnya dalam sekali jalan:

Sunting: Oke, ini harus dapat menangani tabel bersarang secara rekursif juga ke tingkat apa pun:

Sub SelectAllTables()
    Dim tbl As Table
    For Each tbl In ActiveDocument.Tables
        DelTableBorder tbl
    Next
End Sub

Function DelTableBorder(tbl As Table)
    Dim itbl As Table
    tbl.Borders(wdBorderLeft).Visible = False
    tbl.Borders(wdBorderRight).Visible = False
    tbl.Borders(wdBorderTop).Visible = False
    tbl.Borders(wdBorderBottom).Visible = False
    tbl.Borders(wdBorderVertical).Visible = False
    tbl.Borders(wdBorderHorizontal).Visible = False
    tbl.Borders(wdBorderDiagonalUp).Visible = False
    tbl.Borders(wdBorderDiagonalDown).Visible = False
    For Each itbl In tbl.Tables
        DelTableBorder itbl
    Next
End Function