Pintasan di Windows 7 untuk beralih di antara jendela aplikasi yang sama, seperti Cmd + `di OS X

Apakah ada jalan pintas di Windows 7 untuk beralih antar windows di aplikasi yang diberikan saja? Saya sangat menyukai fitur ini di OS X; apa yang setara di Windows?

Jika itu adalah salah satu dari sepuluh aplikasi pertama pada taskbar, maka (Win)+ n, di mana n adalah nomor posisinya, akan memilihnya dan menggilir melalui jendela. (Gunakan 0(nol) untuk aplikasi kesepuluh.) Misalnya, saya menyematkan Windows Explorer dan Internet Explorer sebagai dua hal pertama di taskbar saya, jadi saya dapat menggunakan + 1untuk menelusuri direktori saya dan + 2untuk menelusuri browser saya.

Beberapa catatan aneh:

• Jika Anda menekan dan menahan dan mengetik (dan melepaskan) digit n, Windows akan membuka  aplikasi ke- n di taskbar. Mengetuk berulang kali n akan menggilir melalui jendela program itu, seperti dibahas di atas. Seperti yang  dinyatakan oleh TranslucentCloud , jika Anda kemudian mengetik Shift+ n, itu akan menggilirnya dalam urutan terbalik, seperti dengan Alt+ Tab dan  Ctrl+ Tab, dll.

  Jika aplikasi ke- n pada bilah tugas disematkan tetapi tidak berjalan, maka + nakan memulainya. 

• Tetapi, jika Anda menekan dan menahan danShift, sejak awal, dan kemudian mengetikn, Windows akan memulai contoh baru (atau setidaknya jendela baru) dari aplikasi itu, bahkan jika itu sudah berjalan.   (Ini akan gagal untuk beberapa aplikasi, seperti Windows Media Player, yang tidak memungkinkan beberapa jendela berjalan secara bersamaan.)
• + ntampaknya tidak berfungsi dengan tombol angka.

Di Windows 7 dan 8, meskipun tidak ada pintasan yang saya tahu tersedia dari keyboard saja, Anda dapat menahan Ctrlsambil mengklik ikon bilah tugas dari aplikasi yang Anda minati. Setiap kali Anda melakukan ini jendela yang berbeda milik aplikasi itu akan datang ke garis depan.

Selain itu, program VistaSwitcher mengatur Win+ F11dan Alt+ `untuk beralih di antara jendela aplikasi saat ini. (BTW, situs web-nya mengatakan Windows 8 tidak didukung, tapi saya beruntung di bawah 8.1; satu-satunya masalah yang saya lihat sejauh ini adalah bahwa kadang-kadang daftar hal-hal seperti pencarian sidebar sebagai jendela terbuka. Saya hanya mengabaikan itu, tapi YMMV.)

Anda dapat menggunakan AutoHotkey: www.autohotkey.com

Dan letakkan skrip ini di sana:

!`:: ; Next window
WinGetClass, ActiveClass, A
WinGet, WinClassCount, Count, ahk_class %ActiveClass%
IF WinClassCount = 1
    Return
Else
WinGet, List, List, % "ahk_class " ActiveClass
Loop, % List
{
    index := List - A_Index + 1
    WinGet, State, MinMax, % "ahk_id " List%index%
    if (State <> -1)
    {
        WinID := List%index%
        break
    }
}
WinActivate, % "ahk_id " WinID
return

!^`:: ; Last window
WinGetClass, ActiveClass, A
WinGet, WinClassCount, Count, ahk_class %ActiveClass%
IF WinClassCount = 1
    Return
Else
WinGet, List, List, % "ahk_class " ActiveClass
Loop, % List
{
    index := List - A_Index + 1
    WinGet, State, MinMax, % "ahk_id " List%index%
    if (State <> -1)
    {
        WinID := List%index%
        break
    }
}
WinActivate, % "ahk_id " WinID
return

Bekerja sangat baik untuk saya. Menggunakan Autohotkey, saya juga membuat kunci salin / tempel / undo, ... seperti Mac. Bagus sekali!

Era

Terima kasih, Erasmose, tetapi skrip autohotkey versi Anda akan meminimalkan jendela jika tidak ada jendela lain dari jenis itu. Terkadang Anda tidak tahu, dan meminimalkan adalah cara yang menjengkelkan untuk mencari tahu, jadi saya memodifikasi skrip Anda seperti:

!`::    ; Next window
WinGetClass, ActiveClass, A
WinGet, WinClassCount, Count, ahk_class %ActiveClass%
IF WinClassCount = 1
    Return
Else
WinSet, Bottom,, A
WinActivate, ahk_class %ActiveClass%
return

!+`::    ; Last window
WinGetClass, ActiveClass, A
WinActivateBottom, ahk_class %ActiveClass%
return

oh, dan saya juga mengubah kelas terakhir untuk menggunakan shift daripada ctrl karena saya itulah pengubah untuk mundur dengan beberapa cara pintas keyboard lainnya. Saya suka autohotkey.

Beberapa aplikasi yang menerapkan MDI menyediakan Ctrl + Tab untuk beralih antara "Dokumen" di bawah contoh aplikasi yang sama. misalnya MS Office. Tapi ini bukan fitur windows dan tergantung aplikasi. Untuk perangkat lunak lain ada jalan pintas yang berbeda. misal Firefox tidak menyediakan fitur ini tetapi ada add-on yang menambahkan fungsionalitas.

Selain itu, berikut adalah daftar pintasan keyboard yang disediakan di windows.

Juga, ada diskusi yang ada tentang jalan pintas Keyboard di Windows.

Semoga itu bisa membantu.

Easy Windows Switcher dari Neosmart melakukan apa yang Anda cari.

Berikut adalah deskripsi dari Situs Web Easy Windows Switcher

Easy Window Switcher membuat beralih di antara berbagai jendela semudah alt+`(yaitu alt + backtick) seperti pada Mac. Lupakan keharusan alt+tabantara satu juta dan satu jendela terbuka yang berbeda untuk menemukan jendela yang Anda cari, dengan Easy Window Switcher, menabrak antara jendela program yang sama hanya berjarak alt+`jauh.

VistaSwitcher memungkinkan atau untuk fitur ini. Ini kompatibel dengan Windows 10, (meskipun namanya menunjukkan sebaliknya). Pada Windows 8 ke atas, saya sarankan menambahkan aplikasi metro tertentu ke daftar pengecualian.

Jawaban teratas baik, tetapi tidak berfungsi pada pengaturan multi-monitor di mana bilah tugas diatur untuk hanya menampilkan ikon pada monitor aktif.

Selain apa yang dibagikan Scott ( https://superuser.com/users/150988/scott ):

ctrl+ repeatedly click lebih dari ikon aplikasi di bilah tugas juga akan melakukan pekerjaan.

Dengan AutoHotkey juga, perilaku yang lebih alami:

; Switch between windows of the same application with Alt+(key above Tab)
; Icon: made by Freepik (www.freepik.com), licence CC 3.0 BY
;       from https://www.flaticon.com/free-icon/switch-window_71630
; Script Licence: CC0 (Public Domain)
; Source: https://framagit.org/dr4Ke/AutoHotkey_scripts

KeyName := GetKeyName("sc029")
Menu, Tray, Tip, Switch between windows of the same applications with 'Alt+%KeyName%'

*!SC029::
WinGetClass, ActiveClass, A
WinGet, WinClassCount, Count, ahk_class %ActiveClass%
If WinClassCount = 1
    Return
WinGet, List, List, % "ahk_class " ActiveClass

index := 0
if not GetKeyState("Shift") {
    index := 1
}
;MsgBox, Entering Loop
While GetKeyState("Alt") {
    If GetKeyState("Shift") {
        index := Mod(List + index - 2, List) + 1
    } else {
        index := Mod(List + index, List) + 1
    }
    WinGet, State, MinMax, % "ahk_id " List%index%
    if (State == -1)
    {
        continue
    }
    WinID := List%index%
    WinActivate, % "ahk_id " WinID
    ErrorLevel := 1
    sleep 50
    While (ErrorLevel != 0) and GetKeyState("Alt") {
        KeyWait, sc029, DT1
    }
}
return

Saya membuat skrip AutoHotkey untuk beralih di antara jendela aplikasi yang sama yang berfungsi dengan Aplikasi Jendela biasa , Pintasan Chrome , dan Aplikasi Chrome .

https://github.com/JuanmaMenendez/AutoHotkey-script-Open-Show-Apps/blob/master/AutoHotkey-script-Switch-Windows-same-App.ahk

Tambahan

Dalam repo Github itu ada skrip AutoHotkey lain yang dapat bekerja dengan baik bersama dengan yang satu ini, karena Anda akan dapat Membuka, Memulihkan, atau Meminimalkan Aplikasi Anda menggunakan tombol cepat yang Anda inginkan.

Contoh:

• F7:: OpenOrShowAppBasedOnExeName("C:\Windows\System32\SnippingTool.exe")
• F8:: OpenOrShowAppBasedOnWindowTitle("Gmail", "C:\Program Files (x86)\Google\Chrome\Application\chrome.exe --app=https://mail.google.com/mail/")

Saya membuat skrip AutoHotkey yang terintegrasi dengan baik dengan Windows Task Switcher ( Alt+ Tab), memberikan semua manfaatnya: pratinjau jendela aplikasi, klik untuk memilih, navigasi tombol panah, hanya mengaktifkan satu jendela yang Anda inginkan. Aktifkan / navigasikan dengan Alt+ `dan Alt+ Shift+ `(backtick) untuk menggilir antara jendela yang memiliki nama proses yang sama dengan jendela saat ini. Saya menemukan ini lebih bermanfaat daripada Win+ numkarena berfungsi untuk aplikasi apa pun (daripada harus mengingat nomor slot yang disematkan), pratinjau jendela lebih besar, latar belakangnya tidak kabur, dan bercampur dengan navigasi Alt+ dengan mulus Tab. Diuji pada Windows 10.

Trik utamanya adalah untuk sementara waktu menyembunyikan jendela aplikasi non-target dari Task Switcher dengan mengatur WS_EX_TOOLWINDOWdan membatalkan pengaturan WS_EX_APPWINDOW. Untuk mengatur gaya windows ini pada windows yang berjalan sebagai administrator, AutoHotkey perlu ditandatangani atau dijalankan sebagai admin . Saya mengikuti instruksi penandatanganan yang sangat mudah di sini .

Beberapa utas terkait yang berkontribusi:

• https://stackoverflow.com/questions/35971452/what-is-the-right-way-to-send-alt-tab-in-ahk
• https://autohotkey.com/board/topic/21657-alttab-window-list-get-a-list-of-alt-tab-windows/

!`::
{
   WS_EX_TOOLWINDOW = 0x80
   WS_EX_APPWINDOW = 0x40000
   tw := []
   aw := []

   WinGet, processName, ProcessName, A

   DetectHiddenWindows, Off
   AltTab_window_list(1)

   Loop, %AltTab_ID_List_0%
   {
      wid := AltTab_ID_List_%A_Index%
      WinGet, processName2, ProcessName, ahk_id %wid%

      if (processName2 != processName)
      {
         WinGet, exStyle2, ExStyle, ahk_id %wid%

         if (!(exStyle2 & WS_EX_TOOLWINDOW))
         {
            tw.InsertAt(0, wid)
            WinSet, ExStyle, ^0x80, ahk_id %wid%
         }

         if ((exStyle2 & WS_EX_APPWINDOW))
         {
            aw.InsertAt(0, wid)
            WinSet, ExStyle, ^0x40000, ahk_id %wid%
         }
      }
   }

   Send {Alt Down}{Tab} ; Bring up switcher immediately

   KeyWait, ``, T.25  ; Go to next window; wait .25s before looping
   if (Errorlevel == 0)
   {
      While ( GetKeyState( "Alt","P" ) )
      {
         KeyWait, ``, D T.25
         if (Errorlevel == 0)
         {
            if (GetKeyState( "Shift","P" ))
            {
               Send {Alt Down}{Shift Down}{Tab}
               Sleep, 200
            }
            else
            {
               Send {Alt Down}{Tab}
               Sleep, 200
            }
         }
      }
   }

   Send {Alt Up} ; Close switcher on hotkey release

   for index, wid in tw
   {
      WinSet, ExStyle, ^0x80, ahk_id %wid%
   }

   for index, wid in aw
   {
      WinSet, ExStyle, ^0x40000, ahk_id %wid%
   }
}
return

AltTab_window_list(excludeToolWindows)
{
   global
   WS_EX_CONTROLPARENT =0x10000
   WS_EX_APPWINDOW =0x40000
   WS_EX_TOOLWINDOW =0x80
   WS_DISABLED =0x8000000
   WS_POPUP =0x80000000
   AltTab_ID_List_ =0
   WinGet, Window_List, List,,, Program Manager ; Gather a list of running programs
   id_list =
   Loop, %Window_List%
   {
      wid := Window_List%A_Index%
      WinGetTitle, wid_Title, ahk_id %wid%
      WinGet, Style, Style, ahk_id %wid%

      If ((Style & WS_DISABLED) or ! (wid_Title)) ; skip unimportant windows
         Continue

      WinGet, es, ExStyle, ahk_id %wid%
      Parent := Decimal_to_Hex( DllCall( "GetParent", "uint", wid ) )
      WinGetClass, Win_Class, ahk_id %wid%
      WinGet, Style_parent, Style, ahk_id %Parent%

      If ((excludeToolWindows & (es & WS_EX_TOOLWINDOW))
         or ((es & ws_ex_controlparent) and ! (Style & WS_POPUP) and !(Win_Class ="#32770") and ! (es & WS_EX_APPWINDOW)) ; pspad child window excluded
         or ((Style & WS_POPUP) and (Parent) and ((Style_parent & WS_DISABLED) =0))) ; notepad find window excluded ; note - some windows result in blank value so must test for zero instead of using NOT operator!
         continue
      AltTab_ID_List_ ++
      AltTab_ID_List_%AltTab_ID_List_% :=wid
   }  
   AltTab_ID_List_0 := AltTab_ID_List_
}

Menggunakan Autohotkey, inilah versi saya, yang berfungsi dengan aplikasi Chrome dan Electron. Itu diubah dari jawaban @ user332861 , sehingga membedakan dengan benar antara aplikasi Chrome dan Electron seperti Slack dan Visual Studio Code. (Untuk melakukan itu, ia menggunakan ahk_exebukan ahk_class)

!`::    ; Next window if using alt-backtick
    WinGet, ExeName, ProcessName , A
    WinGet, ExeCount, Count, ahk_exe %ExeName%
    If ExeCount = 1
        Return
    Else
        WinSet, Bottom,, A
        WinActivate, ahk_exe %ExeName%
return

!+`::    ; prev window, Alt+shift+backtick
    WinGet, ExeName, ProcessName , A
    WinActivateBottom, ahk_exe %ExeName%
return

!`::
#`::
WinGet, ExeName, ProcessName, A
WinActivateBottom, ahk_exe %ExeName%
return

Disederhanakan dari jawaban @ otter.pro. Ini hanya siklus mundur melalui jendela aplikasi saat ini. Bersepeda ke depan dapat menyebabkan kilatan singkat dari jendela lain muncul. Karena tidak melihat kilatan mungkin lebih penting daripada bersepeda dua arah, hanya saja jangan berputar ke depan. Lebih jauh lagi, jawaban ini memungkinkan # `sebagai alternatif!` Karena itulah kombinasi kunci untuk pintasan Mac.