Bagaimana cara mengkonfigurasi Firefox melalui skrip?

Saya ingin mengonfigurasi pengaturan Firefox berikut melalui skrip (VBS atau kumpulan)

• beranda bawaan
• mesin pencari default
• nonaktifkan pembaruan otomatis

Apakah ini mungkin?

Anda dapat melakukan ini dengan membuat atau memanipulasi file preferensi Mozilla dengan bahasa skrip pilihan Anda.

Untuk daftar preferensi yang dapat diatur melalui file-file ini, lihat Preferensi Mozilla dan tentang: dokumentasi konfigurasi , meskipun yang sesuai dengan daftar Anda tampaknya: -

• browser.startup.homepage (halaman muka default)
• browser.search.defaultenginename (mesin pencari default)
• app.update.auto (aktifkan / nonaktifkan pembaruan otomatis)

Namun, tergantung pada lingkungan Anda, Anda mungkin merasa lebih baik untuk mendorong pengaturan melalui add-on khusus (lihat komentar XPI di Panduan Singkat untuk Preferensi Mozilla ), atau melalui GPO dengan FirefoxADM atau yang serupa.

Anda dapat mengganti opsi browser pribadi di file user.js di folder profil pengguna. Saya sering menggunakannya untuk mengganti beberapa opsi, misalnya pipelining. Firefox harus dimulai ulang setelah Anda memperbarui user.js. Jika file user.js tidak ada, Anda harus membuatnya.

untuk benar-benar menyalin / menempelkan bagian dari jawaban yang saya cari (win env.)

'C:\Users\User\AppData\Roaming\Mozilla\Firefox\Profiles\#####.default\prefs.js'

Menambahkan

user_pref("browser.startup.homepage", "http://www.URL");

upaya saya untuk menyalin ke mesin jarak jauh dengan jalur Get-Content / cat string.txt / "String" >>, berakhir dengan sampah dimasukkan ke dalam prefs.jsfile karena karakter pelarian dalam string.

cd /D "%APPDATA%\Mozilla\Firefox\Profiles\*.default"

set ffile=%cd%

echo user_pref("browser.startup.homepage", "http://superuser.com");>>"%ffile%\prefs.js"
echo user_pref("browser.search.defaultenginename", "Google");>>"%ffile%\prefs.js"
echo user_pref("app.update.auto", false);>>"%ffile%\prefs.js"
set ffile=

cd %windir%

Utasnya sudah lama, tetapi saya ingin membagikan solusi saya. Semoga ini bisa membantu seseorang. Kami memiliki masalah yang sama dan ingin menambahkan sertifikat dari windows store ke firefox. Jadi saya membuat skrip untuk melakukannya. Bagaimanapun, Anda dapat mengubahnya sesuai kebutuhan Anda: Cukup tambahkan atau hapus baris di :: create cfg_file_name.cfg [...] dan masukkan apa yang Anda butuhkan misalnya untuk memulai beranda dan sebagainya. Ingatlah untuk mengatur ^ sebelum yang terakhir), jika tidak maka ^ tidak akan berfungsi! echo pref("browser.startup.homepage", "http://superuser.com"^);

Sejak versi 49 Anda dapat melakukannya seperti itu:

@echo off
setlocal enabledelayedexpansion
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: MAIN INFORMATION
:: Title: Change about:config entries in Mozilla Firefox
:: Author: I-GaLaXy-I
:: Version: 1.1
:: Last Modified: 10.01.2018
:: Last Modified by: I-GaLaXy-I
::------------------------------------------------------------------------------
:: This script will add two files, which will change about:config parameters of
:: Mozilla Firefox. You can change the name of these two files and remove or add
:: parameters according to your needs. Renaming the files could be essential, if
:: a user creates own files and you don't want to overwrite them.
:: 
:: If the two files already exist and the script is run, the complete content
:: of both files will be overwritten!
::
:: Note: You may have to run it with administrative privileges!
::
:: More information: https://developer.mozilla.org/en-US/Firefox/Enterprise_deployment
:: http://kb.mozillazine.org/Locking_preferences
::------------------------------------------------------------------------------
:: Subtitle: Import CAs from Windows certificate store
:: More information: https://serverfault.com/questions/722563/how-to-make-firefox-trust-system-ca-certificates
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Set the name of the .cfg file
set cfg_file_name=add_win_certstore_cas

:: Set the name of the .js file
set js_file_name=add_win_certstore_cas

:: Registry keys to check for the installation path of Mozilla Firefox
set regkey1="HKEY_LOCAL_MACHINE\SOFTWARE\MICROSOFT\Windows\CurrentVersion\App Paths\firefox.exe" /v "Path"
set regkey2="HKEY_LOCAL_MACHINE\SOFTWARE\Clients\StartMenuInternet\FIREFOX.EXE\shell\open\command" /ve

:: Get installation path of Mozilla Firefox (if not found exit script):
reg query %regkey1%
if %errorlevel%==0 (
    :: First key found, getting path
    for /f "tokens=2* delims=    " %%a in ('reg query %regkey1%') do set path_firefox=%%b
) else (
    :: If first key not found, try another one:
    reg query %regkey2%
    if !errorlevel!==0 (
        for /f "tokens=2* delims=    " %%a in ('reg query %regkey2%') do set path_firefox=%%b
        set path_firefox=!path_firefox:\firefox.exe=!
        for /f "useback tokens=*" %%a in ('!path_firefox!') do set path_firefox=%%~a
) else (
    :: No key found, exit script
    exit
))

:: Create cfg_file_name.cfg if it doesn't exist and input the following lines.
:: Caution! If cfg_file_name.cfg already exists, all lines will be overwritten!
:: Add more lines as needed with the following syntax: 
::echo pref("<name_of_config_entry>", <value>^);
(
    echo //Firefox Settings rolled out via KACE from Systec
    echo //Do not manually edit this file because it will be overwritten!
    echo //Import CAs that have been added to the Windows certificate store by an user or administrator.
    echo pref("security.enterprise_roots.enabled", true^);
) > "%path_firefox%\%cfg_file_name%.cfg"

:: Create js_file_name.js if it doesn't exist and input the following lines.
:: Caution! If js_file_name.js already exists, all lines will be overwritten!
(
    echo /* Firefox Settings rolled out via KACE from Systec
    echo Do not manually edit this file because it will be overwritten! */
    echo pref("general.config.obscure_value", 0^);
    echo pref("general.config.filename", "%cfg_file_name%.cfg"^);
) > "%path_firefox%\defaults\pref\%js_file_name%.js"

:: Files created, exit
exit