Pindahkan seluruh baris ke atas dan ke bawah di Vim

Di Notepad ++, saya bisa menggunakan Ctrl+ Shift+ Up/ Downuntuk memindahkan garis saat ini ke atas dan ke bawah. Apakah ada perintah yang mirip dengan ini di Vim? Saya telah melihat melalui panduan yang tak ada habisnya, tetapi tidak menemukan apa pun.

Jika tidak ada, bagaimana saya bisa mengikat tindakan ke kombinasi tombol itu?

Sunting: Jawaban Mykola bekerja untuk semua baris, selain yang ada di awal dan akhir buffer. Memindahkan garis pertama ke atas atau garis bawah ke bawah menghapus garis, dan ketika memindahkan garis bawah ke atas itu melompat dua spasi pada awalnya, seperti pion! Adakah yang bisa menawarkan perbaikan?

Masukkan berikut ini ke .vimrc Anda untuk melakukan pekerjaan

noremap <c-s-up> :call feedkeys( line('.')==1 ? '' : 'ddkP' )<CR>
noremap <c-s-down> ddp

Menghilangnya garis itu tampak seperti bug Vim. Saya menaruh retasan untuk menghindarinya. Mungkin ada beberapa solusi yang lebih akurat.

Memperbarui

Ada banyak kesulitan yang tidak dapat dijelaskan dengan hanya menggunakan kombinasi Vim. Ini adalah garis yang hilang dan garis melompat ekstra.

Jadi di sini adalah solusi scripting yang dapat ditempatkan di dalam .vimrc atau ~ / .vim / plugin / swap_lines.vim

function! s:swap_lines(n1, n2)
    let line1 = getline(a:n1)
    let line2 = getline(a:n2)
    call setline(a:n1, line2)
    call setline(a:n2, line1)
endfunction

function! s:swap_up()
    let n = line('.')
    if n == 1
        return
    endif

    call s:swap_lines(n, n - 1)
    exec n - 1
endfunction

function! s:swap_down()
    let n = line('.')
    if n == line('$')
        return
    endif

    call s:swap_lines(n, n + 1)
    exec n + 1
endfunction

noremap <silent> <c-s-up> :call <SID>swap_up()<CR>
noremap <silent> <c-s-down> :call <SID>swap_down()<CR>

Jika saya ingin menukar satu baris dengan baris di atas, saya biasanya melakukan hal berikut

ddkP

Penjelasan

• dd akan menghapus baris dan menambahkannya ke register default.
• k akan bergerak ke atas garis (j akan pindah ke bawah garis)
• P akan menempel di atas garis saat ini

Dengan asumsi kursor berada pada garis yang ingin Anda pindahkan.

Bergerak ke atas dan ke bawah: :muntuk bergerak

:m +1 - bergerak ke bawah 1 baris

:m -2 - naik 1 baris

(Catatan Anda dapat mengganti +1 dengan angka apa saja tergantung pada berapa banyak garis yang ingin Anda pindahkan ke atas atau ke bawah, yaitu +2 akan memindahkannya ke bawah 2 baris, -3 akan memindahkannya ke atas 2 baris)

Untuk pindah ke jalur tertentu

:set number - menampilkan garis angka (lebih mudah untuk melihat ke mana Anda memindahkannya)

:m 3 - pindahkan garis setelah garis ke-3 (ganti 3 ke garis yang Anda inginkan)

Memindahkan banyak baris:

V(ie Shift- V) dan gerakkan courser ke atas dan ke bawah untuk memilih beberapa baris dalam VIM

sekali dipilih tekan :dan jalankan perintah di atas, m +1dll

Pindahkan garis ke atas: ddkP

Pindahkan garis ke bawah: ddp

Ini bekerja untuk saya:

http://vim.wikia.com/wiki/Moving_lines_up_or_down_in_a_file

BTW, jika Anda ingin menggunakan ALT + some_key dan terminal Anda (urxvt melakukan ini) menolak untuk mematuhi, Anda harus memasukkan sesuatu seperti ini di .vimrc Anda:

" For moving lines (^] is a special character; use <M-k> and <M-j> if it works)
nnoremap ^]k mz:m-2<CR>`z==
inoremap ^]j <Esc>:m+<CR>==gi
inoremap ^]k <Esc>:m-2<CR>==gi
vnoremap ^]j :m'>+<CR>gv=`<my`>mzgv`yo`z
nnoremap ^]j mz:m+<CR>`z==
vnoremap ^]k :m'<-2<CR>gv=`>my`<mzgv`yo`z

di mana ^] adalah karakter tunggal yang mewakili kunci ALT. Untuk memasukkan karakter itu, gunakan C+v, Escdalam Vim ( C+q, Escpada Windows).

tambahkan berikut ini ke file ~ / .vimrc (pastikan Anda tidak memiliki pemetaan untuk n, m)

nmap n :m +1<CR>
nmap m :m -2<CR>

sekarang menekan ntombol akan memindahkan garis ke bawah dan makan memindahkan garis ke atas.

Dalam mode perintah, posisikan kursor pada baris yang Anda inginkan untuk bergerak ke bawah, dan kemudian

ddp

Penjelasan: dd menghapus baris saat ini ke buffer umum p mengembalikannya SETELAH posisi kursor, atau dalam kasus seluruh baris, satu baris di bawah ini.

Ada beberapa kebingungan tentang perintah p dan P di banyak dokumen. Pada kenyataannya, p pasta setelah kursor, dan kursor P AT.

Cukup tambahkan kode ini ke .vimrc (atau .gvimrc)

nnoremap <A-j> :m+<CR>==
nnoremap <A-k> :m-2<CR>==
inoremap <A-j> <Esc>:m+<CR>==gi
inoremap <A-k> <Esc>:m-2<CR>==gi
vnoremap <A-j> :m'>+<CR>gv=gv
vnoremap <A-k> :m-2<CR>gv=gv

Tepat seperti yang Anda cari dalam plugin yang luar biasa ini: https://github.com/vim-scripts/upAndDown

Sebuah solusi sederhana adalah untuk dimasukkan ke dalam Anda .vimrcbaris-baris:

nmap <C-UP> :m-2<CR>  
nmap <C-DOWN> :m+1<CR>

Saya meletakkan yang berikut ini di akhir file .vimrc saya:

noremap H ddkkp
noremap N ddp

Jadi sekarang 'H' dan 'N' memindahkan garis saat ini ke atas dan ke bawah masing-masing.

Berikut adalah versi yang disederhanakan, untuk MacVim, menggunakan contoh artikel Wikia (lih. Tautan dari komentar gun ).

" Move selection up/down (add =gv to reindent after move)
:vmap <D-S-Up> :m-2<CR>gv
:vmap <D-S-Down> :m'>+<CR>gv

Saya hanya menggunakan varian pemilihan blok, karena yang diperlukan hanyalah Shift-V untuk memilih garis saat ini, dan secara opsional kursor naik / turun untuk memilih beberapa garis lagi.

Menurut pintasan di atas, menekan Cmd-Shift-Atas / Bawah akan menggeser pemilihan blok ke atas / bawah. "D" adalah kunci Command di MacVim, untuk Windows coba "C" (Control), atau "A" (Alt) (mis. <CAf> akan menjadi Control Alt f).

Artikel Wikia menambahkan "= gv" pada ini, yang memiliki efek untuk menyesuaikan lekukan blok setelah pindah, berdasarkan teks di sekitarnya. Ini membingungkan jadi saya menghapusnya, dan menambahkan pintasan untuk dengan cepat membuat indentasi pemilihan.

" Indent selection left/right (Cmd Shift Left/Right is used for Tab switching)
:vmap <D-A-Left> <gv
:vmap <D-A-Right> >gv

Pikiran, hal yang sama dapat dilakukan dengan << dan >> tetapi pemilihan akan hilang, jadi pintasan di atas memungkinkan untuk indentasi beberapa kali dan masih memindahkan blok sekitar karena pemilihan dipertahankan.

MacVim saya dikonfigurasi untuk beralih Tab dengan Cmd-Shift-Kiri / Kanan jadi saya menggunakan Cmd-Alt-Kiri / Kanan.

Inilah Tab switching untuk MacVim (masukkan .gvimrc dengan sisanya di atas):

:macm Window.Select\ Previous\ Tab key=<D-S-Left>
:macm Window.Select\ Next\ Tab key=<D-S-Right>

plugin vim unimpaired.vim [e and] e

Ketika anda menekan perintah :help movedi vim, di sini adalah hasilnya:

:[range]m[ove] {address} *:m* *:mo* *:move* *E134* Move the lines given by [range] to below the line given by {address}.

Misalnya: Pindahkan baris saat ini satu baris ke bawah => :m+1 .

Misalnya: Pindahkan garis dengan angka 100 di bawah garis dengan angka 80 => :100 m 80 .

Misalnya: Pindahkan garis dengan angka 100 di bawah garis dengan angka 200 => :100 m 200 .

Misalnya: Pindahkan garis dengan angka dalam [100, 120] di bawah garis dengan angka 200 => :100,120 m 200 .

Berikut adalah solusi yang berfungsi pada komputer saya : MacBook Pro menjalankan VIM 8.1

Perintah-perintah ini tidak akan menghapus baris Anda di bagian atas atau bawah buffer Anda.

Menggunakan simbol aktual yang dihasilkan Alt-J dan Alt-K adalah solusi untuk kode-kunci mereka yang tidak memetakan dengan benar di lingkungan saya.

Lemparkan ini di .vimrc lama dan lihat apakah itu cocok untuk Anda.

" Maps Alt-J and Alt-K to macros for moving lines up and down
" Works for modes: Normal, Insert and Visual
nnoremap ∆ :m .+1<CR>==
nnoremap ˚ :m .-2<CR>==
inoremap ∆ <Esc>:m .+1<CR>==gi
inoremap ˚ <Esc>:m .-2<CR>==gi
vnoremap ∆ :m '>+1<CR>gv=gv
vnoremap ˚ :m '<-2<CR>gv=gv

Bagi saya, ddkkpmelakukannya (bukan ddkPdengan P huruf besar, yang akan berhasil juga).

: m. +1 atau: m.-2 akan dilakukan jika Anda memindahkan satu baris. Inilah skrip saya untuk memindahkan banyak baris. Dalam mode visual, Alt-up / Alt-down akan memindahkan garis yang berisi pemilihan visual naik / turun satu baris. Dalam mode insert atau mode normal, Alt-up / Alt-down akan memindahkan garis saat ini jika tidak ada awalan hitungan yang diberikan. Jika ada awalan hitungan, Alt-up / Alt-down akan memindahkan banyak baris mulai dari baris saat ini naik / turun dengan satu baris.

function! MoveLines(offset) range
    let l:col = virtcol('.')
    let l:offset = str2nr(a:offset)
    exe 'silent! :' . a:firstline . ',' . a:lastline . 'm'
        \ . (l:offset > 0 ? a:lastline + l:offset : a:firstline + l:offset)
    exe 'normal ' . l:col . '|'
endf

imap <silent> <M-up> <C-O>:call MoveLines('-2')<CR>
imap <silent> <M-down> <C-O>:call MoveLines('+1')<CR>
nmap <silent> <M-up> :call MoveLines('-2')<CR>
nmap <silent> <M-down> :call MoveLines('+1')<CR>
vmap <silent> <M-up> :call MoveLines('-2')<CR>gv
vmap <silent> <M-down> :call MoveLines('+1')<CR>gv

Jika Anda ingin melakukan ini pada beberapa baris yang cocok dengan pencarian tertentu:

• Atas: :g/Your query/ normal ddpatau:g/Your query/ m -1
• Turun :g/Your query/ normal ddpatau:g/Your query/ m +1