Cara mudah untuk mencetak Perl array? (dengan sedikit format)

Apakah ada cara mudah untuk mencetak larik Perl dengan koma di antara setiap elemen?

Menulis perulangan for untuk melakukannya cukup mudah tetapi tidak cukup elegan .... jika itu masuk akal.

Gunakan saja join():

# assuming @array is your array:
print join(", ", @array);

Anda dapat menggunakan Data::Dump:

use Data::Dump qw(dump);
my @a = (1, [2, 3], {4 => 5});
dump(@a);

Menghasilkan:

"(1, [2, 3], { 4 => 5 })"

Jika Anda membuat kode untuk jenis kejelasan yang akan dipahami oleh seseorang yang baru memulai dengan Perl, konsep tradisional ini menjelaskan artinya, dengan tingkat kejelasan dan keterbacaan yang tinggi:

$string = join ', ', @array;
print "$string\n";

Konstruksi ini didokumentasikan di perldoc -fjoin .

Namun, saya selalu menyukai betapa sederhana $,membuatnya. Variabel khusus $"untuk interpolasi, dan variabel khusus $,untuk daftar. Gabungkan salah satu dengan pembatasan lingkup dinamis ' local' untuk menghindari efek riak di seluruh skrip:

use 5.012_002;
use strict;
use warnings;

my @array = qw/ 1 2 3 4 5 /;

{
    local $" = ', ';
    print "@array\n"; # Interpolation.
}

ATAU dengan $ ,:

use feature q(say);
use strict;
use warnings;

my @array = qw/ 1 2 3 4 5 /;
{
    local $, = ', ';
    say @array; # List
}

Variabel khusus $,dan $"didokumentasikan dalam perlvar . Kata localkunci, dan bagaimana dapat digunakan untuk membatasi efek mengubah nilai variabel tanda baca global mungkin paling baik dijelaskan di perlsub .

Nikmati!

Juga, Anda mungkin ingin mencoba Data :: Dumper . Contoh:

use Data::Dumper;

# simple procedural interface
print Dumper($foo, $bar);

Untuk pemeriksaan / debugging, periksa Data::Printermodulnya. Ini dimaksudkan untuk melakukan satu hal dan hanya satu hal:

menampilkan variabel Perl dan objek di layar, diformat dengan benar (untuk diperiksa oleh manusia)

Contoh penggunaan:

use Data::Printer;  
p @array;  # no need to pass references

Kode di atas mungkin menghasilkan sesuatu seperti ini (dengan warna!):

   [
       [0] "a",
       [1] "b",
       [2] undef,
       [3] "c",
   ]

Anda bisa printmelakukannya.

@a = qw(abc def hij);

print "@a";

Anda akan mendapatkan:

abc def hij

# better than Dumper --you're ready for the WWW....

use JSON::XS;
print encode_json \@some_array

Menggunakan Data::Dumper:

use strict;
use Data::Dumper;

my $GRANTstr = 'SELECT, INSERT, UPDATE, DELETE, LOCK TABLES, EXECUTE, TRIGGER';
$GRANTstr    =~ s/, /,/g;
my @GRANTs   = split /,/ , $GRANTstr;

print Dumper(@GRANTs) . "===\n\n";

print Dumper(\@GRANTs) . "===\n\n";

print Data::Dumper->Dump([\@GRANTs], [qw(GRANTs)]);

Menghasilkan tiga gaya keluaran yang berbeda:

$VAR1 = 'SELECT';
$VAR2 = 'INSERT';
$VAR3 = 'UPDATE';
$VAR4 = 'DELETE';
$VAR5 = 'LOCK TABLES';
$VAR6 = 'EXECUTE';
$VAR7 = 'TRIGGER';
===

$VAR1 = [
          'SELECT',
          'INSERT',
          'UPDATE',
          'DELETE',
          'LOCK TABLES',
          'EXECUTE',
          'TRIGGER'
        ];
===

$GRANTs = [
            'SELECT',
            'INSERT',
            'UPDATE',
            'DELETE',
            'LOCK TABLES',
            'EXECUTE',
            'TRIGGER'
          ];

Ini mungkin bukan yang Anda cari, tapi inilah yang saya lakukan untuk sebuah tugas:

$" = ", ";
print "@ArrayName\n";

Peta juga dapat digunakan, tetapi terkadang sulit dibaca saat Anda memiliki banyak hal.

map{ print "element $_\n" }   @array; 

Tapi aku belum mencoba lari di bawah. Saya pikir ini cara yang rumit.

map{print $_;} @array;