Bagaimana cara menguji apakah ada executable di% PATH% dari file batch windows?

Saya mencari cara sederhana untuk menguji apakah ada yang dapat dieksekusi di variabel lingkungan PATH dari file batch Windows.

Penggunaan alat eksternal yang tidak disediakan oleh OS tidak diperbolehkan. Versi Windows minimal yang dibutuhkan adalah Windows XP.

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X)
if defined FOUND ...

Jika Anda memerlukan ini untuk ekstensi yang berbeda, cukup ulangi PATHEXT:

set FOUND=
for %%e in (%PATHEXT%) do (
  for %%X in (myExecutable%%e) do (
    if not defined FOUND (
      set FOUND=%%~$PATH:X
    )
  )
)

Mungkin itu wherejuga sudah ada di versi Windows lama, tetapi saya tidak memiliki akses ke salah satunya, jadi saya tidak tahu. Di mesin saya hal berikut juga berfungsi:

where myExecutable

dan kembali dengan kode keluar bukan nol jika tidak dapat ditemukan. Namun, dalam batch, Anda mungkin juga ingin mengalihkan output ke NUL.

Mengingat

Parsing dalam .batfile batch ( ) dan pada baris perintah berbeda (karena file batch memiliki %0- %9), jadi Anda harus menggandakannya %. Pada baris perintah ini tidak perlu, jadi untuk variabel hanya %X.

Windows Vista dan versi yang lebih baru dikirimkan dengan program yang disebut where.exeyang mencari program di jalur. Ini bekerja seperti ini:

D:\>where notepad
C:\Windows\System32\notepad.exe
C:\Windows\notepad.exe

D:\>where where
C:\Windows\System32\where.exe

Untuk digunakan dalam file batch Anda dapat menggunakan /qsakelar, yang hanya mengatur ERRORLEVELdan tidak menghasilkan output apa pun.

where /q myapplication
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH.
    EXIT /B
) ELSE (
    ECHO Application exists. Let's go!
)

Atau versi singkat sederhana (tapi kurang terbaca) yang mencetak pesan dan keluar dari aplikasi Anda:

where /q myapplication || ECHO Cound not find app. && EXIT /B

Berikut adalah solusi sederhana yang mencoba menjalankan aplikasi dan menangani kesalahan apa pun sesudahnya .

file.exe /?  2> NUL
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path

Kode kesalahan 9009 biasanya berarti file tidak ditemukan.

Satu-satunya downside adalah yang file.exebenar-benar dieksekusi jika ditemukan (yang dalam beberapa kasus tidak dapat diterima).

Ini dapat dilakukan melalui substitusi parameter.

%~$PATH:1

Ini mengembalikan jalur lengkap dari nama file yang dapat dieksekusi di% 1, jika tidak string kosong.

Ini tidak berfungsi dengan variabel buatan pengguna. Jadi jika nama file yang dapat dieksekusi bukan merupakan parameter untuk skrip Anda, maka Anda memerlukan subrutin. Sebagai contoh:

call :s_which app.exe
if not "%_path%" == "" (
  "%_path%"
)

goto :eof

:s_which
  setlocal
  endlocal & set _path=%~$PATH:1
  goto :eof

Lihat http://ss64.com/nt/syntax-args.html

@echo off
set found=
set prog=cmd.exe
for %%i in (%path%) do if exist %%i\%prog% set found=%%i
echo "%found%"
if "%found%"=="" ....

Terkadang solusi sederhana ini berfungsi, di mana Anda memeriksa untuk melihat apakah hasilnya cocok dengan yang Anda harapkan. Baris pertama menjalankan perintah dan mengambil baris terakhir dari keluaran standar.

FOR /F "tokens=*" %%i in (' "xcopy /? 2> nul" ') do SET xcopyoutput=%%i
if "%xcopyoutput%"=="" echo xcopy not in path.

Jika Anda mencari sesuatu seperti saya di folder startup, harus pergi folder. Misalnya saya mencari exe di folder startup dan saya menggunakan kode ini seperti

@echo off
cd C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
where /q program.exe
IF ERRORLEVEL 1 (
echo F | xcopy /Y /S /I /E "\\programsetup\programsetup.exe" 
"C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\program.exe"
) ELSE (
ECHO Application exists. Let's go!
)

Gunakan perintah: PowerShell Test-Path "exe yang Anda cari"

Ini akan mengembalikan True jika ada, jika tidak Salah.

Bagi mereka yang mencari opsi PowerShell. Anda dapat menggunakan Get-Commandcmdlet dengan melewatkan dua item. Pertama berikan lokasi dir saat ini dengan .\awalan, lalu berikan nama exe saja.

(Get-Command ".\notepad", "notepad" -ErrorAction Ignore -CommandType Application) -ne $null

Itu akan mengembalikan nilai true jika ditemukan lokal atau di jalur lebar sistem.