Mencetak semuanya kecuali bidang pertama dengan awk

Saya memiliki file yang terlihat seperti ini:

AE  United Arab Emirates
AG  Antigua & Barbuda
AN  Netherlands Antilles
AS  American Samoa
BA  Bosnia and Herzegovina
BF  Burkina Faso
BN  Brunei Darussalam

Dan saya ingin membalik pesanan, pertama-tama mencetak semuanya kecuali $ 1 lalu $ 1:

United Arab Emirates AE

Bagaimana saya bisa melakukan trik "semuanya kecuali bidang 1"?

Penetapan $1berfungsi tetapi akan meninggalkan ruang utama:awk '{first = $1; $1 = ""; print $0, first; }'

Anda juga dapat menemukan jumlah kolom dalam NFdan menggunakannya dalam satu lingkaran.

$1=""sisakan ruang seperti yang disebutkan Ben Jackson, jadi gunakan forloop:

awk '{for (i=2; i<=NF; i++) print $i}' filename

Jadi jika string Anda adalah "satu dua tiga", hasilnya akan menjadi:

dua
tiga

Jika Anda menginginkan hasil dalam satu baris, Anda dapat melakukan hal berikut:

awk '{for (i=2; i<NF; i++) printf $i " "; print $NF}' filename

Ini akan memberi Anda: "dua tiga"

Gunakan cutperintah dengan --complementopsi:

$ echo a b c | cut -f 1 -d ' '
a
$ echo a b c | cut -f 1,2 -d ' '
a b
$ echo a b c | cut -f 1 -d ' ' --complement
b c

Mungkin cara paling ringkas:

$ awk '{$(NF+1)=$1;$1=""}sub(FS,"")' infile
United Arab Emirates AE
Antigua & Barbuda AG
Netherlands Antilles AN
American Samoa AS
Bosnia and Herzegovina BA
Burkina Faso BF
Brunei Darussalam BN

Penjelasan:

$(NF+1)=$1: Generator kolom terakhir "baru".

$1="": Setel bidang pertama yang asli ke nol

sub(FS,""): Setelah dua tindakan pertama {$(NF+1)=$1;$1=""}singkirkan pemisah bidang pertama dengan menggunakan sub. Hasil cetak terakhir tersirat.

awk '{sub($1 FS,"")}7' YourFile

Hapus bidang pertama dan pemisah, dan cetak hasilnya ( 7adalah nilai bukan nol jadi mencetak $ 0).

awk '{ saved = $1; $1 = ""; print substr($0, 2), saved }'

Menyetel bidang pertama untuk ""menyisakan satu salinan OFSdi awal $0. Dengan asumsi itu OFShanya satu karakter (secara default, itu adalah satu spasi), kita dapat menghapusnya dengan substr($0, 2). Kemudian kami menambahkan salinan yang disimpan dari $1.

Jika Anda terbuka untuk solusi Perl ...

perl -lane 'print join " ",@F[1..$#F,0]' file

adalah solusi sederhana dengan pemisah input / output satu spasi, yang menghasilkan:

United Arab Emirates AE
Antigua & Barbuda AG
Netherlands Antilles AN
American Samoa AS
Bosnia and Herzegovina BA
Burkina Faso BF
Brunei Darussalam BN

Yang berikut ini sedikit lebih kompleks

perl -F`  ` -lane 'print join "  ",@F[1..$#F,0]' file

dan mengasumsikan bahwa pemisah input / output adalah dua spasi:

United Arab Emirates  AE
Antigua & Barbuda  AG
Netherlands Antilles  AN
American Samoa  AS
Bosnia and Herzegovina  BA
Burkina Faso  BF
Brunei Darussalam  BN

Opsi baris perintah ini digunakan:

• -n memutar di sekitar setiap baris file input, jangan mencetak setiap baris secara otomatis

• -l menghapus baris baru sebelum diproses, dan menambahkannya kembali setelahnya

• -amode autosplit - memisahkan baris input ke dalam larik @F. Secara default, pemisahan di spasi kosong

• -F pengubah pemisahan otomatis, dalam contoh ini dibagi menjadi '' (dua spasi)

• -e jalankan kode perl berikut

@Fadalah larik kata di setiap baris, diindeks mulai dengan 0
$#Fadalah jumlah kata dalam @F
@F[1..$#F]potongan larik elemen 1 sampai elemen terakhir
@F[1..$#F,0]adalah irisan larik elemen 1 sampai elemen terakhir ditambah elemen 0

Pemisah bidang di gawk (setidaknya) bisa berupa string serta karakter (bisa juga berupa regex). Jika data Anda konsisten, ini akan berfungsi:

awk -F "  " '{print $2,$1}' inputfile

Itu dua spasi di antara tanda kutip ganda.

awk '{ tmp = $1; sub(/^[^ ]+ +/, ""); print $0, tmp }'

Mari pindahkan semua record ke record berikutnya dan atur yang terakhir sebagai yang pertama:

$ awk '{a=$1; for (i=2; i<=NF; i++) $(i-1)=$i; $NF=a}1' file
United Arab Emirates AE
Antigua & Barbuda AG
Netherlands Antilles AN
American Samoa AS
Bosnia and Herzegovina BA
Burkina Faso BF
Brunei Darussalam BN

Penjelasan

• a=$1 simpan nilai pertama ke dalam variabel sementara.
• for (i=2; i<=NF; i++) $(i-1)=$i simpan nilai bidang ke-N ke dalam bidang (N-1).
• $NF=asimpan nilai pertama ( $1) ke dalam bidang terakhir.
• {}1Kondisi benar untuk make awkmelakukan tindakan default: {print $0}.

Dengan cara ini, jika Anda kebetulan memiliki pemisah bidang lain, hasilnya juga bagus:

$ cat c
AE-United-Arab-Emirates
AG-Antigua-&-Barbuda
AN-Netherlands-Antilles
AS-American-Samoa
BA-Bosnia-and-Herzegovina
BF-Burkina-Faso
BN-Brunei-Darussalam

$ awk 'BEGIN{OFS=FS="-"}{a=$1; for (i=2; i<=NF; i++) $(i-1)=$i; $NF=a}1' c
United-Arab-Emirates-AE
Antigua-&-Barbuda-AG
Netherlands-Antilles-AN
American-Samoa-AS
Bosnia-and-Herzegovina-BA
Burkina-Faso-BF
Brunei-Darussalam-BN

Tusukan pertama tampaknya berhasil untuk kasus khusus Anda.

awk '{ f = $1; i = $NF; while (i <= 0); gsub(/^[A-Z][A-Z][ ][ ]/,""); print $i, f; }'

Pilihan 1

Ada solusi yang berfungsi dengan beberapa versi awk:

awk '{ $(NF+1)=$1;$1="";$0=$0;} NF=NF ' infile.txt

Penjelasan:

       $(NF+1)=$1                          # add a new field equal to field 1.
                  $1=""                    # erase the contents of field 1.
                        $0=$0;} NF=NF      # force a re-calc of fields.
                                           # and use NF to promote a print.

Hasil:

United Arab Emirates AE
Antigua & Barbuda AG
Netherlands Antilles AN
American Samoa AS
Bosnia and Herzegovina BA
Burkina Faso BF
Brunei Darussalam BN

Namun itu mungkin gagal dengan versi awk yang lebih lama.

pilihan 2

awk '{ $(NF+1)=$1;$1="";sub(OFS,"");}1' infile.txt

Itu adalah:

awk '{                                      # call awk.
       $(NF+1)=$1;                          # Add one trailing field.
                  $1="";                    # Erase first field.
                        sub(OFS,"");        # remove leading OFS.
                                    }1'     # print the line.

Perhatikan bahwa yang perlu dihapus adalah OFS, bukan FS. Garis akan dihitung ulang saat bidang $ 1 ditentukan. Itu mengubah semua proses FS menjadi salah satu OFS.

Tetapi bahkan opsi itu masih gagal dengan beberapa pembatas, seperti yang ditunjukkan secara jelas dengan mengubah OFS:

awk -v OFS=';' '{ $(NF+1)=$1;$1="";sub(OFS,"");}1' infile.txt

Baris itu akan menampilkan:

United;Arab;Emirates;AE
Antigua;&;Barbuda;AG
Netherlands;Antilles;AN
American;Samoa;AS
Bosnia;and;Herzegovina;BA
Burkina;Faso;BF
Brunei;Darussalam;BN

Itu menunjukkan bahwa run dari FS sedang diubah menjadi salah satu OFS.
Satu-satunya cara untuk menghindarinya adalah dengan menghindari penghitungan ulang bidang.
Salah satu fungsi yang dapat menghindari penghitungan ulang adalah sub.
Bidang pertama dapat diambil gambarnya, lalu dihapus dari $ 0 dengan sub, dan kemudian keduanya dicetak ulang.

Pilihan 3

awk '{ a=$1;sub("[^"FS"]+["FS"]+",""); print $0, a;}' infile.txt
       a=$1                                   # capture first field.
       sub( "                                 # replace: 
             [^"FS"]+                         # A run of non-FS
                     ["FS"]+                  # followed by a run of FS.
                            " , ""            # for nothing.
                                  )           # Default to $0 (the whole line.
       print $0, a                   # Print in reverse order, with OFS.


United Arab Emirates AE
Antigua & Barbuda AG
Netherlands Antilles AN
American Samoa AS
Bosnia and Herzegovina BA
Burkina Faso BF
Brunei Darussalam BN

Bahkan jika kita mengubah FS, OFS dan / atau menambahkan lebih banyak pembatas, itu berhasil.
Jika file input diubah menjadi:

AE..United....Arab....Emirates
AG..Antigua....&...Barbuda
AN..Netherlands...Antilles
AS..American...Samoa
BA..Bosnia...and...Herzegovina
BF..Burkina...Faso
BN..Brunei...Darussalam

Dan perintah berubah menjadi:

awk -vFS='.' -vOFS=';' '{a=$1;sub("[^"FS"]+["FS"]+",""); print $0,a;}' infile.txt

Outputnya adalah (masih mempertahankan pembatas):

United....Arab....Emirates;AE
Antigua....&...Barbuda;AG
Netherlands...Antilles;AN
American...Samoa;AS
Bosnia...and...Herzegovina;BA
Burkina...Faso;BF
Brunei...Darussalam;BN

Perintah dapat diperluas ke beberapa bidang, tetapi hanya dengan awks modern dan dengan opsi --re-interval active. Perintah ini pada file asli:

awk -vn=2 '{a=$1;b=$2;sub("([^"FS"]+["FS"]+){"n"}","");print $0,a,b;}' infile.txt

Akan menampilkan ini:

Arab Emirates AE United
& Barbuda AG Antigua
Antilles AN Netherlands
Samoa AS American
and Herzegovina BA Bosnia
Faso BF Burkina
Darussalam BN Brunei

Jika Anda terbuka untuk solusi Perl lain:

perl -ple 's/^(\S+)\s+(.*)/$2 $1/' file

Ada pilihan sed juga ...

 sed 's/\([^ ]*\)  \(.*\)/\2 \1/' inputfile.txt

Dijelaskan ...

Swap
\([^ ]*\) = Match anything until we reach a space, store in $1
\(.*\)    = Match everything else, store in $2
With
\2        = Retrieve $2
\1        = Retrieve $1

Lebih jelasnya dijelaskan ...

s    = Swap
/    = Beginning of source pattern
\(   = start storing this value
[^ ] = text not matching the space character
*    = 0 or more of the previous pattern
\)   = stop storing this value
\(   = start storing this value
.    = any character
*    = 0 or more of the previous pattern
\)   = stop storing this value
/    = End of source pattern, beginning of replacement
\2   = Retrieve the 2nd stored value
\1   = Retrieve the 1st stored value
/    = end of replacement

Namun cara lain ...

... ini menggabungkan kembali bidang 2 melalui NF dengan FS dan mengeluarkan satu baris per baris masukan

awk '{for (i=2;i<=NF;i++){printf $i; if (i < NF) {printf FS};}printf RS}'

Saya menggunakan ini dengan git untuk melihat file apa yang telah dimodifikasi di direktori kerja saya:

git diff| \
    grep '\-\-git'| \
    awk '{print$NF}'| \
    awk -F"/" '{for (i=2;i<=NF;i++){printf $i; if (i < NF) {printf FS};}printf RS}'

Cara lain dan mudah menggunakan perintah cat

cat filename | awk '{print $2,$3,$4,$5,$6,$1}' > newfilename