Cara mengembalikan hasil dari fungsi VBA

Bagaimana cara mengembalikan hasil dari suatu fungsi?

Sebagai contoh:

Public Function test() As Integer
    return 1
End Function

Ini memberikan kesalahan kompilasi.

Bagaimana cara membuat fungsi ini mengembalikan bilangan bulat?

Untuk jenis pengembalian non-objek, Anda harus menetapkan nilai ke nama fungsi Anda, seperti ini:

Public Function test() As Integer
    test = 1
End Function

Contoh penggunaan:

Dim i As Integer
i = test()

Jika fungsi mengembalikan tipe objek, maka Anda harus menggunakan Setkata kunci seperti ini:

Public Function testRange() As Range
    Set testRange = Range("A1")
End Function

Contoh penggunaan:

Dim r As Range
Set r = testRange()

Perhatikan bahwa menetapkan nilai kembali ke nama fungsi tidak menghentikan eksekusi fungsi Anda. Jika Anda ingin keluar dari fungsi, maka Anda perlu mengatakannya secara eksplisit Exit Function. Sebagai contoh:

Function test(ByVal justReturnOne As Boolean) As Integer
    If justReturnOne Then
        test = 1
        Exit Function
    End If
    'more code...
    test = 2
End Function

Dokumentasi: http://msdn.microsoft.com/en-us/library/office/gg264233%28v=office.14%29.aspx

Fungsi VBA memperlakukan nama fungsi itu sendiri sebagai semacam variabel. Jadi alih-alih menggunakan returnpernyataan " ", Anda hanya akan mengatakan:

test = 1

Namun, perhatikan bahwa ini tidak keluar dari fungsinya. Kode apa pun setelah pernyataan ini juga akan dieksekusi. Dengan demikian, Anda dapat memiliki banyak pernyataan penugasan yang menetapkan nilai berbeda test, dan apa pun nilainya ketika Anda mencapai akhir fungsi akan menjadi nilai yang dikembalikan.

Hanya mengatur nilai kembali ke nama fungsi masih tidak persis sama dengan pernyataan Java (atau lainnya) return, karena di java, returnkeluar dari fungsi, seperti ini:

public int test(int x) {
    if (x == 1) {
        return 1; // exits immediately
    }

    // still here? return 0 as default.
    return 0;
}

Dalam VB, ekuivalen yang tepat mengambil dua baris jika Anda tidak menetapkan nilai balik di akhir fungsi Anda . Jadi, dalam VB konsekuensi wajar yang tepat akan terlihat seperti ini:

Public Function test(ByVal x As Integer) As Integer
    If x = 1 Then
        test = 1 ' does not exit immediately. You must manually terminate...
        Exit Function ' to exit
    End If

    ' Still here? return 0 as default.
    test = 0
    ' no need for an Exit Function because we're about to exit anyway.
End Function 

Karena ini adalah kasusnya, itu juga bagus untuk mengetahui bahwa Anda dapat menggunakan variabel kembali seperti variabel lain dalam metode ini. Seperti ini:

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test <> 1 Then ' Test the currently set return value
        test = 0 ' Reset the return value to a *new* value
    End If

End Function 

Atau, contoh ekstrem tentang bagaimana variabel pengembalian bekerja (tetapi tidak harus contoh yang baik tentang bagaimana Anda seharusnya kode) - contoh yang akan membuat Anda terjaga di malam hari:

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test > 0 Then

        ' RECURSIVE CALL...WITH THE RETURN VALUE AS AN ARGUMENT,
        ' AND THE RESULT RESETTING THE RETURN VALUE.
        test = test(test - 1)

    End If

End Function

Kode di bawah ini menyimpan nilai kembali ke variabel retValdan kemudian MsgBoxdapat digunakan untuk menampilkan nilai:

Dim retVal As Integer
retVal = test()
Msgbox retVal