Kueri Google SpreadSheet: Dapatkah saya menghapus tajuk kolom?

99

Saya melakukan kueri ini di spreadsheet Google saya:

=QUERY(H4:L35;"select sum(L) where H='First Week'"; -1)

Tapi itu mengembalikan tabel kecil dengan "jumlah" sebagai tajuk dan hasil di bawahnya. Yang saya inginkan hanyalah hasilnya! Bagaimana cara menghapus header? Bisakah saya?

google-sheets formulas google-sheets-query google-query-language Poliane Brito
sumber
Ini tampaknya lebih mudah: stackoverflow.com/a/41797729/5316231
pengguna19581

Jawaban:

190

Coba ini:

=QUERY(H4:L35,"select sum(L) where H='First Week' label sum(L) ''")

Semoga Membantu!

KRR
sumber
3
Saya baru saja menguji ini di salah satu lembar saya dan menghapus header dari hasil yang dikembalikan; ini harus ditandai sebagai jawaban yang benar. :)
FooBar
1
Ini bagus dan berhasil, tetapi adakah yang bisa menjelaskan mengapa dua tanda kutip tunggal diperlukan di bagian akhir? Apa yang dilakukannya dari perspektif sintaks?
y-i_guy
2
Kutipan tunggal menggantikan tajuk jumlah dengan spasi kosong. Semoga itu menjelaskan pertanyaan Anda !!
KRR
2
Terima kasih atas jawabannya! Saya perlu melakukan hal yang sama dengan lebih dari satu kolom tetapi saya tidak dapat mencapainya! Saya berharap ini akan berhasil: = QUERY (H4: L35, "pilih jumlah (L), jumlah (H) di mana H = 'Minggu Pertama' label sum (L) '' label sum (H) ''")
Emilio Nicolás
11
LABEL B 'Label1', C 'Label2'untuk beberapa kolom
sojim2
30

=QUERY(QUERY(A1:D, "SELECT *", 1), "SELECT * OFFSET 1", 0)

Kueri luar: "SELECT * OFFSET 1"mengecualikan baris pertama (tajuk).

Kueri dalam secara eksplisit menentukan satu baris tajuk (melalui argumen ketiga yang diberikan ke QUERY), sedangkan kueri luar tidak menentukan satu pun.

pengguna280150
sumber
3
Sedikit penjelasan?
J Fabian Meier
Mengapa yang kedua QUERYdiperlukan? Tidakkah parameter "0" menghilangkan header, jadi Anda dapat menggunakannya pertama kali QUERY, seperti ini: QUERY('Form responses 3'!$A$2:$P$1017, "SELECT max(E),max(C), max(D) WHERE B='" & B14 & "' GROUP BY B LIMIT 1 ", 0)
Steven M. Mortimer
3
Saya percaya OFFSET 1pada kueri kedua akan membuang baris pertama dari kumpulan data yang dikembalikan, bukan tajuk di baris pertama.
Steven M. Mortimer
2
Jawaban ini mungkin lebih bertele-tele tetapi juga lebih kuat dan dapat digunakan tanpa perlu menduplikasi string agregasi kolom. Bahkan dapat digunakan dengan pivot, yang tidak dapat digunakan dengan jawaban lain di sini.
7yl4r
1
Kecuali saya salah, ini tidak benar-benar menyelesaikan tantangan khusus yang ditawarkan oleh pembuat poster asli, yaitu menghapus tajuk yang secara otomatis dibuat oleh QUERY saat menggunakan fungsi agregasi seperti SUM. Saat menggunakan SUM (atau fungsi agregasi lainnya), QUERY secara otomatis membuat baris header yang menentukan agregasi yang dilakukan, misalnya "jumlah". Ini akan melakukan ini bahkan jika Anda menyetel header ke 0 dan bahkan jika Anda menerapkan klausa OFFSET 1. Rumus berikut masih mengembalikan header. = QUERY (Sheet1! A: B, "PILIH A, JUMLAH (B) GROUP BY A OFFSET 1", 0) Jawaban yang diterima memecahkan tantangan ini.
Dave Meindl
0

Saya memiliki QUERY yang mengembalikan 3 teratas. Saya tidak dapat menjalankan ini saat mengembalikan beberapa baris. Saya akhirnya hanya menyembunyikan baris dengan rumus dan hanya jawabannya yang ditampilkan sekarang.

Brian Wochele
sumber
0 
=INDEX(QUERY(H4:L35;"select sum(L) where H='First Week'"; -1),2,1)

Ini hanya mem-parsing array yang dikembalikan dan memilih catatan ke-2 yang dikembalikan di kolom pertama.

Anda juga dapat melakukan ini dengan fungsi filter yang kurang intensif komputasi. 

=SUM(FILTER(L4:L35, H4:H35 = "First Week"))
Dean Falconer
sumber
-3

Lihat formatnya di sini .

Contoh:

=QUERY(B4:C38,
   "SELECT C, sum(B) where C!='' group by C label C 'Member', sum(B) 'Sum'"
)
Andy
sumber
2
Contoh yang diberikan tidak mengembalikan hasil tanpa header.
Rubén