Tinggalkan tanda kutip saat menyalin dari sel

Masalah :
Saat menyalin sel dari Excel di luar program, tanda kutip ganda ditambahkan secara otomatis.

Rincian :
Saya menggunakan Excel 2007 di mesin Windows 7. Jika saya memiliki sel dengan rumus berikut:

="1"&CHAR(9)&"SOME NOTES FOR LINE 1."&CHAR(9)&"2"&CHAR(9)&"SOME NOTES FOR LINE 2."

Output dalam sel (diformat sebagai angka) terlihat seperti ini di Excel:

1SOME NOTES FOR LINE 1.2SOME NOTES FOR LINE 2.

Baik dan bagus. Tetapi, jika saya menyalin sel ke program lain, seperti notepad, saya mendapatkan tanda kutip ganda yang mengganggu di awal dan akhir. Perhatikan tab yang dibuat oleh "CHAR (9)" disimpan, dan itu bagus.

"1  SOME NOTES FOR LINE 1.  2     SOME NOTES FOR LINE 2."

Bagaimana cara agar tanda kutip ganda tidak muncul saat saya menyalin ke program lain? Dengan kata lain, dapatkah saya mencegahnya ditambahkan secara otomatis saat sel disalin ke papan klip?

Jika Anda mencoba menempelkan ke Word-Pad, Notepad ++ atau Word, Anda tidak akan mengalami masalah ini. Untuk menyalin nilai sel sebagai teks murni, untuk mencapai apa yang Anda gambarkan, Anda harus menggunakan makro:

Di buku kerja tempat Anda ingin menerapkan ini (atau di Personal.xls Anda jika Anda ingin menggunakan di beberapa buku kerja), letakkan kode berikut dalam modul standar:

Kode:

Sub CopyCellContents()
'create a reference in the VBE to Microsft Forms 2.0 Lib
' do this by (in VBA editor) clicking tools - > references and then ticking "Microsoft Forms 2.0 Library"
Dim objData As New DataObject
Dim strTemp As String
strTemp = ActiveCell.Value
objData.SetText (strTemp)
objData.PutInClipboard
End Sub

Untuk menambahkan modul standar ke proyek Anda (buku kerja), buka VBE dengan Alt+ F11dan kemudian klik kanan pada buku kerja Anda di kiri atas Jendela Proyek dan pilih Sisipkan> Modul. Tempel kode ke jendela modul kode yang akan terbuka di sebelah kanan.

Kembali ke Excel, buka Alat> Makro> Makro dan pilih makro yang disebut "CopyCellContents" lalu pilih Opsi dari dialog. Di sini Anda dapat menetapkan makro ke tombol pintas (misalnya seperti CTRL+ Cuntuk salinan normal) - Saya duluCTRL + Q.

Kemudian, ketika Anda ingin menyalin satu sel ke Notepad / di mana pun, cukup lakukan Ctrl + q (atau apa pun yang Anda pilih) lalu lakukan CTRL+V atau Edit> Tempel di tujuan yang Anda pilih.

Jawaban saya disalin (dengan beberapa tambahan) dari: di sini

EDIT : (dari komentar)

Jika Anda tidak menemukan Perpustakaan Microsoft Forms 2.0 dalam daftar referensi, Anda dapat mencoba

• mencari FM20.DLL sebagai gantinya (terima kasih @Peter Smallwood)
• mengklik Jelajahi dan memilih C:\Windows\System32\FM20.dll (32 bit Windows) (terima kasih @JWhy)
• mengklik Jelajahi dan memilih C:\Windows\SysWOW64\FM20.dll (pada 64-bit)

Saya baru saja mengalami masalah ini dan membungkus setiap sel dengan CLEANfungsi yang memperbaikinya untuk saya. Itu seharusnya relatif mudah dilakukan dengan melakukan =CLEAN(, memilih sel Anda, lalu mengisi kolom secara otomatis. Setelah saya melakukan ini, tempel ke Notepad atau program lain tidak lagi memiliki tanda kutip ganda.

Pertama paste ke Word, kemudian Anda bisa paste ke notepad dan akan muncul tanpa tanda kutip

Jika Anda ingin memilih beberapa sel dan menyalin nilainya ke clipboard tanpa semua tanda kutip yang mengganggu, kode berikut mungkin berguna. Ini adalah peningkatan dari kode yang diberikan di atas dari user3616725.

Sub CopyCells()
 'Attach Microsoft Forms 2.0 Library: tools\references\Browse\FM20.DLL
 'Then set a keyboard shortcut to the CopyCells Macro (eg Crtl T)
 Dim objData As New DataObject
 Dim cell As Object
 Dim concat As String
 Dim cellValue As String
 CR = ""
  For Each cell In Selection
  If IsNumeric(cell.Value) Then
   cellValue = LTrim(Str(cell.Value))
  Else
   cellValue = cell.Value
  End If
  concat = concat + CR + cellValue
  CR = Chr(13)
 Next
 objData.SetText (concat)
 objData.PutInClipboard
End Sub

Solusi saya ketika saya menekan masalah tanda kutip adalah menghapus kereta kembali dari akhir teks sel saya. Karena carriage return ini (disisipkan oleh program eksternal), Excel menambahkan tanda kutip ke seluruh string.

Kemungkinan masalah terkait dengan jawaban dari "user3616725":
Saya menggunakan Windows 8.1 dan sepertinya ada masalah dengan kode VBA tertaut dari jawaban yang diterima dari "user3616725":

Sub CopyCellContents()
 ' !!! IMPORTANT !!!:
 ' CREATE A REFERENCE IN THE VBE TO "Microsft Forms 2.0 Library" OR "Microsft Forms 2.0 Object Library"
 ' DO THIS BY (IN VBA EDITOR) CLICKING TOOLS -> REFERENCES & THEN TICKING "Microsoft Forms 2.0 Library" OR "Microsft Forms 2.0 Object Library"
 Dim objData As New DataObject
 Dim strTemp As String
 strTemp = ActiveCell.Value
 objData.SetText (strTemp)
 objData.PutInClipboard
End Sub

Detail:
Menjalankan kode di atas dan menempelkan clipboard ke dalam sel di Excel Saya mendapatkan dua simbol yang terdiri dari kotak dengan tanda tanya di dalamnya, seperti ini: ⍰⍰. Menempelkan ke Notepad bahkan tidak menampilkan apa pun.

Solusi:
Setelah mencari beberapa lama saya menemukan skrip VBA lain dari pengguna "Nepumuk" yang menggunakan API Windows . Inilah kodenya yang akhirnya berhasil untuk saya:

Option Explicit

Private Declare Function OpenClipboard Lib "user32.dll" ( _
    ByVal hwnd As Long) As Long
Private Declare Function CloseClipboard Lib "user32.dll" () As Long
Private Declare Function EmptyClipboard Lib "user32.dll" () As Long
Private Declare Function SetClipboardData Lib "user32.dll" ( _
    ByVal wFormat As Long, _
    ByVal hMem As Long) As Long
Private Declare Function GlobalAlloc Lib "kernel32.dll" ( _
    ByVal wFlags As Long, _
    ByVal dwBytes As Long) As Long
Private Declare Function GlobalLock Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function GlobalFree Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function lstrcpy Lib "kernel32.dll" ( _
    ByVal lpStr1 As Any, _
    ByVal lpStr2 As Any) As Long

Private Const CF_TEXT As Long = 1&

Private Const GMEM_MOVEABLE As Long = 2

Public Sub Beispiel()
    Call StringToClipboard("Hallo ...")
End Sub

Private Sub StringToClipboard(strText As String)
    Dim lngIdentifier As Long, lngPointer As Long
    lngIdentifier = GlobalAlloc(GMEM_MOVEABLE, Len(strText) + 1)
    lngPointer = GlobalLock(lngIdentifier)
    Call lstrcpy(ByVal lngPointer, strText)
    Call GlobalUnlock(lngIdentifier)
    Call OpenClipboard(0&)
    Call EmptyClipboard
    Call SetClipboardData(CF_TEXT, lngIdentifier)
    Call CloseClipboard
    Call GlobalFree(lngIdentifier)
End Sub

Untuk menggunakannya dengan cara yang sama seperti kode VBA pertama dari atas, ubah Sub "Beispiel ()" dari:

Public Sub Beispiel()
    Call StringToClipboard("Hallo ...")
End Sub

Untuk:

Sub CopyCellContents()
    Call StringToClipboard(ActiveCell.Value)
End Sub

Dan jalankan melalui menu makro Excel seperti yang disarankan dari "user3616725" dari jawaban yang diterima:

Kembali ke Excel, buka Alat> Makro> Makro dan pilih makro yang disebut "CopyCellContents" lalu pilih Opsi dari dialog. Di sini Anda dapat menetapkan makro ke tombol pintas (misalnya seperti Ctrl + c untuk salinan normal) - Saya menggunakan Ctrl + q.

Kemudian, ketika Anda ingin menyalin satu sel ke Notepad / di mana pun, cukup lakukan Ctrl + q (atau apa pun yang Anda pilih) dan kemudian lakukan Ctrl + v atau Edit> Tempel di tujuan yang Anda pilih.

Sunting (21 November 2015):
@ komentar dari "dotctor":
Tidak, ini benar-benar bukan pertanyaan baru! Menurut pendapat saya, ini adalah tambahan yang bagus untuk jawaban yang diterima karena jawaban saya menjawab masalah yang dapat Anda hadapi saat menggunakan kode dari jawaban yang diterima. Jika saya ingin memiliki reputasi lebih, saya akan membuat komentar.
@ komentar dari "Teepeemm":
Ya, Anda benar, jawaban yang diawali dengan judul "Masalah:" menyesatkan. Diubah menjadi: "Kemungkinan masalah terkait dengan jawaban dari" user3616725 ":". Sebagai komentar saya pasti akan menulis jauh lebih kompak.

"Jika Anda ingin Memilih beberapa Sel dan Salin nilainya ke Papan Klip tanpa semua tanda kutip yang mengganggu" ( tanpa bug dalam solusi multi-Sel Peter Smallwood) "kode berikut mungkin berguna." Ini adalah peningkatan dari kode yang diberikan di atas dari Peter Smallwood (yang "merupakan peningkatan dari kode yang diberikan di atas dari pengguna3616725"). Ini memperbaiki bug berikut dalam solusi Peter Smallwood:

• Menghindari Kesalahan Penyusun "Variabel tidak ditentukan" (untuk "CR" - "clibboardFieldDelimiter" di sini)
• Ubah Sel Kosong menjadi String kosong vs. "0".
• Tambahkan Tab (ASCII 9) vs. CR (ASCII 13) setelah setiap Sel.
• Tambahkan CR (ASCII 13) + LF (ASCII 10) (vs. CR (ASCII 13)) setelah setiap Baris.

CATATAN: Anda masih tidak dapat menyalin karakter yang disematkan di dalam Sel yang akan menyebabkan keluarnya bidang target tempat Anda Menempelkan Sel itu (yaitu Tab atau CR saat Menempelkan ke Jendela Akses Edit Tabel atau SSMS).

Option Explicit

Sub CopyCellsWithoutAddingQuotes()

' -- Attach Microsoft Forms 2.0 Library: tools\references\Browse\FM20.DLL
' -- NOTE: You may have to temporarily insert a UserForm into your VBAProject for it to show up.
' -- Then set a Keyboard Shortcut to the "CopyCellsWithoutAddingQuotes" Macro (i.e. Crtl+E)

Dim clibboardFieldDelimiter As String
Dim clibboardLineDelimiter As String
Dim row As Range
Dim cell As Range
Dim cellValueText As String
Dim clipboardText As String
Dim isFirstRow As Boolean
Dim isFirstCellOfRow As Boolean
Dim dataObj As New dataObject

clibboardFieldDelimiter = Chr(9)
clibboardLineDelimiter = Chr(13) + Chr(10)
isFirstRow = True
isFirstCellOfRow = True

For Each row In Selection.Rows

    If Not isFirstRow Then
        clipboardText = clipboardText + clibboardLineDelimiter
    End If

    For Each cell In row.Cells

        If IsEmpty(cell.Value) Then

            cellValueText = ""

        ElseIf IsNumeric(cell.Value) Then

            cellValueText = LTrim(Str(cell.Value))

        Else

            cellValueText = cell.Value

        End If ' -- Else Non-empty Non-numeric

        If isFirstCellOfRow Then

            clipboardText = clipboardText + cellValueText
            isFirstCellOfRow = False

        Else ' -- Not (isFirstCellOfRow)

            clipboardText = clipboardText + clibboardFieldDelimiter + cellValueText

        End If ' -- Else Not (isFirstCellOfRow)

    Next cell

    isFirstRow = False
    isFirstCellOfRow = True

Next row

clipboardText = clipboardText + clibboardLineDelimiter

dataObj.SetText (clipboardText)
dataObj.PutInClipboard

End Sub

Untuk mempertahankan jeda baris saat menempelkan di notepad, ganti baris ini di makro:

strTemp = ActiveCell.Value

oleh:

strTemp = Replace(ActiveCell.Value, Chr(10), vbCrLf)

Silakan gunakan rumus di bawah ini

=Clean("1"&CHAR(9)&"SOME NOTES FOR LINE 1."&CHAR(9)&"2"&CHAR(9)&"SOME NOTES FOR LINE 2.")

dan Anda akan mendapatkan apa yang Anda inginkan ;-)

Anda bisa melakukan ini di makro Excel melalui VBA, mengirimkan hasilnya ke file:

Sub SimpleVBAWriteToFileWithoutQuotes()
    Open "c:\TEMP\Excel\out.txt" For Output As #1
    Print #1, Application.ActiveSheet.Cells(2, 3)
    Close #1
End Sub

Dan jika Anda ingin mendapatkan nama file dan konten menjadi beberapa file, berikut adalah cuplikan singkat yang menghindari tanda kutip ganda di sekitar output.

Sub DumpCellDataToTextFilesWithoutDoubleQuotes()
    ' this will work for filename and content in two different columns such as:
    ' filename column       data column
    ' 101                   this is some data
    ' 102                   this is more data

    Dim rngData As Range
    Dim strData As String
    Dim strTempFile As String
    Dim strFilename As String
    Dim i As Long
    Dim intFilenameColumn As Integer
    Dim intDataColumn As Integer
    Dim intStartingRow As Integer

    intFilenameColumn = 1     ' the column number containing the filenames
    intDataColumn = 3         ' the column number containing the data
    intStartingRow = 2        ' the row number to start gathering data


    For i = intStartingRow To Range("A1", Range("A1").End(xlDown)).Rows.Count

        ' copy the data cell's value
        Set rngData = Application.ActiveSheet.Cells(i, intDataColumn)

        ' get the base filename
        strFilename = Application.ActiveSheet.Cells(i, intFilenameColumn)

        ' assemble full filename and path
        strTempFile = "w:\TEMP\Excel\" & strFilename & ".txt"

        ' write to temp file
        Open strTempFile For Output As #1
        Print #1, rngData
        Close #1

    Next i

    ' goto home cell
    Application.ActiveSheet.Cells(1, 1).Select
    Range("A1").ClearOutline
End Sub

• Jika rumus memiliki multi baris (artinya ada baris baru dalam rumus) maka salin tempel akan berfungsi seperti itu
• jika dapat menghapus multi baris maka tidak akan muncul tanda kutip saat copy paste.
• lain gunakan fungsi CLEAN seperti yang dikatakan oleh @greg di jawaban sebelumnya

Catatan: Penyebab tanda kutip adalah saat data berpindah dari excel ke clipboard, ia sepenuhnya mematuhi standar CSV yang mencakup nilai kutipan yang mencakup tab, baris baru, dll (dan karakter tanda kutip ganda diganti dengan dua karakter tanda kutip ganda)

Jadi pendekatan lain, terutama seperti dalam kasus OP ketika tab / baris baru karena rumus, adalah menggunakan karakter alternatif untuk tab dan pengembalian keras. Saya menggunakan ascii Unit Separator = char (31) untuk tab dan ascii Record Separator = char (30) untuk baris baru.

Kemudian menempelkan ke editor teks tidak akan melibatkan aturan CSV tambahan dan Anda dapat melakukan pencarian cepat dan mengganti untuk mengubahnya kembali.

Jika tab / baris baru disematkan dalam data, Anda dapat melakukan pencarian dan mengganti di excel untuk mengubahnya.

Baik menggunakan rumus atau mengubah data, kunci untuk memilih pemisah adalah jangan pernah menggunakan karakter yang bisa ada dalam data sebenarnya. Inilah mengapa saya merekomendasikan karakter ascii level rendah.

Anda juga dapat menghapus tanda kutip ganda ini dengan menempatkan hasil Anda pada fungsi "Bersihkan".

Contoh:

=CLEAN("1"&CHAR(9)&"SOME NOTES FOR LINE 1."&CHAR(9)&"2"&CHAR(9)&"SOME NOTES FOR LINE 2.")

Keluaran akan ditempelkan tanpa tanda kutip ganda pada program lain seperti Notepad ++.