Bagaimana Anda menguji waktu berjalan kode VBA?

Apakah ada kode di VBA yang dapat saya gabungkan dengan suatu fungsi yang akan memberi tahu saya waktu yang dibutuhkan untuk menjalankannya, sehingga saya dapat membandingkan waktu berjalan yang berbeda dari fungsi?

Kecuali jika fungsi Anda sangat lambat, Anda memerlukan pengatur waktu dengan resolusi sangat tinggi. Yang paling akurat yang saya tahu adalah QueryPerformanceCounter. Google itu untuk info lebih lanjut. Coba dorong perintah berikut ke dalam kelas, sebut saja CTimer, lalu Anda dapat membuat instance di suatu tempat secara global dan cukup panggil .StartCounterdan.TimeElapsed

Option Explicit

Private Type LARGE_INTEGER
    lowpart As Long
    highpart As Long
End Type

Private Declare Function QueryPerformanceCounter Lib "kernel32" (lpPerformanceCount As LARGE_INTEGER) As Long
Private Declare Function QueryPerformanceFrequency Lib "kernel32" (lpFrequency As LARGE_INTEGER) As Long

Private m_CounterStart As LARGE_INTEGER
Private m_CounterEnd As LARGE_INTEGER
Private m_crFrequency As Double

Private Const TWO_32 = 4294967296# ' = 256# * 256# * 256# * 256#

Private Function LI2Double(LI As LARGE_INTEGER) As Double
Dim Low As Double
    Low = LI.lowpart
    If Low < 0 Then
        Low = Low + TWO_32
    End If
    LI2Double = LI.highpart * TWO_32 + Low
End Function

Private Sub Class_Initialize()
Dim PerfFrequency As LARGE_INTEGER
    QueryPerformanceFrequency PerfFrequency
    m_crFrequency = LI2Double(PerfFrequency)
End Sub

Public Sub StartCounter()
    QueryPerformanceCounter m_CounterStart
End Sub

Property Get TimeElapsed() As Double
Dim crStart As Double
Dim crStop As Double
    QueryPerformanceCounter m_CounterEnd
    crStart = LI2Double(m_CounterStart)
    crStop = LI2Double(m_CounterEnd)
    TimeElapsed = 1000# * (crStop - crStart) / m_crFrequency
End Property

Fungsi Timer di VBA memberi Anda jumlah detik yang berlalu sejak tengah malam, hingga 1/100 detik.

Dim t as single
t = Timer
'code
MsgBox Timer - t

Jika Anda mencoba mengembalikan waktu seperti stopwatch, Anda dapat menggunakan API berikut yang mengembalikan waktu dalam milidetik sejak sistem dimulai:

Public Declare Function GetTickCount Lib "kernel32.dll" () As Long
Sub testTimer()
Dim t As Long
t = GetTickCount

For i = 1 To 1000000
a = a + 1
Next

MsgBox GetTickCount - t, , "Milliseconds"
End Sub

setelah http://www.pcreview.co.uk/forums/grab-time-milliseconds-included-vba-t994765.html (karena timeGetTime di winmm.dll tidak berfungsi untuk saya dan QueryPerformanceCounter terlalu rumit untuk tugas yang diperlukan)

Untuk lebah baru, tautan ini menjelaskan cara melakukan pembuatan profil otomatis dari semua kapal selam yang ingin Anda pantau waktu:

http://www.nullskull.com/a/1602/profiling-and-optimizing-vba.aspx

http://sites.mcpher.com/share/Home/excelquirks/optimizationlink lihat procProfiler.zip di http://sites.mcpher.com/share/Home/excelquirks/downlable-items

Sub Macro1()
    Dim StartTime As Double
    StartTime = Timer

        ''''''''''''''''''''
            'Your Code'
        ''''''''''''''''''''
    MsgBox "RunTime : " & Format((Timer - StartTime) / 86400, "hh:mm:ss")
End Sub

Keluaran:

RunTime: 00:00:02

Kami telah menggunakan solusi berdasarkan timeGetTime di winmm.dll untuk akurasi milidetik selama bertahun-tahun. Lihat http://www.aboutvb.de/kom/artikel/komstopwatch.htm

Artikelnya dalam bahasa Jerman, tetapi kode dalam unduhan (kelas VBA yang membungkus panggilan fungsi dll) cukup sederhana untuk digunakan dan dipahami tanpa bisa membaca artikel.

Detik dengan 2 spasi desimal:

Dim startTime As Single 'start timer
MsgBox ("run time: " & Format((Timer - startTime) / 1000000, "#,##0.00") & " seconds") 'end timer

Milidetik:

Dim startTime As Single 'start timer
MsgBox ("run time: " & Format((Timer - startTime), "#,##0.00") & " milliseconds") 'end timer

Milidetik dengan pemisah koma:

Dim startTime As Single 'start timer
MsgBox ("run time: " & Format((Timer - startTime) * 1000, "#,##0.00") & " milliseconds") 'end timer

Tinggalkan ini di sini untuk siapa saja yang mencari pengatur waktu sederhana yang diformat dengan detik hingga 2 spasi desimal seperti saya. Ini adalah timer kecil yang pendek dan manis yang suka saya gunakan. Mereka hanya mengambil satu baris kode di awal sub atau fungsi dan satu baris kode lagi di akhir. Ini tidak dimaksudkan untuk menjadi sangat akurat, saya biasanya tidak peduli tentang apa pun yang kurang dari 1/100 detik secara pribadi, tetapi pengatur waktu milidetik akan memberi Anda waktu berjalan paling akurat dari 3 ini. Saya juga telah membaca Anda bisa mendapatkan pembacaan yang salah jika kebetulan berjalan saat melintasi tengah malam, hal yang jarang terjadi tetapi hanya FYI.