UltiSnips dan YouCompleteMe

Saya memiliki bundel ultisnips dan youcompleteme diinstal pada macvim saya. Masalahnya adalah bahwa ultisnips tidak berfungsi karena tab diikat oleh ycm. Saya mencoba meletakkanlet g:UltiSnipsExpandTrigger = "<s-tab>" sehingga saya dapat memicu penyelesaian cuplikan dengan tab-geser, tetapi tidak berhasil karena alasan yang tidak diketahui. Saya bisa menggunakan topi sebagai pemicunya, tetapi sejauh ini saya tidak menemukan cara untuk melakukannya.

Apakah ada di antara Anda yang menggunakan kedua add-ons itu bersama-sama? Apa yang bisa saya lakukan untuk membuat shift-tab bekerja? Bisakah Anda merekomendasikan kunci lain untuk memicu cuplikan?

Opsi lain menggunakan plugin SuperTab:

" if you use Vundle, load plugins:
Bundle 'ervandew/supertab'
Bundle 'Valloric/YouCompleteMe'
Bundle 'SirVer/ultisnips'

" make YCM compatible with UltiSnips (using supertab)
let g:ycm_key_list_select_completion = ['<C-n>', '<Down>']
let g:ycm_key_list_previous_completion = ['<C-p>', '<Up>']
let g:SuperTabDefaultCompletionType = '<C-n>'

" better key bindings for UltiSnipsExpandTrigger
let g:UltiSnipsExpandTrigger = "<tab>"
let g:UltiSnipsJumpForwardTrigger = "<tab>"
let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"

Di sini YouCompleteMe terikat ke kombinasi yang berbeda Ctrln, tetapi kemudian kombinasi tersebut terikat ke tab melalui SuperTab. UltiSnips dan SuperTab bermain bagus bersama, jadi Anda bisa mengikat UltiSnips langsung ke tab dan semuanya akan berhasil.

Coba saran ini pada halaman dari pelacak masalah YouCompleteMe. Di .vimrc Anda:

let g:UltiSnipsExpandTrigger="<c-j>"

Meskipun pengaturan ini akan membuat perluasan potongan cuplikan pemetaan default untuk melompat maju dalam potongan , itu mensimulasikan perilaku TextMates 'seperti yang disebutkan dalam tag bantuan UltiSnips.

Karena saya telah memetakan tombol Caps Lock ke Ctrl, pemetaan ini berfungsi dengan sangat lancar.

salin kode berikut ke vimrc Anda, dan selamat menikmati. Fungsi ini akan menangani semua masalah antara YCM dan UltiSnips.

function! g:UltiSnips_Complete()
    call UltiSnips#ExpandSnippet()
    if g:ulti_expand_res == 0
        if pumvisible()
            return "\<C-n>"
        else
            call UltiSnips#JumpForwards()
            if g:ulti_jump_forwards_res == 0
               return "\<TAB>"
            endif
        endif
    endif
    return ""
endfunction

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
let g:UltiSnipsJumpForwardTrigger="<tab>"
let g:UltiSnipsListSnippets="<c-e>"
" this mapping Enter key to <C-y> to chose the current highlight item 
" and close the selection list, same as other IDEs.
" CONFLICT with some plugins like tpope/Endwise
inoremap <expr> <CR> pumvisible() ? "\<C-y>" : "\<C-g>u\<CR>"

saya punya ini di vimrc saya

"" YouCompleteMe
let g:ycm_key_list_previous_completion=['<Up>']

"" Ultisnips
let g:UltiSnipsExpandTrigger="<c-tab>"
let g:UltiSnipsListSnippets="<c-s-tab>"

Itulah yang saya lakukan pada percobaan pertama saya, tetapi saya salah mengeja UltiSnips dengan Ultisnips .. oh well, akhirnya berhasil!

Saya pribadi memilih untuk tidak menggunakan <tab> dengan YouCompleteMe tetapi menavigasi secara manual.

Jadi saya menambahkan ini ke .vimrc:

let g:ycm_key_list_select_completion=[]
let g:ycm_key_list_previous_completion=[]

yang hanya menonaktifkan tabkunci untuk YCM. Sebagai gantinya Anda menggunakan tombol gerakan (panah atau CTRL-N/ CTRL-P) dan memilih entri dengan CR. UltiSnips berfungsi dengan default tab.

Hanya dengan mengumpulkan jawaban oleh Michaelslec, Joey Liu dan bersama dengan solusi yang saya temukan di utas masalah ini dan vimrc orang ini , saya sekarang memiliki ini yang memecahkan hampir semua masalah.

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippet()
  if g:ulti_expand_res == 0
    if pumvisible()
      return "\<C-n>"
    else
      call UltiSnips#JumpForwards()
      if g:ulti_jump_forwards_res == 0
        return "\<TAB>"
      endif
    endif
  endif
  return ""
endfunction

function! g:UltiSnips_Reverse()
  call UltiSnips#JumpBackwards()
  if g:ulti_jump_backwards_res == 0
    return "\<C-P>"
  endif

  return ""
endfunction


if !exists("g:UltiSnipsJumpForwardTrigger")
  let g:UltiSnipsJumpForwardTrigger = "<tab>"
endif

if !exists("g:UltiSnipsJumpBackwardTrigger")
  let g:UltiSnipsJumpBackwardTrigger="<s-tab>"
endif

au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger     . " <C-R>=g:UltiSnips_Complete()<cr>"
au InsertEnter * exec "inoremap <silent> " .     g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Meskipun saya tahu posting ini agak lama, saya memiliki fungsi saya sendiri yang sedikit lebih dioptimalkan daripada yang diberikan di atas:

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippetOrJump()
  if g:ulti_expand_or_jump_res == 0
    if pumvisible()
      return "\<C-N>"
    else
      return "\<TAB>"
    endif
  endif

  return ""
endfunction

Tentu saja, jika Anda hanya menyimpan pengaturan yang disediakan Joey Liu dan kemudian hanya menggunakan fungsi ini semuanya akan bekerja dengan sempurna!

EDIT: Juga, saya menggunakan fungsi lain untuk meningkatkan fungsionalitas back-stepping antara YouCompleteMe dan UltiSnips. Saya akan menunjukkan kepada Anda apa yang saya maksud:

function! g:UltiSnips_Reverse()                                                                                               
  call UltiSnips#JumpBackwards()                                                                                              
  if g:ulti_jump_backwards_res == 0        
    return "\<C-P>"                                                                                                           
  endif                                                                                                                       

  return ""                                                                                                                   
endfunction

Kemudian cukup letakkan ini di .vimrc Anda:

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Serta let g:UltiSnipsJumpBackwardTrigger="<s-tab>"dan set Anda!

Saya menggunakan keduanya bersama-sama. Secara default YouCompleteMe mengikat <Tab>dan <Down>memilih item penyelesaian selanjutnya dan juga <S-Tab>dan <Up>untuk memilih item penyelesaian sebelumnya. Anda dapat mengubah binding YouCompleteMe dengan opsi g: ycm_key_list_select_completion dan g: ycm_key_list_previous_completion . Perhatikan bahwa nama-nama opsi ini baru-baru ini berubah ketika opsi diubah dari string tunggal ke daftar string.

Saya menginstal plugin UltiSnips setelah plugin YouCompleteMe jadi saya pikir mereka saling bertentangan, tetapi pada kenyataannya saya memiliki sesuatu yang lebih mengganggu:

set paste

Pastikan untuk menghapusnya .vimrcjika ada.

Sementara Banyak jawaban berfungsi dengan baik di pos ini, saya hanya ingin mengatakan bahwa masalahnya disebabkan oleh tabrakan pengikatan kunci antara YCM dan UltiSnip, sementara YCM mendukung cuplikan UltiSnip secara default, dibutuhkan pemicu ultiSnip memperluas standar <tab>sebagai kunci pilih penyelesaiannya, jadi Cuplikan UltiSnip tidak akan diperluas oleh <tab>. Memberi mereka pengikatan kunci yang berbeda akan menyelesaikan masalah, saya pribadi menggunakan <c-ndan <c-p>untuk YCM dan menggunakan default <tab>untuk UltiSnip. Anda bisa mendapatkan detail lebih lanjut dengan help youcompletemedoc in vim.

Berdasarkan jawaban Siegfried, saya menggunakan yang berikut ini yang tampaknya lebih alami:

let g:ycm_key_list_select_completion = ['<C-j>']
let g:ycm_key_list_previous_completion = ['<C-k>']

let g:UltiSnipsExpandTrigger = "<C-l>"
let g:UltiSnipsJumpForwardTrigger = "<C-j>"
let g:UltiSnipsJumpBackwardTrigger = "<C-k>"

Saya juga menggunakan c-hjklbinding di tempat lain (beralih dari panel ke yang lain), tapi itu hanya dalam mode normal, jadi tidak ada masalah.

Saya menggunakan ;untuk memperluas UltiSnips, itu sangat bagus untuk saya

let g:UltiSnipsExpandTrigger = ";"

Saya menggunakan kj. Inilah yang ada di saya .vimrc:

let g:UltisnipsExpandTrigger="kj".

Jarang terjadi bahwa saya menemukan kata yang ada kjdi dalamnya. Jika ini masalahnya saya hanya akan menunggu beberapa detik setelah mengetik kdan tipe itu j.

Seperti yang disebutkan oleh orang lain, pemetaan Cj ke ultisnips berfungsi dengan baik.
let g:UltiSnipsExpandTrigger="<c-j>"

Sekarang, jika Anda melangkah lebih jauh dan instal xcape dan gunakan
xcape -e "Shift_L=Control_R|J"

Anda melepaskan kekuatan hanya menggunakan tombol shift untuk utlitsnips.