org: Bagaimana cara mengurutkan judul dengan TODO dan kemudian berdasarkan prioritas?

Saya sering memiliki daftar seperti ini:

* Main heading
** TODO [#A] Make world better
** TODO [#B] Make Emacs better 
** TODO [#B] Customize emacs 
** DONE [#C] some task
** TODO [#A] Launch rocket to mars

Saya ingin mengurutkannya sesuai dengan taskword 'TODO' terlebih dahulu. Kemudian barang-barang di dalam TODO yang diurutkan saya ingin mengurutkan berdasarkan prioritas. (Maka akan menyenangkan untuk mengurutkan lebih lanjut dengan "Usaha").

Dan maksud saya saat ini saya dapat mengklik tajuk utama dan mengurutkan anak-anak dengan prioritas atau dengan kata kunci, tetapi tidak keduanya.

Apakah mengurutkan berdasarkan keduanya mungkin seperti strategi sortir?

Saat ini saya memiliki dua judul

* Tasks
** TODO [#A] meh
** TODO [#B] meh2
* Completed.
** DONE [#B] meh3.

Tetapi masalah dengan pendekatan ini adalah bahwa saya harus terus-menerus mengacak tugas ketika saya menyelesaikannya.

[EDIT]
Ini agak mirip dengan ini, kecuali bahwa saya tidak bisa memahami jawabannya untuk mentransfernya ke kebutuhan saya?

Akan lebih bagus jika ada sesuatu seperti org-agenda-sorting-stratagyitu bekerja dengan baik org-sort-entries, tetapi sepertinya tidak ada. Kami dapat memalsukannya karena org-sort-entriesdapat mengambil argumen yang menetapkan fungsi yang menetapkan kunci (string atau angka) untuk setiap judul, yang akan digunakan untuk mengurutkan entri ketika ?fjenis penyortiran diberikan. Yang harus kita lakukan adalah mendapatkan string untuk properti TODO dan PRIORITY. Kuncinya adalah kita ingin menyortir properti TODO berdasarkan posisinya org-todo-keywords, bukan berdasarkan abjad.

(require 'cl)
(require 'dash)

(defun todo-to-int (todo)
    (first (-non-nil
            (mapcar (lambda (keywords)
                      (let ((todo-seq
                             (-map (lambda (x) (first (split-string  x "(")))
                                   (rest keywords)))) 
                        (cl-position-if (lambda (x) (string= x todo)) todo-seq)))
                    org-todo-keywords))))

(defun my/org-sort-key ()
  (let* ((todo-max (apply #'max (mapcar #'length org-todo-keywords)))
         (todo (org-entry-get (point) "TODO"))
         (todo-int (if todo (todo-to-int todo) todo-max))
         (priority (org-entry-get (point) "PRIORITY"))
         (priority-int (if priority (string-to-char priority) org-default-priority)))
    (format "%03d %03d" todo-int priority-int)
    ))

(defun my/org-sort-entries ()
  (interactive)
  (org-sort-entries nil ?f #'my/org-sort-key))

M-x my/org-sort-entriesakan mengurutkan berdasarkan kata kunci TODO dan memutuskan hubungan dengan PRIORITY (menggunakan org-default-priorityketika tidak ada prioritas diberikan). Ini akan rusak jika Anda memiliki lebih dari 1000 kata kunci TODO, yang merupakan alasan bagus untuk tidak melakukannya.

Tambahkan yang berikut ke file Anda:

#+ARCHIVE: :: * Completed.

Dan menyeret menjadi pengarsipan

Daripada mengurutkan entri, bagaimana dengan tampilan yang diurutkan?

(setq org-agenda-custom-commands
      '(("cx" "TODOs sorted by state, priority, effort"
         todo "*"
         ((org-agenda-overriding-header "\nTODOs sorted by state, priority, effort")
          (org-agenda-sorting-strategy '(todo-state-down priority-down effort-up))))))

Batasi ke file saat ini dengan <. Anda dapat menandai DIBUAT dan arsipkan dari tampilan yang diurutkan.

Anda juga dapat mendefinisikan org-agenda-cmp-user-definedfungsi dan menambahkannya ke org-agenda-sorting-strategy. Ini yang saya buat sebagai contoh.

(setq org-todo-sort-order '("WAIT" "TODO" "DOING" "CANCELED" "DONE"))

(defun my:user-todo-sort (a b)
  "Sort todo based on which I want to see first"
  (when-let ((state-a (get-text-property 14 'todo-state a))
             (state-b (get-text-property 14 'todo-state b))
             (cmp (--map (cl-position-if (lambda (x)
                                           (equal x it))
                                         org-todo-sort-order)
                         (list state-a state-b))))
    (cond ((apply '> cmp) 1)
          ((apply '< cmp) -1)
          (t nil))))
(setq org-agenda-cmp-user-defined 'my:user-todo-sort)

Anda dapat menggunakan perpustakaan ini yang dibuat oleh saya: https://github.com/felipelalli/org-sort-tasks

Ini menggunakan Gabung Urut algo dengan meminta pengguna jika tugas A lebih penting daripada B, dan kemudian membangun daftar diurutkan.