Bagaimana saya bisa mendeteksi jika karakter saat ini adalah karakter komentar untuk mode utama itu?

Saya sedang mengerjakan fungsi kecil ini yang menarik baris berikutnya ke baris saat ini. Saya ingin menambahkan fungsionalitas sehingga jika baris saat ini adalah komentar baris dan baris berikutnya juga merupakan komentar baris, maka karakter komentar akan dihapus setelah tindakan "pull-up".

Contoh:

Sebelum

;; comment 1▮
;; comment 2

Panggilan M-x modi/pull-up-line

Setelah

;; comment 1▮comment 2

Perhatikan bahwa ;;karakter dihapus yang sebelumnya comment 2.

(defun modi/pull-up-line ()
  "Join the following line onto the current one (analogous to `C-e', `C-d') or
`C-u M-^' or `C-u M-x join-line'.

If the current line is a comment and the pulled-up line is also a comment,
remove the comment characters from that line."
  (interactive)
  (join-line -1)
  ;; If the current line is a comment
  (when (nth 4 (syntax-ppss))
    ;; Remove the comment prefix chars from the pulled-up line if present
    (save-excursion
      (forward-char)
      (while (looking-at "/\\|;\\|#")
        (delete-forward-char 1))
      (when (looking-at "\\s-")
        (delete-forward-char 1)))))

Fungsi di atas bekerja tetapi untuk sekarang, terlepas dari besar-mode, itu akan mempertimbangkan /atau ;atau #sebagai karakter komentar: (looking-at "/\\|;\\|#").

Saya ingin membuat garis ini lebih cerdas; khusus mode utama.

Larutan

Berkat solusi @ericstokes, saya percaya bahwa di bawah ini sekarang mencakup semua kasus penggunaan saya :)

(defun modi/pull-up-line ()
  "Join the following line onto the current one (analogous to `C-e', `C-d') or
`C-u M-^' or `C-u M-x join-line'.

If the current line is a comment and the pulled-up line is also a comment,
remove the comment characters from that line."
  (interactive)
  (join-line -1)
  ;; If the current line is a comment
  (when (nth 4 (syntax-ppss))
    ;; Remove the comment prefix chars from the pulled-up line if present
    (save-excursion
      (forward-char)
      ;; Delete all comment-start or space characters
      (while (looking-at (concat "\\s<" ; comment-start char as per syntax table
                                 "\\|" (substring comment-start 0 1) ; first char of `comment-start'
                                 "\\|" "\\s-")) ; extra spaces
        (delete-forward-char 1)))))

Anda dapat memeriksa apakah karakter saat ini adalah komentar karakter dengan menggunakan tabel sintaks: (looking-at "\\s<"). Regexp \\s<akan mencocokkan karakter apa pun dengan sintaks "komentar mulai"; \\s>akan cocok dengan sintaks "komentar akhir".

Opsi lain adalah variabel comment-start, yang merupakan string yang dimasukkan oleh comment-dwimdan teman. Biasanya diatur ke karakter mulai komentar ditambah beberapa ruang.

Ada solusi yang lebih sederhana , silakan pelajari kode saya di https://github.com/redguardtoo/evil-nerd-commenter/blob/master/evil-nerd-commenter.el

Saya tidak akan menyalin / menempelkan semua kode di sini. tetapi inilah poin-poin utamanya:

• komentar memiliki wajah font sendiri, cari font-lock-comment-face dan font-lock-comment-delimiter-face dalam kode saya

• gunakan API Emacs sendiri untuk menghapus komentar pada baris kedua, lalu bergabung dengan baris pertama

Ini harus bekerja pada mode utama yang masuk akal.

Trik ini tidak saya temukan. Ini sebenarnya dari kode Emacs sendiri, (lebih khusus, flyspell). Jadi solusinya harus mendukung semua dukungan mode terbang utama mode

Jika Anda mencari fitur ini untuk kode lisp (Elisp, Clojure, Skema dan Common Lisp), maka Anda harus mencoba lispy , sebuah fungsi yang disebut lispy-fillmelakukan hal semacam ini.

Jika Anda mencari fitur ini untuk bahasa lain, maka Anda harus rebox2 (diverifikasi untuk Cdan Python), fungsi yang disebut rebox-fillatau fungsi lain yang disebut rebox-dwimmelakukan hal semacam ini.

Keduanya adalah paket yang bagus, dan tidak saling bertentangan karena keduanya digunakan untuk mode-mode utama yang berbeda, dan keduanya ( lispy-filldan rebox-dwim) terikat M-q, cukup rapi.