buat `delete-duplikat-baris` abaikan baris kosong dan kata-kata tertentu

9

Saya mengedit teks dalam mode org, beberapa baris diulang karena mereka merupakan bagian dari file yang berbeda dari topik yang sama.

Saya ingin menggunakan delete-duplicate-linesuntuk menghapus baris yang diulang, namun, perintah menghapus baris kosong juga, yang merupakan sesuatu yang tidak saya inginkan (kalau tidak saya tidak akan memiliki paragraf!). Saya ingin mengabaikan kata-kata tertentu yang ada sendirian dalam barisan, misalnya, "Lanjutkan" , itu diulangi berkali-kali dalam teks, tetapi saya ingin menyimpannya karena diperlukan.

text-editing shackra
sumber

Jawaban:

5

Mengabaikan garis kosong

Anda dapat memberitahu delete-duplicate-linesuntuk mengabaikan garis kosong dengan memanggilnya melalui

C-u C-u C-u M-x delete-duplicate-lines RET

Jika Anda tidak ingin harus memukul C-usebanyak itu saat menelepon delete-duplicate-lines, Anda bisa membungkusnya dengan perintah khusus dan mengikat perintah itu ke urutan kunci pilihan Anda:

(defun delete-duplicate-lines-keep-blanks ()
  (interactive)
  (delete-duplicate-lines (region-beginning) (region-end) nil nil t))

(global-set-key (kbd "C-c d") 'delete-duplicate-lines-keep-blanks)

Mengabaikan garis yang cocok dengan regexp

Adapun bagian kedua dari pertanyaan Anda, saya tidak berpikir Anda dapat mencapai apa yang Anda inginkan menggunakan versi built-in delete-duplicate-lines. Anda dapat, bagaimanapun, menggunakan versi modifikasi dari perintah (yang juga menjaga baris kosong secara default):

(defun delete-duplicate-lines
    (beg end keep &optional reverse adjacent keep-blanks interactive)
  (interactive
   (progn
     (barf-if-buffer-read-only)
     (list (region-beginning) (region-end)
           (read-string "Keep lines matching regexp: ") ; Prompt for regexp to keep
           (equal current-prefix-arg '(4))
           (equal current-prefix-arg '(16))
           t                                            ; Keep blanks by default
           t)))
  (let ((lines (unless adjacent (make-hash-table :test 'equal)))
        line prev-line
        (count 0)
        (beg (copy-marker beg))
        (end (copy-marker end)))
    (save-excursion
      (goto-char (if reverse end beg))
      (if (and reverse (bolp)) (forward-char -1))
      (while (if reverse
             (and (> (point) beg) (not (bobp)))
               (and (< (point) end) (not (eobp))))
        (setq line (buffer-substring-no-properties
                (line-beginning-position) (line-end-position)))
        (if (or (and keep-blanks (string= "" line))
                (string-match keep line))               ; Ignore line if it
                                                        ; matches regexp to keep
            (forward-line 1)
          (if (if adjacent (equal line prev-line) (gethash line lines))
              (progn
                (delete-region (progn (forward-line 0) (point))
                               (progn (forward-line 1) (point)))
                (if reverse (forward-line -1))
                (setq count (1+ count)))
            (if adjacent (setq prev-line line) (puthash line t lines))
            (forward-line (if reverse -1 1))))))
    (set-marker beg nil)
    (set-marker end nil)
    (when interactive
      (message "Deleted %d %sduplicate line%s%s"
               count
               (if adjacent "adjacent " "")
               (if (= count 1) "" "s")
               (if reverse " backward" "")))
    count))

Versi ini delete-duplicate-linesakan meminta Anda untuk regexp dan menyimpan semua baris yang cocok dengan regexp. Misalnya, untuk menjaga semua baris yang terdiri dari kata Resumeyang akan Anda lakukan:

M-x delete-duplicate-lines RET ^Resume$ RET

itu hanya
sumber