Menurut simpul manual pada Mengisi , beberapa fungsi isian mengambil argumen JUSTIFY opsional yang dapat Anda gunakan. Jadi, misalnya, untuk mengisi paragraf dengan justifikasi yang tepat, Anda bisa menggunakan (fill-paragraph 'right).
Anda juga dapat menggunakan (justify-current-line 'right)untuk satu baris.
Jika Anda berencana untuk menggunakan banyak opsi ini, Anda dapat membungkusnya dalam fungsi-fungsi, seperti berikut ini, dan kemudian ikat fungsi-fungsi ini ke tombol pilihan Anda:
(defun right-justify-current-line ()
"Right-justify this line."
(interactive)
(justify-current-line 'right))
(defun right-fill-paragraph ()
"Fill paragraph with right justification."
(interactive)
(fill-paragraph 'right))
Inilah fungsi yang mungkin Anda singgahi sebagai pengganti fill-paragraph. Dengan berbagai awalan, Anda dapat memutuskan jenis justifikasi apa yang akan digunakan pada paragraf yang Anda isi:
(defun fill-paragraph-dwim (&optional arg)
"Fills the paragraph as normal with no prefix. With C-u,
right-justify. With C-u C-u, center-justify. With C-u C-u C-u,
full-justify."
(interactive "p")
(fill-paragraph (cond ((= arg 4) 'right)
((= arg 16) 'center)
((= arg 64) 'full))))
Jika Anda tidak ingin mengisi ketika Anda sedang meluruskan ke kanan, Anda dapat menggunakan fungsi berikut, yang disambungkan langsung dari center-regionfungsi dengan perubahan satu baris untuk membuatnya menyelaraskan ke kanan:
(defun right-region (from to)
"Right-justify each nonblank line starting in the region."
(interactive "r")
(if (> from to)
(let ((tem to))
(setq to from from tem)))
(save-excursion
(save-restriction
(narrow-to-region from to)
(goto-char from)
(while (not (eobp))
(or (save-excursion (skip-chars-forward " \t") (eolp))
;; (center-line)) ; this was the original code
(justify-current-line 'right)) ; this is the new code
(forward-line 1)))))
