buat `buffer-sebelumnya` dan` buffer-depan` untuk mengabaikan beberapa buffer

di Helm saya mengabaikan beberapa buffer untuk ditampilkan ketika menggunakan C-x b, saya mencari cara untuk membuat perintah previous-bufferdan next-bufferberperilaku sama mengabaikan beberapa buffer.

Berikut ini dua cara:

1. Jika Anda melihat definisi fungsi switch-to-next-buffer(di perpustakaan window.el) Anda akan melihat bahwa itu menyaring buffer oleh predikat (jika ada) yang merupakan nilai parameter bingkai buffer-predicate. Fungsi itu digunakan oleh next-buffer.

   Anda dapat mengatur parameter frame ke predikat yang memfilter seperti yang Anda inginkan.

2. Anda cukup menyarankan fungsi switch-to-next-bufferuntuk memfilter seperti yang Anda inginkan. Anda pada dasarnya akan mengganti definisinya dengan definisi yang hampir sama, tetapi menyaring juga seperti yang Anda inginkan.

Demikian pula untuk switch-to-previous-buffer.

(defvar my-skippable-buffers '("*Messages*" "*scratch*" "*Help*")
  "Buffer names ignored by `my-next-buffer' and `my-previous-buffer'.")

(defun my-change-buffer (change-buffer)
  "Call CHANGE-BUFFER until current buffer is not in `my-skippable-buffers'."
  (let ((initial (current-buffer)))
    (funcall change-buffer)
    (let ((first-change (current-buffer)))
      (catch 'loop
        (while (member (buffer-name) my-skippable-buffers)
          (funcall change-buffer)
          (when (eq (current-buffer) first-change)
            (switch-to-buffer initial)
            (throw 'loop t)))))))

(defun my-next-buffer ()
  "Variant of `next-buffer' that skips `my-skippable-buffers'."
  (interactive)
  (my-change-buffer 'next-buffer))

(defun my-previous-buffer ()
  "Variant of `previous-buffer' that skips `my-skippable-buffers'."
  (interactive)
  (my-change-buffer 'previous-buffer))

(global-set-key [remap next-buffer] 'my-next-buffer)
(global-set-key [remap previous-buffer] 'my-previous-buffer)