Emacs berfungsi untuk mengubah PROPERTI ORG yang sewenang-wenang menjadi string sewenang-wenang (yaitu, label LaTeX)?

Saya memiliki banyak dokumen sebagai file org yang memiliki properti CUSTOM_LABEL, seperti

* Introduction :PROPERTIES: :CUSTOM_LABEL: AP 1 :END:

Dalam hal ini, file perlu diekspor sebagai LaTeX, menerjemahkan masing CUSTOM_LABEL- masing sebagai a \label{marker}. Contoh di atas harus diterjemahkan ke \label{AP 1}.

Saya sudah tahu cara memanggil fungsi kustom pada waktu ekspor, tetapi saya tidak cukup ahli untuk menulis defun untuk melakukan konversi tertentu, yaitu CUSTOM_LABEL->\label{}

Bagaimana defun untuk menyuntikkan custom_labelseperti yang \label{}ditulis

Saya akan menghargai bahkan hanya beberapa pseudo-code, atau beberapa pointer.

Saya mengajukan pertanyaan ini di sini alih-alih di tempat lain, karena ini lebih merupakan pertanyaan Emacs, karena saya mencari secara menyeluruh manual mode-org, dan fitur semacam itu saat ini tidak tersedia.

Fungsi generik untuk mengonversi PROPERTI yang diberikan saat mengekspor (LaTeX, HTML, atau format lainnya), akan lebih baik.

Terima kasih.

Saya telah menulis fungsi yang melakukan apa yang Anda inginkan dengan cara yang cukup panjang. Ia memeriksa tajuk mana yang berisi properti CUSTOM_LABEL (atau properti lain yang Anda konfigurasikan) dan memanggil fungsi endless/insert-org-label-latexmasing-masing dengan nilai properti sebagai argumen.

Cuplikan contoh juga menunjukkan cara memperluasnya untuk html atau backend lainnya.

Konfigurasikan penggantian

Dengan variabel ini, Anda dapat mengonfigurasi properti yang Anda pedulikan dan fungsi mana yang dipanggil untuk menangani masing-masing properti.

(defcustom endless/org-property-mapping 
  '((latex ("CUSTOM_LABEL" . endless/insert-org-label-latex))
    (html ("CUSTOM_LABEL" . endless/insert-org-label-html)))
  "List of mappings from org property to arbitrary strings.
Each element is a list:
  (BACKEND (PROPERTY1 . FUNCTION1) (PROPERTY2 . FUNCTION2) ...)

FUNCTION are functions which get called with a single
argument (the value of PROPERTY) and are responsible for doing
whatever should be done."
  :type '(repeat (cons symbol (repeat (cons string string)))))

Pekerja Berat

Fungsi ini adalah apa yang harus Anda tambahkan ke kait ekspor org. Ini mengurus memeriksa properti yang tercantum di atas, dan memanggil fungsi yang terkait dengan properti tersebut.

(defun endless/replace-org-property (backend)
  "Convert org properties using `endless/org-property-mapping'.
Lookup BACKEND in `endless/org-property-mapping' for a list of
\(PROPERTY REPLACEMENT). For each healine being exported, if it has a
PROPERTY listed insert a string immediately after the healine given by
    (format REPLACEMENT PROPERTY-VALUE)"
  (let ((map (cdr (assoc backend endless/org-property-mapping)))
        value replacement)
    (when map      
      (org-map-entries
       (lambda () 
         (dolist (it map)
           (save-excursion
             (when (setq value (org-entry-get (point) (car it))) 
               (funcall (cdr it) value)))))))))

(add-hook 'org-export-before-processing-hook #'endless/replace-org-property)

Fungsi yang Anda tetapkan

Ini adalah orang-orang yang melakukan penggantian yang sebenarnya. Di bawah ini adalah contoh untuk kasus lateks.

(defun endless/insert-org-label-latex (label)
  "Insert \"\\\\label{LABEL}\\n\" after the :PROPERTY: drawer."
  (search-forward-regexp org-property-end-re)
  (forward-char 1)
  (insert (format "\\label{%s}\n" label)))

Hasil

Evaluasi semua kode ini di atas, lalu ekspor buffer org berikut ke lateks.

* Test
  :PROPERTIES:
  :CUSTOM_LABEL: hi
  :END:
Test

Buffer lateks yang dihasilkan harus seperti ini.

\section{Test}
\label{sec-1}
\label{hi}
Test

Catatan untuk cuplikan kode Anda harus menggunakan versi pengembangan saat ini (org-version) => "8.3beta",.

Silakan gunakan CUSTOM_IDdan tautan internal. Lihat (info "(org) Handling links").

Dalam kebanyakan kasus, Anda tidak perlu khawatir tentang hasil penamaan internal yang diekspor di Org. Tautan ke angka dan tajuk berita, katakanlah, akan benar ketika diekspor. Lihat (info "(org) Internal links").

Untuk LaTeX coba:

(with-temp-buffer
  (let ((org-latex-prefer-user-labels t))
(insert "
* h
:PROPERTIES:
:CUSTOM_ID: h
:END:")
(org-mode)
(org-latex-export-as-latex nil nil nil t)))

Hasil:

\section{h}
\label{h}

Dalam eksportir seperti ox-odtdan ox-htmltajuk berisi id internal, IDdan CUSTOM_ID. Tautan mana yang digunakan tergantung pada tautan:

(with-temp-buffer
  (let ((org-export-with-toc nil))
(insert "
* h
:PROPERTIES:
:CUSTOM_ID: h
:END:
[[*h]] [[#h]]")
(org-mode)
(org-html-export-as-html nil nil nil t)))

Hasil:

<div id="outline-container-h" class="outline-2">
<h2 id="h"><a id="sec-1"></a><span class="section-number-2">1</span> h</h2>
<div class="outline-text-2" id="text-h">
<p>
<a href="#sec-1">1</a> <a href="#h">1</a>
</p>
</div>
</div>

Saya tidak yakin, tetapi Anda mungkin perlu memberi saran atau bahkan menimpa fungsi eksportir. Dalam Org 8, itu org-latex-export-headline.

Fungsi ini mendapatkan elemen tajuk, isi tajuk, dan daftar properti tambahan. Dalam fungsi eksportir, Anda bisa mendapatkan properti elemen (termasuk label khusus) org-element-property.