Saya terkejut bahwa tantangan ini belum ada di sini, karena sudah sangat jelas. (Atau saya terkejut saya tidak bisa menemukannya dan siapa pun akan menandainya sebagai duplikat.)

Tugas

Dengan bilangan bulat -negatif $n$, hitung jumlah bilangan prima pertama $n$dan hasilkan.

Contoh 1

Untuk $n = 5$ , lima bilangan prima pertama adalah:

• 2
• 3
• 5
• 7
• 11

Jumlah angka-angka ini adalah $2 + 3 + 5 + 7 + 11 = 28$ , sehingga program harus menghasilkan $28$ .

Contoh # 2

Untuk $n = 0$ , bilangan prima "nol pertama" tidak ada. Dan jumlah no angka - tentu saja - $0$ .

Aturan

• Anda dapat menggunakan built-in, misalnya, untuk memeriksa apakah suatu bilangan prima.
• Ini adalah kode-golf , sehingga jumlah byte terendah di setiap bahasa menang!

6502 rutin kode mesin , 75 byte

A0 01 84 FD 88 84 FE C4 02 F0 32 E6 FD A0 00 A5 FD C9 04 90 1F 85 64 B1 FB 85
65 A9 00 A2 08 06 64 2A C5 65 90 02 E5 65 CA D0 F4 C9 00 F0 DC C8 C4 FE D0 DB
A5 FD A4 FE 91 FB C8 D0 C8 A9 00 18 A8 C4 FE F0 05 71 FB C8 D0 F7 60

Mengharapkan pointer ke beberapa penyimpanan sementara di $fb/ $fcdan jumlah bilangan prima untuk diringkas $2. Mengembalikan jumlah padaA (register accu).

Tidak pernah melakukan beberapa pemeriksaan prima dalam kode mesin 6502, jadi ini dia akhirnya;)

Perhatikan ini mulai memberikan hasil yang salah untuk input> = 14. Ini karena overflow, kode ini bekerja dengan kisaran nomor "alami" dari platform 8bit yang 0 - 255untuk unsigned .

Komentar pembongkaran

; function to sum the first n primes
;
; input:
;   $fb/$fc: pointer to a buffer for temporary storage of primes
;   $2:      number of primes to sum (n)
; output:
;   A:       sum of the first n primes
; clobbers:
;   $fd:     current number under primality test
;   $fe:     number of primes currently found
;   $64:     temporary numerator for modulo check
;   $65:     temporary divisor for modulo check
;   X, Y
 .primesum:
A0 01       LDY #$01            ; init variable for ...
84 FD       STY $FD             ; next prime number to test
88          DEY                 ; init number of found primes
 .mainloop:
84 FE       STY $FE             ; store current number of found primes
C4 02       CPY $02             ; compare with requested number
F0 32       BEQ .sum            ; enough primes -> calculate their sum
 .mainnext:
E6 FD       INC $FD             ; check next prime number
A0 00       LDY #$00            ; start check against first prime number
 .primecheckloop:
A5 FD       LDA $FD             ; load current number to check
C9 04       CMP #$04            ; smaller than 4?
90 1F       BCC .isprime        ; is a prime (shortcut to get list started)
85 64       STA $64             ; store to temp as numerator
B1 FB       LDA ($FB),Y         ; load from prime number table
85 65       STA $65             ; store to temp as divisor
A9 00       LDA #$00            ; init modulo to 0
A2 08       LDX #$08            ; iterate over 8 bits
 .bitloop:
06 64       ASL $64             ; shift left numerator
2A          ROL A               ; shift carry into modulo
C5 65       CMP $65             ; compare with divisor
90 02       BCC .bitnext        ; smaller -> to next bit
E5 65       SBC $65             ; otherwise subtract divisor
 .bitnext:
CA          DEX                 ; next bit
D0 F4       BNE .bitloop
C9 00       CMP #$00            ; compare modulo with 0
F0 DC       BEQ .mainnext       ; equal? -> no prime number
C8          INY                 ; next index in prime number table
C4 FE       CPY $FE             ; checked against all prime numbers?
D0 DB       BNE .primecheckloop ; no -> check next
 .isprime:
A5 FD       LDA $FD             ; prime found
A4 FE       LDY $FE             ; then store in table
91 FB       STA ($FB),Y
C8          INY                 ; increment number of primes found
D0 C8       BNE .mainloop       ; and repeat whole process
 .sum:
A9 00       LDA #$00            ; initialize sum to 0
18          CLC
A8          TAY                 ; start adding table from position 0
 .sumloop:
C4 FE       CPY $FE             ; whole table added?
F0 05       BEQ .done           ; yes -> we're done
71 FB       ADC ($FB),Y         ; add current entry
C8          INY                 ; increment index
D0 F7       BNE .sumloop        ; and repeat
 .done:
60          RTS

Contoh program assembler C64 menggunakan rutin:

Demo online

Kode dalam sintaksis ca65 :

.import primesum   ; link with routine above

.segment "BHDR" ; BASIC header
                .word   $0801           ; load address
                .word   $080b           ; pointer next BASIC line
                .word   2018            ; line number
                .byte   $9e             ; BASIC token "SYS"
                .byte   "2061",$0,$0,$0 ; 2061 ($080d) and terminating 0 bytes

.bss
linebuf:        .res    4               ; maximum length of a valid unsigned
                                        ; 8-bit number input
convbuf:        .res    3               ; 3 BCD digits for unsigned 8-bit
                                        ; number conversion
primebuf:       .res    $100            ; buffer for primesum function

.data
prompt:         .byte   "> ", $0
errmsg:         .byte   "Error parsing number, try again.", $d, $0

.code
                lda     #$17            ; set upper/lower mode
                sta     $d018

input:
                lda     #<prompt        ; display prompt
                ldy     #>prompt
                jsr     $ab1e

                lda     #<linebuf       ; read string into buffer
                ldy     #>linebuf
                ldx     #4
                jsr     readline

                lda     linebuf         ; empty line?
                beq     input           ; try again

                lda     #<linebuf       ; convert input to int8
                ldy     #>linebuf
                jsr     touint8
                bcc     numok           ; successful -> start processing
                lda     #<errmsg        ; else show error message and repeat
                ldy     #>errmsg
                jsr     $ab1e
                bcs     input

numok:          
                sta     $2
                lda     #<primebuf
                sta     $fb
                lda     #>primebuf
                sta     $fc
                jsr     primesum        ; call function to sum primes
                tax                     ; and ...
                lda     #$0             ; 
                jmp     $bdcd           ; .. print result

; read a line of input from keyboard, terminate it with 0
; expects pointer to input buffer in A/Y, buffer length in X
.proc readline
                dex
                stx     $fb
                sta     $fc
                sty     $fd
                ldy     #$0
                sty     $cc             ; enable cursor blinking
                sty     $fe             ; temporary for loop variable
getkey:         jsr     $f142           ; get character from keyboard
                beq     getkey
                sta     $2              ; save to temporary
                and     #$7f
                cmp     #$20            ; check for control character
                bcs     checkout        ; no -> check buffer size
                cmp     #$d             ; was it enter/return?
                beq     prepout         ; -> normal flow
                cmp     #$14            ; was it backspace/delete?
                bne     getkey          ; if not, get next char
                lda     $fe             ; check current index
                beq     getkey          ; zero -> backspace not possible
                bne     prepout         ; skip checking buffer size for bs
checkout:       lda     $fe             ; buffer index
                cmp     $fb             ; check against buffer size
                beq     getkey          ; if it would overflow, loop again
prepout:        sei                     ; no interrupts
                ldy     $d3             ; get current screen column
                lda     ($d1),y         ; and clear 
                and     #$7f            ;   cursor in
                sta     ($d1),y         ;   current row
output:         lda     $2              ; load character
                jsr     $e716           ;   and output
                ldx     $cf             ; check cursor phase
                beq     store           ; invisible -> to store
                ldy     $d3             ; get current screen column
                lda     ($d1),y         ; and show
                ora     #$80            ;   cursor in
                sta     ($d1),y         ;   current row
                lda     $2              ; load character
store:          cli                     ; enable interrupts
                cmp     #$14            ; was it backspace/delete?
                beq     backspace       ; to backspace handling code
                cmp     #$d             ; was it enter/return?
                beq     done            ; then we're done.
                ldy     $fe             ; load buffer index
                sta     ($fc),y         ; store character in buffer
                iny                     ; advance buffer index
                sty     $fe
                bne     getkey          ; not zero -> ok
done:           lda     #$0             ; terminate string in buffer with zero
                ldy     $fe             ; get buffer index
                sta     ($fc),y         ; store terminator in buffer
                sei                     ; no interrupts
                ldy     $d3             ; get current screen column
                lda     ($d1),y         ; and clear 
                and     #$7f            ;   cursor in
                sta     ($d1),y         ;   current row
                inc     $cc             ; disable cursor blinking
                cli                     ; enable interrupts
                rts                     ; return
backspace:      dec     $fe             ; decrement buffer index
                bcs     getkey          ; and get next key
.endproc

; parse / convert uint8 number using a BCD representation and double-dabble
.proc touint8
                sta     $fb
                sty     $fc
                ldy     #$0
                sty     convbuf
                sty     convbuf+1
                sty     convbuf+2
scanloop:       lda     ($fb),y
                beq     copy
                iny
                cmp     #$20
                beq     scanloop
                cmp     #$30
                bcc     error
                cmp     #$3a
                bcs     error
                bcc     scanloop
error:          sec
                rts
copy:           dey
                bmi     error
                ldx     #$2
copyloop:       lda     ($fb),y
                cmp     #$30
                bcc     copynext
                cmp     #$3a
                bcs     copynext
                sec
                sbc     #$30
                sta     convbuf,x
                dex
copynext:       dey
                bpl     copyloop
                lda     #$0
                sta     $fb
                ldx     #$8
loop:           lsr     convbuf
                lda     convbuf+1
                bcc     skipbit1
                ora     #$10
skipbit1:       lsr     a
                sta     convbuf+1
                lda     convbuf+2
                bcc     skipbit2
                ora     #$10
skipbit2:       lsr     a
                sta     convbuf+2
                ror     $fb
                dex
                beq     done
                lda     convbuf
                cmp     #$8
                bmi     nosub1
                sbc     #$3
                sta     convbuf
nosub1:         lda     convbuf+1
                cmp     #$8
                bmi     nosub2
                sbc     #$3
                sta     convbuf+1
nosub2:         lda     convbuf+2
                cmp     #$8
                bmi     loop
                sbc     #$3
                sta     convbuf+2
                bcs     loop
done:           lda     $fb
                clc
                rts
.endproc

Python 2 , 49 byte

f=lambda n,t=1,p=1:n and p%t*t+f(n-p%t,t+1,p*t*t)

Menggunakan teorema Wilson , (seperti yang diperkenalkan ke situs oleh xnor, saya percaya di sini )

Cobalah online!

Fungsi fini bersifat rekursif, dengan input awal ndan ekor ketika nmencapai nol, menghasilkan nol itu (karena logis and); nakan dikurangi kapan saja t, nomor tes yang bertambah dengan setiap panggilan f, adalah prima. Tes prima adalah apakah yang dengannya kami melacak kuadrat faktorial.$(n-1)!\ \equiv\ -1 \pmod n$p

Jelly , 4 byte

Program Jelly pertama saya

RÆNS

Cobalah online!

05AB1E , 3 byte

ÅpO

Cobalah online.

Penjelasan:

Åp     # List of the first N primes (N being the implicit input)
       #  i.e. 5 → [2,3,5,7,11]
  O    # Sum of that list
       #  i.e. [2,3,5,7,11] → 28

Java 8, 89 byte

n->{int r=0,i=2,t,x;for(;n>0;r+=t>1?t+0*n--:0)for(t=i++,x=2;x<t;t=t%x++<1?0:t);return r;}

Cobalah online.

Penjelasan:

n->{               // Method with integer as both parameter and return-type
  int r=0,         //  Result-sum, starting at 0
      i=2,         //  Prime-integer, starting at 2
      t,x;         //  Temp integers
  for(;n>0         //  Loop as long as `n` is still larger than 0
      ;            //    After every iteration:
       r+=t>1?     //     If `t` is larger than 1 (which means `t` is a prime):
           t       //      Increase `r` by `t`
           +0*n--  //      And decrease `n` by 1
          :        //     Else:
           0)      //      Both `r` and `n` remain the same
    for(t=i++,     //   Set `t` to the current `i`, and increase `i` by 1 afterwards
        x=2;       //   Set `x` to 2
        x<t;       //   Loop as long as `x` is still smaller than `t`
      t=t%x++<1?   //    If `t` is divisible by `x`:
         0         //     Set `t` to 0
        :          //    Else:
         t);       //     `t` remains the same
                   //   If `t` is still the same after this loop, it means it's a prime
  return r;}       //  Return the result-sum

Perl 6 , 31 byte

{sum grep(&is-prime,2..*)[^$_]}

Cobalah online!

The is-primebuilt-in sayangnya panjang.

J , 8 byte

1#.p:@i.

Cobalah online!

Brachylog , 8 7 byte

~lṗᵐ≠≜+

Cobalah online!

Disimpan 1 byte berkat @sundar.

Penjelasan

~l        Create a list of length input
  ṗᵐ      Each element of the list must be prime
    ≠     All elements must be distinct
     ≜    Find values that match those constraints
      +   Sum

Sekam , 4 byte

Σ↑İp

Cobalah online!

Menghasilkan İ daftar nfinite dari p nomor rime, dan menghitung jumlah dari pertama$N$( Σ↑)

Attache , 10 byte

Sum@Primes

Cobalah online!

ho hum

Retina , 41 byte

K`_
"$+"{`$
$%"_
)/¶(__+)\1+$/+`$
_
^_

_

Cobalah online! Saya ingin terus menambahkan 1 sampai saya telah menemukan nbilangan prima, tetapi saya tidak tahu bagaimana cara melakukannya di Retina jadi saya beralih ke loop bersarang. Penjelasan:

K`_

Mulai dengan 1.

"$+"{`

nWaktu loop .

$
$%"_

Buat salinan dari nilai sebelumnya, dan tambahkan.

)/¶(__+)\1+$/+`$
_

Terus menambahnya selagi komposit. (The )menutup loop luar.)

^_

Hapus yang asli 1.

_

Jumlahkan dan konversikan ke desimal.

MATL , 4 byte

:Yqs

Cobalah online!

Penjelasan:

       % Implicit input: 5
:      % Range: [1, 2, 3, 4, 5]
 Yq    % The n'th primes: [2, 3, 5, 7, 11]
   s   % Sum: 28

PHP, 66 byte

menggunakan fungsi utama saya sendiri lagi ...

for(;$k<$argn;$i-1||$s+=$n+!++$k)for($i=++$n;--$i&&$n%$i;);echo$s;

Jalankan sebagai pipa dengan -nratau coba online .

kerusakan

for(;$k<$argn;      # while counter < argument
    $i-1||              # 3. if divisor is 1 (e.g. $n is prime)
        $s+=$n              # add $n to sum
        +!++$k              # and increment counter
    )
    for($i=++$n;        # 1. increment $n
        --$i&&$n%$i;);  # 2. find largest divisor of $n smaller than $n:
echo$s;             # print sum

Haskell , 48 byte

sum.(`take`[p|p<-[2..],all((>0).mod p)[2..p-1]])

Cobalah online!

Catatan: \p-> all((>0).mod p)[2..p-1] bukan pemeriksaan perdana yang valid, karena ini Trueuntuk$0,1$demikian juga. Tapi kita bisa mengatasinya dengan memulainya$2$, jadi dalam hal ini sudah cukup.

C (gcc) , 70 byte

f(n,i,j,s){s=0;for(i=2;n;i++)for(j=2;j/i?s+=i,n--,0:i%j++;);return s;}

Cobalah online!

C, C ++, D: 147 142 byte

int p(int a){if(a<4)return 1;for(int i=2;i<a;++i)if(!(a%i))return 0;return 1;}int f(int n){int c=0,v=1;while(n)if(p(++v)){c+=v;--n;}return c;}

Optimasi 5 byte untuk C dan C ++:

-2 byte terima kasih kepada Zacharý

#define R return
int p(int a){if(a<4)R 1;for(int i=2;i<a;++i)if(!(a%i))R 0;R 1;}int f(int n){int c=0,v=1;while(n)if(p(++v))c+=v,--n;R c;}

pmenguji apakah suatu bilangan prima, fmenjumlahkan nbilangan pertama

Kode yang digunakan untuk menguji:

C / C ++:

for (int i = 0; i < 10; ++i)
    printf("%d => %d\n", i, f(i));

D Dioptimalkan jawaban oleh Zacharý , 133 131 byte

D memiliki sistem templat golf

T p(T)(T a){if(a<4)return 1;for(T i=2;i<a;)if(!(a%i++))return 0;return 1;}T f(T)(T n){T c,v=1;while(n)if(p(++v))c+=v,--n;return c;}

Japt -x , 11 byte

;@_j}a°X}hA

Cobalah online!

Menyimpan beberapa byte berkat fitur bahasa baru.

Penjelasan:

;@      }hA    :Get the first n numbers in the sequence:
     a         : Get the smallest number
      °X       : Which is greater than the previous result
  _j}          : And is prime
               :Implicitly output the sum

JavaScript (ES6), 55 byte

f=(k,n=2)=>k&&(g=d=>n%--d?g(d):d<2&&k--&&n)(n)+f(k,n+1)

Cobalah online!

Stax , 6 byte

ê☺Γ☼èY

Jalankan dan debug itu

Penjelasan:

r{|6m|+ Unpacked program, implicit input
r       0-based range
 {  m   Map:
  |6      n-th prime (0-based)
     |+ Sum
        Implicit output

APL (Dyalog Unicode) , 7 + 9 = 16 byte

+/pco∘⍳

Cobalah online!

9 byte tambahan untuk mengimpor pcoDfn (dan lainnya):⎕CY'dfns'

Bagaimana:

+/pco∘⍳
      ⍳ ⍝ Generate the range from 1 to the argument
     ∘  ⍝ Compose
  pco   ⍝ P-colon (p:); without a left argument, it generates the first <right_arg> primes.
+/      ⍝ Sum

Ruby, 22 + 7 = 29 byte

Jalankan dengan ruby -rprime(+7)

->n{Prime.take(n).sum}

Pari / GP , 20 byte

n->vecsum(primes(n))

Cobalah online!

JAEL , 5 byte

#&kȦ

Penjelasan (dihasilkan secara otomatis):

./jael --explain '#&kȦ'
ORIGINAL CODE:  #&kȦ

EXPANDING EXPLANATION:
Ȧ => .a!

EXPANDED CODE:  #&k.a!,

#     ,                 repeat (p1) times:
 &                              push number of iterations of this loop
  k                             push nth prime
   .                            push the value under the tape head
    a                           push p1 + p2
     !                          write p1 to the tape head
       ␄                print machine state

Python 2 , 63 59 56 51 byte

f=lambda n:n and prime(n)+f(n-1)
from sympy import*

Cobalah online!

Diselamatkan:

• -5 byte, terima kasih kepada Jonathan Allan

Tanpa libs:

Python 2 , 83 byte

n,s=input(),0
x=2
while n:
 if all(x%i for i in range(2,x)):n-=1;s+=x
 x+=1
print s

Cobalah online!

Pyke , 4 byte

~p>s

Coba di sini!

~p   -   prime_numbers
  >  -  first_n(^, input)
   s - sum(^)

CJam , 21 byte

0{{T1+:Tmp!}gT}li*]:+

Explanation:
0{{T1+:Tmp!}gT}li*]:+ Original code

 {            }li*    Repeat n times
  {        }          Block
   T                  Get variable T | stack: T
    1+                Add one | Stack: T+1 
      :T              Store in variable T | Stack: T+1
        mp!           Is T not prime?     | Stack: !(isprime(T))
            g         Do while condition at top of stack is true, pop condition
             T        Push T onto the stack | Stack: Primes so far
0                 ]   Make everything on stack into an array, starting with 0 (to not throw error if n = 0)| Stack: array with 0 and all primes up to n
                   :+ Add everything in array

Cobalah online!

F #, 111 byte

let f n=Seq.initInfinite id|>Seq.filter(fun p->p>1&&Seq.exists(fun x->p%x=0){2..p-1}|>not)|>Seq.take n|>Seq.sum

Cobalah online!

Seq.initInfinitemenciptakan urutan yang sangat panjang dengan fungsi generator yang mengambil, sebagai parameter, indeks item. Dalam hal ini fungsi generator hanyalah fungsi identitas id.

Seq.filter hanya memilih angka-angka yang dibuat oleh urutan tak terbatas yang prima.

Seq.takemengambil nelemen pertama dalam urutan itu.

Dan akhirnya, Seq.sumsimpulkan mereka.

cQuents , 3 byte

;pz

Cobalah online!

Penjelasan

;    sum of first n terms for input n
 pz  each term is the next prime after the previous term

MY , 4 byte

⎕ṀΣ↵

Cobalah online!

Masih menyesali tidak ada input / output implisit dalam bahasa sampah ini, sudah dua byte sebaliknya.

• ⎕ = input
• Ṁ = 1 ... termasuk prime prime
• Σ = jumlah
• ↵ = keluaran

APL (NARS), 27 karakter, 54 byte

{⍵=0:0⋄+/{⍵=1:2⋄¯2π⍵-1}¨⍳⍵}

{¯2π⍵} di sini akan mengembalikan n prime berbeda dari 2. Jadi {⍵ = 1: 2⋄¯2π⍵-1} akan mengembalikan n prime 2 dalam hitungan di dalamnya ...