Bagaimana cara membuat Layanan Automator untuk mengubah font teks yang dipilih?

Saya mencoba membuat "Layanan" di Automator yang mengubah font teks yang dipilih di aplikasi paling depan.

Anda dapat menetapkan pintasan ke skrip seperti ini:

tell application "System Events" to tell (process 1 where frontmost is true)
    set {c1, c2} to value of attribute "AXSelectedTextRange" of text area 1 of scroll area 1 of window 1
end tell
tell application (path to frontmost application as text) to tell document 1
    tell characters c1 thru c2
        set font to "Menlo"
        set size to 18
    end tell
end tell

Ini berfungsi dengan TextEdit dan WriteRoom, tetapi mungkin perlu dimodifikasi untuk aplikasi lain.

Pilihan lain yang benar-benar mengerikan:

try
    set old to the clipboard as record
end try
do shell script "textutil -stdin -stdout -format html -convert rtf <<< '<span style=\"font: 18px Menlo\">a</span>' | pbcopy"
tell application "System Events"
    keystroke "v" using command down
    keystroke "c" using {option down, command down}
    keystroke "z" using command down
    keystroke "v" using {option down, command down}
end tell
delay 0.05
try
    set the clipboard to old
end try

Setelah banyak penelitian, alur kerja di bawah ini berfungsi untuk saya di TextEdit, Mail, Notes, Stickies. Di mana itu tidak berfungsi adalah ketika aplikasi menggunakan Styles (Microsoft Word, Pages, Keynote), karena gaya menimpa font yang Anda input. Satu-satunya cara saya bisa memikirkan untuk mengganti gaya adalah dengan langsung skrip setiap aplikasi untuk membuat gaya kustom.

Kode ApplesScript:

on run {input, parameters}

    do shell script "pbpaste | textutil -stdin -stdout -convert rtf -font Arial -fontsize 12 | pbcopy"
    tell application "System Events" to keystroke "v" using command down

    return input
end run