Bagaimana cara menyimpan pesan terkirim dalam folder yang sama dengan pesan yang dibalas?

Salah satu fitur favorit saya saat saya menggunakan Outlook adalah opsi untuk menyimpan email yang terkirim di folder yang sama dengan pesan yang dibalas. Misalnya, jika saya telah memindahkan pesan ke folder A dan membalasnya, balasan saya disimpan di A, bukan Terkirim. (Jika saya membalas pesan di Kotak Masuk saya, balasan saya pergi ke folder Terkirim default.)

Ini membuatnya sangat mudah untuk melihat seluruh utas ketika saya kembali lagi nanti. Alur kerja ini sangat menghemat waktu bagi saya dan satu-satunya hal yang saya lewatkan dari Outlook. Saat ini, saya secara manual memindahkan pesan yang dikirim ke folder dengan pesan terkait yang membosankan. Apakah ada cara untuk membuat ulang fitur ini dari Outlook dengan Mac Mail? (Saya menggunakan Mac Mail 6.2 pada OSX 10.8.2).

Mail dapat diperluas untuk meniru dengan sangat dekat fitur yang Anda sebutkan dari Outlook.

OS X menyediakan fitur yang disebut layanan yang dapat digunakan untuk memperluas fungsionalitas aplikasi (lihat http://www.macosxautomation.com/services/learn/index.html untuk informasi lebih lanjut).

Saya akan menggunakan Automator dan AppleScript untuk membuat layanan yang memindahkan pesan terkirim ke folder pesan yang dibalas, dan kemudian menetapkan pintasan keyboard balasan standar ( ⌘R) ke layanan:

• Tutup Surat.

• Buka Automator di folder Applicationsdan pilih Layanan:

• Pilih Utilitas di bawah Perpustakaan dan seret Jalankan AppleScript ke panel kosong di sebelah kanan:

• Konfigurasikan layanan untuk tidak menerima input di Mail:

• Ganti konten dari tindakan Jalankan AppleScript dengan:

  on run {input, parameters}
  
  tell application "Mail"
      try
          (* Get selected messages or exit *)
          set messageSelection to selection
          set selectedMessage to item 1 of messageSelection
          set replyMessage to reply selectedMessage opening window yes
          set messageID to message id of selectedMessage
          set currentMailbox to mailbox of selectedMessage
      on error
          return
      end try
      repeat
          (* Wait until reply message is sent *)
          delay 2
          try
              if replyMessage is not visible then exit repeat
          on error
              exit repeat
          end try
      end repeat
      synchronize with (account of currentMailbox)
      (* Wait while reply message is being sent *)
      delay 10
      (* Loop over all sent messages *)
      set sentMailbox to sent mailbox of application "Mail"
      set allSentMessages to messages of sentMailbox
      repeat with sentMessage in allSentMessages
          if source of sentMessage contains messageID then
              set mailbox of sentMessage to currentMailbox
              return
          end if
      end repeat
  end tell
  
  return input
  end run
  

  • Simpan dengan nama deskriptif seperti Balas dan Pindahkan Pesan Terkirim ke Folder Saat Ini . Layanan akan disimpan ke ~/Library/Services/. Seperti apa layanan ini:

• Buka System Preferences, pilih panel preferensi Keyboard dan kemudian tab Shortcut Keyboard .

• Pilih Pintasan Aplikasi , tekan +tombol dan ubah untuk aplikasi Kirim pintasan yang ditetapkan ke item menu Balas ke ⌥⌘R. Kami mengubahnya untuk menghindari konflik saat menugaskan ⌘Rke layanan di bawah ini:

• Pilih Layanan , gulir ke bawah ke layanan yang sebelumnya Anda tambahkan dan atur pintasan keyboard ke ⌘R:

• Buka Surat. Perhatikan bahwa pintasan Balas tidak lagi ⌘R, tetapi ⌥⌘R:

• Juga perhatikan bahwa ada layanan baru, dapat diakses dengan ⌘R:

• Sekarang pilih pesan dalam folder, tekan ⌘R, ketik balasan Anda dan kirimkan, dalam beberapa detik Anda akan melihat pesan terkirim muncul di folder.

Script memiliki beberapa batasan dan efek samping:

• Layanan tidak dapat membedakan pesan yang dibatalkan dan dikirim. Jadi, jika Anda menekan ⌘Rdan kemudian berubah pikiran dan menutup jendela, layanan akan terus mengeksekusi dan memeriksa folder Terkirim Anda untuk ID yang cocok.

• AppleScript tidak menawarkan cara apa pun untuk mendapatkan daftar balasan pesan. Solusi saya adalah untuk mendapatkan id pesan dari pesan yang dibalas dan mencarinya di pesan yang dikirim.

• Pesan yang dikirim tidak dapat dipindahkan saat sedang diunduh. AppleScript tidak mengembalikan pesan kesalahan jika itu yang terjadi, jadi saya menambahkan penundaan 10 detik. Penundaan 5 detik tidak dapat diandalkan dalam pengujian saya, sesuaikan dengan kebutuhan Anda jika perlu.

• Saat layanan mencari folder Terkirim, Mail melambat.