Menggabungkan beberapa kolom menjadi satu di Google Sheets

15

masukkan deskripsi gambar di sini

Saya ingin menggabungkan / menggabungkan kolom A, B dan C ke kolom D seperti yang ditampilkan.

Jumlah entri yang diisi dalam A, B dan C akan bervariasi dari waktu ke waktu, sehingga alamat sel absolut tidak dapat digunakan.

Formula apa yang bisa saya masukkan ke D1 untuk mengisi kolom seperti yang diilustrasikan?

google-sheets concatenate Paulb
sumber
Saya sadar bahwa "menambahkan" mungkin lebih baik dari pada kosakata "gabungan." Karena gabungan adalah sesuatu yang biasanya Anda lakukan dengan nilai-nilai individual.
Paulb
1
Mungkin jawaban terbaik untuk menggabungkan manipulasi statistik di sini di mana Anda tidak perlu memfilter di sini webapps.stackexchange.com/a/69049/66725 Jadi gunakan saja = {A1:A; B1:B}. Dll untuk menghitung kecocokan unik dalam dua kolom = count(unique(A1:A; B1:B})).
Léo Léopold Hertz 준영

Jawaban:

9

Anda perlu memfilter ke sel yang tidak kosong, dan kemudian menumpuk hasilnya bersama:

={filter(A:A, len(A:A)); filter(B:B, len(B:B)); filter(C:C, len(C:C))}

Ini sama dengan jawaban ini oleh grayob yang sayangnya terkubur di bawah jawaban yang sudah ketinggalan zaman.

user79865
sumber
1
Bekerja dengan sempurna. Saya melihat bahwa Q dan saya fokus pada vmerge, tidak berhasil. Dalam Q itu, jawaban grayob lebih baik daripada jawaban yang diterima. Tks.
Paulb
13

Versi formula yang lebih pendek dalam jawaban lain ini

=FILTER({A:A;B:B;C:C}, LEN({A:A;B:B;C:C}))
Rubén
sumber
3

Sedikit lebih lama, tetapi dapat dibatasi ke array terbatas (bukan seluruh kolom):

=transpose(split(textjoin("|",1,{A1:C4}),"|"))

di mana urutannya tidak masalah. Dimana tempatnya:

=transpose(split(textjoin("|",1,{A1:A4;B1:B4;C1:C4}),"|"))
kacang
sumber
Ini adalah solusi favorit saya untuk masalah ini, tidak memerlukan penamaan semua kolom. Anda juga dapat melakukan SORT untuk solusi pertama di mana Anda ingin abjad.
Lou