Cara membuat kueri dengan Google Spreadsheet, yang memeriksa tanggal

Saya memiliki kisaran mulai dari itu B4:H124. Semua sel di kolom B adalah tanggal. Saya ingin mengambil data dari baris ( B:H), di mana DATE sama dengan konten sel tertentu, katakanlah Q4.

Bagaimana cara membuat kueri yang tepat?

Sejauh ini, apa yang saya dapatkan dengan ini:

=QUERY(B2:G124; "select * where B = date '2012-02-28'")

Ini berfungsi, meskipun format sel dalam B adalah DD / MM / YYYY.

Bagaimana saya bisa mengubah 2012-02-28ke $Q4? Ketika saya mencoba, saya mendapatkan kesalahan berikut:

=QUERY(B2:G124; "select * where B = date '"&Q4&"'")

Invalid query: Invalid date literal [10/02/2012]. Date literals should be of form yyyy-MM-dd.

Ketika saya melihat sel, formatnya adalah yyyy-mm-dd, tetapi ketika saya menggandakannya, formatnya berubah menjadi DD-MM-YYYY.

Apa yang harus saya lakukan?

Juga, bagaimana saya bisa merangkum nilai dari kueri, tanpa menyertakan kolom B?

Saya tidak dapat menemukan trik untuk sel tanggal nyata untuk bekerja, tetapi Anda bisa menyelesaikannya dengan menambahkan tanda kutip tunggal ( ') sebelum tanggal dalam format: YYYY-MM-DDdi dalam Q4sel.

Kutipan tunggal itu berarti bahwa itu akan diurai sebagai string.

Anda dapat memformat tanggal seperti ini:

=QUERY(B2:G124; "select * where B = date '" & text(Q4,"yyyy-MM-dd") & "'")

Untuk meringkas nilai dalam kolom C, lakukan ini:

=QUERY(B2:G124; "select sum(C) where B = date '" & text(Q4,"yyyy-MM-dd") & "'")

Tidak yakin bagaimana meringkas beberapa kolom - masih cukup baru untuk ini sendiri!

Ini seharusnya bekerja:

=QUERY(B2:G124; "select * where B = date '"&text(Q4;"yyyy-MM-dd")&"'")

Bagaimanapun, saya memiliki masalah yang sama dan akhirnya berhasil bagi saya.

Masalahnya adalah Anda menjadi bingung dengan pesan tersebut

Invalid query: Invalid date literal [10/02/2012]. Date literals should be of form yyyy-MM-dd.

Ini karena format tanggal sel Q4 Anda tampaknya dd / MM / tttt. Saya memiliki hal yang sama: bahkan jika ini terlihat seperti menjadi dd / MM / tttt Anda hanya harus mengatakannya seperti yang diberikan pada baris kedua dari jawaban saya di sini di atas.

Masukkan tanggal yang Anda inginkan di sel baru seperti Q3dalam format ini:2/28/2012

Kemudian dalam Q4tipe sel=YEAR(Q3) & "-" & DEC2OCT(MONTH(Q3), 2) & "-" & DAY(Q3)

Ini akan mendapatkan tanggal dari Q3sel dan mengubahnya menjadi string di dalam Q4sel.

Ini lebih bermanfaat jika Anda menginginkan tanggal saat ini. Alih-alih mendapatkan tanggal dari yang Q3dapat Anda gunakan now()untuk mendapatkan tanggal hari ini seperti:=YEAR(now()) & "-" & DEC2OCT(MONTH(now()), 2) & "-" & DAY(now())

Final harus:

=QUERY(B2:G124; "select * where B = date ' "  & text( Q4 ,"yyyy-MM-dd") & "'")

Di mana Q4 adalah sel yang diformat tanggal normal di mana Anda bisa mengetikkan tanggal.

Salin di atas ke notepad Anda dan memperbesar ukuran font untuk semua tentang.

Sulit untuk melihat single 'di dalam double di "sini.

Anda juga dapat menghitung tanggal di luar string dan menjatuhkan date, misalnya

=QUERY(B2:G124; "select * where B = '" & Q4)

Q4 secara efektif diteruskan sebagai bilangan bulat, itulah yang QUERY mengubah tanggal menjadi di belakang layar.

Menggunakan fungsi QUERY Google:

Untuk sum beberapa kolom , penting untuk memasukkan labelparameter di akhir kueri

=QUERY(B2:G124; "select sum(C) + sum(D) + sum(E) + sum(F) + sum(G) label sum(C) + sum(D) + sum(E) + sum(F) + sum(G) '' ") 

catatan: referensi kolom peka huruf besar-kecil & 2 tanda kutip tunggal di akhir kueri diperlukan.

Untuk menambahkan whereklausa referensi nilai tanggal sel : dari solusi s6mikes

=QUERY(B2:G124; "select * where B = date '" & text(Q4,"yyyy-MM-dd") & "') 

2 kueri yang digabungkan ...

=QUERY(B2:G124; "select sum(C) + sum(D) + sum(E) + sum(F) + sum(G) where B = date '" & text(Q4,"yyyy-MM-dd") & "' label sum(C) + sum(D) + sum(E) + sum(F) + sum(G) '' ")

Anda harus mengubah tipe data dalam sel referensi Anda menjadi teks. Dan itu akan bekerja dengan lancar.