Pintasan keyboard untuk beralih antar sheet di Excel

Jawaban:

20

Ctrl+ PgUpuntuk pindah ke kiri.

Ctrl+ PgDnuntuk bergerak ke kanan.

Dmatig
sumber
Ini juga berlaku untuk Excel 2013 =)
Metafaniel
dan di macbook tanpa pgup dan pgdown?
theonlygusti
Saya berharap mereka memiliki jalan pintas yang lebih baik, karena Page Updan Page Downselalu sulit ditemukan di laptop yang berbeda dan tidak terlalu nyaman ditempatkan di keyboard.
Cricrazy
3

VBA Macro dan Custom Keyboard Shortcut untuk Mengaktifkan Lembar Pertama atau Terakhir

Jika Anda ingin pintasan keyboard aktual untuk melompat ke lembar kerja pertama atau terakhir, masukkan kode ini ke dalam modul di buku kerja "PERSONAL":

Sub ToFirstSheet()
    Sheets(1).Activate
End Sub

Sub ToLastSheet()
    Sheets(Sheets.Count).Activate
End Sub

Buka Tab Pengembang> Makro. Jelajahi makro ini (ToFirstSheet dan ToLastSheet). Pilih satu, klik Opsi dan tetapkan pintasan keyboard. Lakukan hal yang sama untuk yang lain.

Dengan menyimpan ini ke buku kerja "PERSONAL" itu akan tersedia di file Excel apa pun.

Dibangun pada Pintasan Keyboard untuk Mengaktifkan Lembar Sebelumnya atau Berikutnya

Untuk melompat satu lembar kerja ke kiri atau kanan Anda dapat menggunakan pintasan keyboard default ini:

Ctrl+PgUp

Ctrl+PgDn

VBA Macro untuk Mengaktifkan Sheet Sebelumnya atau Berikutnya

Inilah cara untuk mencapai hal yang sama dengan menggunakan VBA coba ini:

Sub ToPreviousSheet()
    If ActiveSheet.Index = 1 Then
        ActiveWorkbook.Worksheets(ActiveWorkbook.Worksheets.Count).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index - 1).Activate
    End If
End Sub

Sub ToNextSheet()
    If ActiveSheet.Index = ActiveWorkbook.Worksheets.Count Then
        ActiveWorkbook.Worksheets(1).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index + 1).Activate
    End If
End Sub

Fungsi VBA untuk Mengembalikan Lembar Sebelumnya atau Berikutnya

Gunakan fungsi ini jika Anda lebih suka mendapatkan objek lembar kerja sebelumnya atau berikutnya:

Function GetPreviousSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = 1 Then
        Set GetPreviousSheet = targetBook.Worksheets(targetBook.Worksheets.Count)
    Else
        Set GetPreviousSheet = targetBook.Worksheets(targetSheet.Index - 1)
    End If
End Function

Function GetNextSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = targetBook.Worksheets.Count Then
        Set GetNextSheet = targetBook.Worksheets(1)
    Else
        Set GetNextSheet = targetBook.Worksheets(targetSheet.Index + 1)
    End If
End Function

Gunakan fungsi seperti ini:

Sub EXAMPLE()
    MsgBox "Previous Sheet:  " & GetPreviousSheet(ActiveSheet).Name
    MsgBox "Next Sheet:  " & GetNextSheet(ActiveSheet).Name
    GetNextSheet(ActiveSheet).Activate
End Sub
ChrisB
sumber
Bagaimana saya bisa mendapatkan lembar berikutnya dan sebelumnya? Saya ingin membuat Sub ToPreviousSheetdan ToNextSheet?
theonlygusti
Gunakan indeks lembar untuk ini. Saya akan memperbarui jawaban saya untuk memasukkan ini.
ChrisB
1

Anda juga dapat menggunakan kunci akselerator untuk sampai ke Gokotak dialog. Anda kemudian dapat mengetik sesuatu seperti foo!A1menavigasi ke sel kiri atas di lembar bernama "foo". Sementara halaman naik dan turun halaman umumnya lebih cepat. Jika Anda memiliki sejumlah besar (mis., 20+) lembar dengan nama baik, ini mungkin lebih cepat. Go juga berfungsi dengan baik jika Anda telah memberi nama tabel di sheet Anda.

Menekan F5 biasanya membuka Gokotak dialog.

Jeromy Anglim
sumber